Convert Block Instances into Groups

[koolestani]

Hi

Is there any way to convert all instances of a block in a drawing into groups? The contents of these blocks have to preserve their properties either defined "by layer" or overridden and stay in their place (preserve their location in the drawing).

[imadHabash]

Hi, 

It's Not applicable in normal and existing CAD commands.. you may need an outsource plugin or a lisp to do that.

[koolestani]

That's fine by me. Is there any LISP routine that can achieve this?

[Michiel.Valcke]

Hi @koolestani 

The people at the customization boards can probably help you better. After looking online I found a few lisp routines to change groups to blocks but not the other way around. 

To what end do you need groups over blocks?

[martin_leiter]

Hello Choolestani

You'll find it here, express tools are required

https://ww3.cad.de/foren/ubb/Forum145/HTML/003169.shtml#000003

[Kent1Cooper]

---

@koolestani wrote:

.... The contents of these blocks have to preserve their properties either defined "by layer" or overridden ....

---

And if pieces in a Block definition were drawn on Layer 0, do they need to be that way in the eventual Group, or should they take on the Layer that their containing Block insertion was on?  If the former, it should be rather simple, since after an Explode, the pieces will be the Previous selection, to be fed to a Group command.

Unnamed Groups, or should they be given names?

Any Attributes involved?

[koolestani]

@Kent1Cooper If I understand your question correctly I'll say the former is what needs to happen. Yes, the groups can be unnamed, with no attributes involved. 

[koolestani]

Thank you for the suggestion, I'll take care in the future! This may sound really silly but the objective was to purge blocks to eliminate the possibility of some layers that I cannot delete being referenced within said blocks. Since the block definitions inside the drawing were a hot mess and I was trying to simplify things a bit.

[koolestani]

Thanks for the reply. The contents of the referenced page seem too hard for me to comprehend.

[TomBeauford]

Try entering SetNestedObjectsByBlock at the command line and selecting a block.

https://www.reddit.com/r/AutoCAD/comments/mgfzhc/best_way_to_nuke_a_masterplan_and_make_it_gray/

[Kent1Cooper]

---

@koolestani wrote:

... the former is what needs to happen. Yes, the groups can be unnamed, with no attributes involved. 

---

This seems to do that, in limited testing:

(defun C:B2G ; = Blocks {to} Groups
  (/ bsel bdata bname ct bss n blk)
  (if
    (and
      (setq bsel (entsel "\nSelect Block to have all instances turned into Groups: "))
      (= (cdr (assoc 0 (setq bdata (entget (car bsel))))) "INSERT")
      (not (assoc 1 (tblsearch "block" (setq bname (cdr (assoc 2 bdata)))))); not Xref
    ); and
    (progn ; then
      (setq ct (getvar 'ctab))
      (setq bss (ssget "_X" (list '(0 . "INSERT") (cons 2 bname))))
      (repeat (setq n (sslength bss))
        (setq blk (ssname bss (setq n (1- n))))
        (setvar 'ctab (cdr (assoc 410 (entget blk))))
        (command "_.explode" blk)
        (initcommandversion)
        (command "_.group" (ssget "_P") "")
      ); repeat
      (setvar 'ctab ct)
    ); progn
  ); if
  (princ)
); defun 

It gets them in all Model/Layout spaces.  It relies on the Block in question being defined to allow Exploding, but if that can't be relied on, it could be made to check for that, and if it's not, either change that or ask the User whether to change that.  It also expects that all insertions will be on unlocked and thawed/on Layers, but those possibilities could be accounted for.

It could be made to suppress command echoing, have *error* handling to ensure resetting stuff, put an Undo begin/end wrapping around it all, etc., but first see whether it does what you're after.

[koolestani]

Thank you @Kent1Cooper, this works perfectly! Sorry for the late response. Your remarks about Undo capabilities and error handling features are spot on, I would love to see those bells and whiles added to this routine. The groups being named or unnamed isn't a problem for me, I actually had no idea that groups can be named, but might as well include that facility if possible.

[koolestani]

Hey, @Kent1Cooper, could you find the time to add these finishing touches? Just checking up. It's still a great script,  thank you for your help!