creating a new/open/save/close lisp
@Anonymous wrote:
I have been trying to figure out how to creat a lisp that would let me
- Type in a file number
- if the file is in the a certain folder it would open it
- if not it would create a new file in the before mentioned folder.
- it would then save and close the previous file i have been working on.
- If it could also lastly end in editing an attribute for the new drawing that would be great, epic block lot is the block name.
Hi shawnt,
what occurs to me is to use a '.scr' file to close/open, to the rest of the code we can use Auto/VisualLISP.
"epic block lot" is the block name?
If so, what is the TAG?
Henrique
@Anonymous wrote:
I have three tags for Epic Block Lot
ADD
ST1
CTY
thanks!!
One more question, is the block in model, or in layout?
Henrique
@Anonymous wrote:
It is in a layout, LOT-HOUSE if you need the name.
thanks!
shawnt,
as a starting point
(defun c:demo (/ *error* dwgname name new newfile ofile scrfile)
(defun *error* (msg)
(if ofile
(close ofile)
)
(cond ((not msg))
((member msg '("Function cancelled" "quit / exit abort")))
((princ (strcat "\n** Error: " msg " ** ")))
)
(princ)
)
(if (and (progn
(initget 6)
(setq new (getint "\nEnter the next dwg number: "))
)
(setq name (strcat (itoa new) ".dwg"))
(setq dwgname (strcat (getvar 'dwgprefix) name))
)
(progn
(if (vl-directory-files (getvar 'dwgprefix) name)
(setq newfile (vla-open (vla-get-Documents (vlax-get-acad-object)) dwgname :vlax-false))
(setq newfile (vla-add (vla-get-documents (vlax-get-acad-object)) (getenv "LastTemplate")))
)
(vlax-for layt (vla-get-layouts newfile)
(if (= (vla-get-name layt) "LOT-HOUSE")
(vlax-for blk (vla-get-block layt)
(if (and (= (vla-get-objectname blk) "AcDbBlockReference")
(= (vla-get-effectivename blk) "Epic Block Lot")
)
(foreach att (vlax-invoke blk 'getattributes)
(cond ((= (vla-get-tagstring att) "ADD")
(vla-put-textstring att "New address...")
)
((= (vla-get-tagstring att) "ST1")
(vla-put-textstring att "New state...")
)
((= (vla-get-tagstring att) "CTY")
(vla-put-textstring att "New city...")
)
)
)
)
)
)
)
(vla-saveas newfile (strcat (getvar 'dwgprefix) name))
(vla-close newfile)
(setq scrfile (strcat (getenv "Temp") "\\My_Open.scr")
ofile (open scrfile "w")
)
(write-line "_.qsave" ofile)
(write-line "_.close" ofile)
(write-line "_.open" ofile)
(write-line (strcat "\"" dwgname "\"") ofile)
(close ofile)
(command "_.script" scrfile)
)
)
)
Hope this helps,
Henrique
@Anonymous wrote:
appologies for the late response, few issues:
- only seems to accept 5 digits for the file number
- the block needs to be edited every time, any way to just automaticly open enhanced attribute editor?
- the previous drawing dosen't seem to close on its own.
I am learning a lot from your lisp thru the autodesk help and trying to figure out what this is doing.
thanks again!
Hi shawnt,
the 'demo' it was just a starting point, for your code...
I did change the function to get the 'numbers' for the new dwg, to allow a large number of digits.
The 'demo' show a way to change the attributes in the new dwg without the need to open enhanced attribute editor, if your goal is to use the values from 'Epic Block Lot' at the current dwg, and copy to yhe new dwg, it's easy to add that feature in the code.
the previous drawing should close...
I added some comments to the code...
(defun c:demo (/ *error* dwgname name new newfile ofile scrfile)
;; error function
(defun *error* (msg)
; if the ofile is open during the error, close it
(if ofile
(close ofile)
)
(cond ((not msg))
((member msg '("Function cancelled" "quit / exit abort")))
((princ (strcat "\n** Error: " msg " ** ")))
)
(princ)
)
;; main program
; asks the user to enter a new number (as a string to allow a large number of digits)
(if (and (setq new (getstring "\nEnter the next dwg number: "))
; test if not an empty string
(/= new "")
; test if the user did enter a valid dwg name
(snvalid new)
; set name with file extension
(setq name (strcat new ".dwg"))
; set dwgname with full path
(setq dwgname (strcat (getvar 'dwgprefix) name))
)
; if all previous functions are true:
(progn
; test if dwg exists
(if (vl-directory-files (getvar 'dwgprefix) name)
; if exists, open it and set newfile with it, as a vla-object
(setq newfile (vla-open (vla-get-Documents (vlax-get-acad-object)) dwgname :vlax-false))
; if not exists, add it to the document collection using the lat used template, and set newfile with it, as a vla-object
(setq newfile (vla-add (vla-get-documents (vlax-get-acad-object)) (getenv "LastTemplate")))
)
; foreach layout (layt) from layouts collection from newfile
(vlax-for layt (vla-get-layouts newfile)
; test if layout name is "LOT-HOUSE"
(if (= (vla-get-name layt) "LOT-HOUSE")
; if true, forech block from block collection
(vlax-for blk (vla-get-block layt)
; test if is objectname property from blk is a "AcDbBlockReference"
(if (and (= (vla-get-objectname blk) "AcDbBlockReference")
; and test if the effectivename property from blk is "Epic Block Lot"
(= (vla-get-effectivename blk) "Epic Block Lot")
)
; if the previous tests are true
; foreach attribute
(foreach att (vlax-invoke blk 'getattributes)
; if tagstring is:
(cond ((= (vla-get-tagstring att) "ADD")
; put "New address..."
(vla-put-textstring att "New address...")
)
((= (vla-get-tagstring att) "ST1")
; put "New state..."
(vla-put-textstring att "New state...")
)
((= (vla-get-tagstring att) "CTY")
"New city..."
(vla-put-textstring att "New city...")
)
)
)
)
)
)
)
; save the newfile
(vla-saveas newfile (strcat (getvar 'dwgprefix) name))
; close the newfile
(vla-close newfile)
; start to create the script file
(setq scrfile (strcat (getenv "Temp") "\\My_Open.scr")
; open the script file to write "W"
ofile (open scrfile "w")
)
; write at ofile:
; qsave
(write-line "_.qsave" ofile)
; close
(write-line "_.close" ofile)
; open
(write-line "_.open" ofile)
; the dwg name to open
(write-line (strcat "\"" dwgname "\"") ofile)
; close the ofile
(close ofile)
; call the script command to run the previous cript file
(command "_.script" scrfile)
)
)
)
Hope this helps,
Henrique
@Anonymous wrote:
VERY NICE, THANK YOU FOR THE EXPLANATIONS IN THE LISP!
THANKS!
You're welcome, shawnt
Glad I could help
Henrique
shawnt wrote:
...
In the beginning of this code I need to be able to print the previous file. I can't figure out how to add in code right to not break the lisp.
...
Hi shawnt,
to print the previous file, just add the print command, after the (progn
Do you need to print all layouts?
If so, try to add this code lines after the (progn
(setq adoc (vla-get-ActiveDocument (vlax-get-acad-object)))
(vlax-for layt (vla-get-layouts adoc)
(if (not (eq (vla-get-name layt) "Model"))
(vla-PlotToDevice (vla-get-plot adoc))
)
)
Hope this helps,
Henrique
