Blocks Perpendicular to Polyline

[adaptacad]

Good morning, everyone!

I would like to know if it’s possible to align multiple blocks so that they are perpendicular to polylines in a DWG file.

The goal is to select multiple texts and multiple polylines, ensuring that the texts align perpendicularly to the nearest polyline. I've searched on Google and ChatGPT but haven’t found a solution.

Can anyone help me? I’ve attached images and a DWG file as examples.

Thanks in advance!

[ВeekeeCZ · Accepted solution]

Not search, not ai, just learn. There is nothing complicated. Nothing.

(vl-load-com)

(defun c:BlocksPerpendiculartoPolyline ( / s d b l c q a)
  
  (and (setq s (ssget '((0 . "LWPOLYLINE,INSERT"))))
       (setq d (getdist "\nSpecify distance: " ))
       (setq s (vl-remove-if 'listp (mapcar 'cadr (ssnamex s))))
       (foreach e s
	 (if (= "INSERT" (cdr (assoc 0 (entget e))))
	   (setq b (cons e b))
	   (setq l (cons e l))))
       b
       l
       (foreach e b
	 (if (and (setq p (cdr (assoc 10 (entget e))))
		  (setq l (vl-sort l '(lambda (l1 l2) (< (distance p (vlax-curve-getclosestpointto l1 p))
							 (distance p (vlax-curve-getclosestpointto l2 p))))))
		  (setq c (car l))
		  )
	   (progn
	     (setq q (vlax-curve-getclosestpointto c p))
	     (setq a (angle q p))
	     (setpropertyvalue e "Rotation" a)
	     (setpropertyvalue e "Position" (polar q a d))))))
  (princ)
  )

[adaptacad]

Thank you very much @ВeekeeCZ !!!! This worked very well! But is there a way to keep the original distance, without having to specify it?

[ec-cad · Accepted solution]

If you want the original distance maintained, try the revised code:

(vl-load-com)

(defun c:BlocksPerpendiculartoPolyline ( / s d b l c q a)
  
  (and (setq s (ssget '((0 . "LWPOLYLINE,INSERT"))))
     ;; (setq d (getdist "\nSpecify distance: " )); we want to keep original distance
       (setq s (vl-remove-if 'listp (mapcar 'cadr (ssnamex s))))
       (foreach e s
	 (if (= "INSERT" (cdr (assoc 0 (entget e))))
	   (setq b (cons e b))
	   (setq l (cons e l))))
       b
       l
       (foreach e b
	 (if (and (setq p (cdr (assoc 10 (entget e))))
		  (setq l (vl-sort l '(lambda (l1 l2) (< (distance p (vlax-curve-getclosestpointto l1 p))
							 (distance p (vlax-curve-getclosestpointto l2 p))))))
		  (setq c (car l))
		  )
	   (progn
	     (setq q (vlax-curve-getclosestpointto c p))
	     (setq a (angle q p))
             (setq d (distance q p)); Set the Distance to what it was..
	     (setpropertyvalue e "Rotation" a)
	     (setpropertyvalue e "Position" (polar q a d))))))
  (princ)
  )
;; remove next 2 lines if desired for autoloading
 (c:BlocksPerpendiculartoPolyline)
 (princ)

ECCAD

[adaptacad]

Thank you both very much! It worked great! @ВeekeeCZ  @ec-cad