Combine code to make it even better
UNTESTED:
@djurk_haas wrote:
....
- How can I integrate Lee_Mac's code (and actually I want 3 digits instead of 4).
- How can I stote the attribute value of the tag "TAPPUNT/KEERKLEP" into a variable " tapkeer" (to make the comment out code work)
....
(foreach itm (vlax-invoke e 'GetAttributes)
(if (eq (vla-get-tagstring itm) "TAPPUNT/KEERKLEP")
(setq tapkeer (vla-get-textstring itm))
); if
; (setq tap "Tappunt")
....
)
Code van Lee_Mac:
(defun c:3digits ( / int )
(while
(and
(progn
(initget 6)
(setq int (getint "\nEnter a 3-digit number <Exit>: "))
)
(not (wcmatch (itoa int) "###"))
)
(princ "\nThat's not 3-digits!")
)
(if int
(princ (strcat "\nYou entered " (itoa int) "."))
(princ "\nUser exited.")
)
(princ)
)
As for integrating that, for what input(s) do you want the 3-digit number requested?
Now you got me interested too.
Do you want to be prompted for "Tappuntnr" for every object? IT looks as if thats what you're going for.
...
(repeat (setq i (sslength ss))
(setq e (vlax-ename->vla-object
(ssname ss (setq i (1- i)))))
...
(vla-put-textstring itm (getstring "\nTappuntnr: "));;<---
...And when you say 3 Digits i believe you are referrring to 3 characters as numbers , to include "001" , "025" Yes?
Whats with the :S in ssget anyway?
:S Force single object selection only Is that how you really wanted it? then why the repeat?
Though it still works with multiple selection < which is weird >, but can please confirm want you really want?
@djurk_haas wrote:
Thanks for the response!
I have a dynamic block with different visibilitystates (Tappunt, Keerklep, Onder-boven).
...changed. Both changes must be an 3 digits number.
We understand that, but question were:
Is this for multiple object selection?
if YES will the user be prompted for the 3 digit value per block?
In NO will it be sequential number based on the one time prompt for 3 digit value?
@djurk_haas wrote:
It is for changing 1 block at a time.
This is how I understand from your posted code
(defun c:TP-change (/ Your3digits data ss i e tapkeer attval tagTo)
(vl-load-com)
(defun Your3digits (msg / int nstr)
(while
(and
(progn
(initget 6)
(setq int (getint
(strcat "\n" msg ": ")))
)
(> int 999)
)
(princ (strcat "\nInvalid value"))
)
(setq nstr (itoa int))
(strcat (nth (strlen nstr)'(nil "00" "0" "")) nstr)
)
(setq data '(("Onder-boven" "NUMMER-ONDER-BOVEN")
("Keerklep" "NUMMER_KEERKLEP" )
("Tappunt" "NUMMER_TAPPUNT" )
)
)
(if (setq ss (ssget ":L"
'((0 . "insert") (66 . 1)
(2 . "`*U*,TAPPUNT_CZE"))))
(repeat (setq i (sslength ss))
(setq e (vlax-ename->vla-object
(ssname ss (setq i (1- i)))))
(cond
( (not
(and
(Eq (strcase (vla-get-effectivename e)) "TAPPUNT_CZE")
(setq attval (mapcar '(lambda (at)
(list (vla-get-TagString at)
(vla-get-TextString at) at))
(vlax-invoke e 'GetAttributes)))
(setq tapkeer (cadr (assoc "TAPPUNT/KEERKLEP" attval)))
(setq tagTo (Assoc
(Cadr (assoc tapkeer data)) attval))
)
)
)
( (member tapkeer (mapcar 'car (Cdr data)))
(vlax-invoke e 'Highlight 1)
(vla-put-textstring (caddr tagTo) (Your3digits (car tagTo)))
(vlax-invoke e 'Highlight 0)
)
( t (print "N.v.t.: Tappunt onder/boven")
)
)
)
)
(princ)
)
Depending on the value of "TAPPUNT/KEERKLEP", the prompt will switch between Tappunt and Keerler
Command: TP-CHANGE
NUMMER_TAPPUNT: 12
NUMMER_KEERKLEP: 45
HTH
@roland.r71 wrote:
Anyway, i think its not. So a different way to get the number will be (likely) required.
As leading zero's are ignored for integers. (so it doesn't even accept it as "3 digit number")
Yes, hence my question at post # 6. But i went ahead and wrote a different 3digit thingy.
Your3digits"
We'll see what the OP thinks.
@roland.r71 wrote:
It would appear your thingy got accepted 😄
Gotta to have that thingy in there
I'll tell you a secret [ whispering: I wrote the code and had it-the-ready two days ago 😉 ,]
@djurk_haas wrote:
In drawing B the code works fine but in drawing A the code stops halfway?
Maybe a system variable is wrong?
Drawing A
And because of that...
You see, the program is reading the attribute value of ""TAPPUNT/KEERKLEP"".. its either of the three
- Tappunt
- Keerklep
- Onder-boven
But as you can see. the value is ###, not included as a valid option
Attribute definition TAPPUNT/KEERKLEP is under the layer "A--L$8-hulplijnen" <-- currently locked
After unlocking and regen...
TADA!!!
Drawing B
Although the same layer is locked but the value of the tag "TAPPUNT/KEERKLEP" is not ###.... you know what I mean right?
We can however change the code to read the visibility state instead of the attribute tag "TAPPUNT/KEERKLEP"
A simple quick unlock and regen will solve the issue though
Tell me how it goes..
Here's the modified code that reads the visibility instead of the attribtues
(defun c:TP-change (/ Your3digits data ss i en tapkeer tagTo)
(vl-load-com)
(defun Your3digits (msg / int nstr)
(while
(and
(progn
(initget 6)
(setq int (getint
(strcat "\n" msg ": ")))
)
(> int 999)
)
(princ (strcat "\nInvalid value"))
)
(setq nstr (itoa int))
(strcat (nth (strlen nstr)'(nil "00" "0" "")) nstr)
)
(setq data '(("Onder-boven" "NUMMER-ONDER-BOVEN")
("Keerklep" "NUMMER_KEERKLEP" )
("Tappunt" "NUMMER_TAPPUNT" )
)
)
(if (setq ss (ssget ":L"
'((0 . "insert") (66 . 1)
(2 . "`*U*,TAPPUNT_CZE"))))
(repeat (setq i (sslength ss))
(setq en (ssname ss (setq i (1- i))))
(cond
( (not
(and
(Eq (getpropertyvalue en "BlockTableRecord/Name") "TAPPUNT_CZE")
(setq tapkeer (getpropertyvalue en "AcDbDynBlockPropertyVisibility1"))
(setq tagTo (Cadr (assoc tapkeer data)))
)
)
)
( (member tapkeer (mapcar 'car (Cdr data)))
(redraw en 3)
(setpropertyvalue en tagTo (Your3digits tagTo))
(redraw en 4)
)
( t (print "N.v.t.: Tappunt onder/boven")
)
)
)
)
(princ)
)
HTH
