Block in table

[Lex_van_Ham]

Hello again,

One more question about tables: How do I get a block preview in a table cell.

It doesn't have to be some complicated selection thing just standard always the same block in  the same cell.

Do I just add a line of code in the cell i want it in or is this more complicated? I want it in cell 3 2.

(vla-setText table 3 0 "text")
(vla-setText table 3 1)
(   .................      3 2 )

Thanks

[_gile]

Hi,

As shown in this reply, you can do:

(vla-SetBlockTableRecordId table 3 2 blockId :vlax-true)

where blockId is the ObjectId of the block definition.

[Lex_van_Ham]

Yeah I got that in it but I don't really know how to get the ID, can you help me with this?

(the blocks aren't drawn but are loaded with the dwt)

[Satish_Rajdev · Accepted solution]

Try this functions :

(defun set:tablerecord (tableobject row column blockname / bk fg id)
  (setq	bk (vla-item (vla-get-blocks
		       (vla-get-activedocument (vlax-get-acad-object))
		     )
		     blockname
	   )
  )
  (if (vlax-method-applicable-p
	tableobject
	'setblocktablerecordid32
      )
    (setq id (vla-get-objectid32 bk)
	  fg t
    )
    (setq id (vla-get-objectid bk))
  )
  ((if fg
     vla-setblocktablerecordid32
     vla-setblocktablerecordid
   )
    tableobject	row column id :vlax-true)
)

Example :

(set:tablerecord table 3 2 "Specify Blockname")

[Lex_van_Ham]

Awesome thanks 

[_gile]

Here's a way to get the ObjectId of a block which name is bound to the blockName variable.

;; get the block table (block definitions collection)
(setq blockTable (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object))))

;; get a block by name
;; (throws an error if the the block table does not contain a block names as blockName)
(setq block (vla-Item blockTable blockName))

;; get the block ObjectId
(setq blockId (vla-get-ObjectId block))

Maybe you want to get all block definitions in the current drawing block table:

;; build a list of dotted pairs with all block definitions and their ObjectId
(vlax-for blk blockTable
  (if (and (= (vla-get-IsLayout blk) :vlax-false)
           (= (vla-get-IsXref blk) :vlax-false)
      )
    (setq blockList (cons (cons (vla-get-Name blk) (vla-get-ObjectId blk)) blockList))
  )
)

[Lex_van_Ham]

One last thing might be a stupid question but how do I make the text in the entire table larger (within the lisp so without user input)

[_gile]

This depends on the current table style settings.

[Satish_Rajdev]

I didn't understand your question, Can you please explain it with picture?

[Lex_van_Ham]

When I run the script it makes the table and everything works great but the text is pretty small:

[Satish_Rajdev · Accepted solution]

Understood. You can set text height using this:

(vla-setcelltextheight table row column 1.0)

[Lex_van_Ham]

Also, is there a way I can put a .PNG in the cells instead of blocks?

[_gile]

You can also set the text height for the entire row:

(vla-SetTextHeight table row height)

[_gile]

To be clearer, you can set the text height bay row type:

Only data rows (bit 1)

(vla-SetTextHeight table 1 height)

Only title row (bit 2)

(vla-SetTextHeight table 2 height)

Only header row (bit 4)

(vla-SetTextHeight table 1 height)

 You can also combinate this, e.g. for the entire table (+ 1 2 4):

(vla-SetTextHeight table 7 height)