Can I insert attribute in all current opened drawing's layout?

[skchui6159]

(defun reptag (tag newvalue ent / alist )
(if (and (= (type ent) (read "VLA-OBJECT")) newvalue)
(progn
(setq alist ( vlax-invoke ent 'GetAttributes))
(foreach a alist
(if (= (vla-get-tagstring a) tag)
(vlax-put-property a 'TextString newvalue)
);i
);fe
);p
(if (= 'ename (type ent)) (reptag tag newvalue (vlax-ename->vla-object ent)));i
);i
(princ));d

(defun c:OS ( / ent ss1)
;(setq ent (car (entsel)))
(foreach Layout (layoutlist)
(setq dateofinput "07/24")
(setq ss1 (ssget '(788 190 0)))
(setq ent (ssname ss1 0))
(reptag "ORIGINAL" "ORIGINAL" ent)
(reptag "SIGNED" "SIGNED" ent)
(reptag "GSTAUTHDATE" dateofinput ent)
(reptag "GSTFCHECKDATE" dateofinput ent)
(reptag "GST2CHECKDATE" dateofinput ent)
(reptag "GST1CHECKDATE" dateofinput ent)
(reptag "GSTDRAWDATE" dateofinput ent)
); foreach end
(princ))

The above lisp can run only single layout, but I want to apply all current opened drawing's? Anyone can help? Thx

[skchui6159]

The revise doc. are attached.

[paullimapa]

Also attach your latest code you are using

[skchui6159]

; OS updates attributes on all blocks found matching given name
; OP:
; https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/can-i-insert-attribute-in-all-curren...
(defun c:OS ( / dateofinput ent i obj reptag ss1)
(setq blknam "TITLE BLOCK-A"
dateofinput "07/24"
) ; setq
(vl-load-com)
(defun reptag (tag newvalue ent / alist )
(if (and (= (type ent) (read "VLA-OBJECT")) newvalue)
(progn
(setq alist ( vlax-invoke ent 'GetAttributes))
(foreach a alist
(if (= (vla-get-tagstring a) tag)
(vlax-put-property a 'TextString newvalue)
);i
);fe
);p
(if (= 'ename (type ent)) (reptag tag newvalue (vlax-ename->vla-object ent)));i
);i
(princ)
);d
(if(setq ss1 (ssget "_X" (list '(0 . "INSERT") (cons 2 (strcat blknam ",`*U*")) '(66 . 1))))
(progn
(setq i 0)
(repeat (sslength ss1)
(setq ent (ssname ss1 i)
obj (vlax-ename->vla-object ent)
)
(if (eq blknam (vla-get-effectivename obj))
(progn
(reptag "ORIGINAL" "ORIGINAL" ent)
(reptag "SIGNED" "SIGNED" ent)
(reptag "GSTAUTHDATE" dateofinput ent)
(reptag "GSTFCHECKDATE" dateofinput ent)
(reptag "GST2CHECKDATE" dateofinput ent)
(reptag "GST1CHECKDATE" dateofinput ent)
(reptag "GSTDRAWDATE" dateofinput ent)

#add layout name of each layout
#if version is not A-Z version at the end of layout
(if (= (wcmatch (getvar "ctab") "BM-11*[A-Z]")F)
(reptag "GSTDWGNO" strcat ("ABC/1/BL6/S/" getvar("ctab")) ent)
);end if
#if version is the A-Z version at the end of layout
(if (= (wcmatch (getvar "ctab") "BM-11*[A-Z]")T)
(reptag "GSTDWGNO" strcat ("ABC/1/BL6/S/" (substr (getvar "ctab") 1 6) "/" (substr (getvar "ctab") 7 1)) ent)
);end if
) ; progn
) ; if
(setq i (1+ i))
) ; repeat
(princ(strcat"\nUpdated Blocks matching: " blknam))
) ; progn
(princ(strcat"\nThere are no Blocks found matching: " blknam))
) ; if
(princ)
) ; defun

[paullimapa · Accepted solution]

I see a couple of issues...

The first one is simple.

Your title block name does not match with what the code is searching for.

Your current code is looking for:

(setq blknam "TITLE BLOCK-A"

But the title block name you included in your test dwg "blank title block ver1.dwg" is actually:

(setq blknam "TITLE BLOCK"

The second one is more complex.

A. You're not searching for the ctab variable because you're not changing the current tab to match with the found title block. But since the code stays in the current layout to loop through all the found blocks, when you use ctab it'll always be the current layout tab name and not the layout tab where the title block is actually found.

B. Don't use number # symbol to represent comments. You have to use semicolon ; symbol.

C. For the if test, you don't need to do an additional = test. You just need to rely on the wcmatch function to prove if what you're testing is true or not.

D. You have to always remember to begin a function like strcat or getvar with an open parenthesis.

E. Use combination of substr and strlen to get the layout name except the last character or only the last character:

So replace the following lines of code:

#add layout name of each layout
#if version is not A-Z version at the end of layout
(if (= (wcmatch (getvar "ctab") "BM-11*[A-Z]")F)
(reptag "GSTDWGNO" strcat ("ABC/1/BL6/S/" getvar("ctab")) ent)
);end if
#if version is the A-Z version at the end of layout
(if (= (wcmatch (getvar "ctab") "BM-11*[A-Z]")T)
(reptag "GSTDWGNO" strcat ("ABC/1/BL6/S/" (substr (getvar "ctab") 1 6) "/" (substr (getvar "ctab") 7 1)) ent)
);end if

with these:

         (setq layoutname (cdr(assoc 410 (entget ent))))
;add layout name of each layout
         (if (wcmatch layoutname "BM-11*[A-Z]")
;then version is the A-Z version at the end of layout
          (reptag "GSTDWGNO" (strcat "ABC/1/BL6/S/" (substr layoutname 1 (1- (strlen layoutname))) "/" (substr layoutname (strlen layoutname))) ent)
;else version is not A-Z version at the end of layout
          (reptag "GSTDWGNO" (strcat "ABC/1/BL6/S/" layoutname) ent)
         );end if

[skchui6159]

It works great! Thank you very much. 

Sorry, I forgot to use ";" for the lisp to explain of the statement, I forgot it is lisp not Python😅...

Also, thank you very much for the concept for 410 to get the layer name , the strlen function and my apologize for the name of title block was change (Title block is the real block name of the title block).

[paullimapa]

Once again glad to have helped…cheers!!!

[skchui6159]

One more complicated question, the repeated tags can be edited by lisp?

If I want the first orginal signed to Blank (order by top to bottom), it is possible?

[paullimapa]

I would not change the Tag names otherwise you’ll lose any of the current values. 
when you say blank do you mean nothing like try this

(reptag "ORIGINAL" "" ent)
(reptag "SIGNED" "" ent)

[skchui6159]

If something like that? It is possible to do? It is only way by changing/update by blockeditor and then change the tag name?

[paullimapa]

You can change tag name using lisp. You can read up on it in this thread

[skchui6159]

I can not run the lisp, it shows error. 

[paullimapa]

Include the revised lisp you’re trying to run

[skchui6159]

Hello, can I also get the boundary coordinate of above block?

[paullimapa]

Since I'm not sure what you plan to do, here's the code to get the lower left & the upper right coordinates of your typical title block "TITLE BLOCK" which only works if it's orthogonally placed and not rotated and your UCS is set to World. Here's a section of the code OS.lsp after the blknam has been confirmed which is where you can include the code to get the coordinates:

      (if (eq blknam (vla-get-effectivename obj))
        (progn
          (vla-getBoundingBox obj 'p0 'p1)  
          (setq lowerleft (vlax-safearray->list p0) ; get lower left coordinate
                upperight (vlax-safearray->list p1) ; get upper right coordinate
          )

[skchui6159]

can also get the top of left corner's and bottom of right corner's coordination? 

[paullimapa · Accepted solution]

here you go:

(setq loweright(list(car upperight)(cadr lowerleft)(caddr lowerleft))
      upperleft(list(car lowerleft)(cadr upperight)(caddr upperight))
)

[skchui6159]

Thank you very much!

[paullimapa]

you are welcome...cheers!!!

[skchui6159]

Can you also help me to change the Width Factor to (for example: 0.7) of the above attribute? Thank you!

[paullimapa]

Could not tell from your screenshot the attribute Tag name. Also do you only want to make this change on one Block with this attribute or all Blocks with this attribute? What is the Block name?