Hallo,
Please help!
I have to add MText "HDPE32" as in expalmpe to other multiple green Mlines and to align that text. I could copy/paste and align one by one but there are more then 300 of them. Is there an easier way to add the same text to all of them?
[ The subject line of this post has been edited to include the product name by @handjonathan ]
Hi,
You need here an outsource help .. I suggest to check the following link that may help . >> Click1 <<
Imad Habash
Are they always and only two-point MLINE objects -- nothing "fancier"? Are they always all of the same Style and Scale and Justification [thinking about placement of the Text part -- length variations shouldn't matter]? Are they always on the same Layer, with no other Mlines on that Layer that you don't want Text added to? In that case the routine could find them all, or would the User select? Would the User specify [type in] the Text content, or select an already-existing Text object, or would it be determined from some characteristic of each Mline, or ...?
They are "street crossings", so lenght and rotations are different on eacht one, but all are in the same layer als o with text. At first they are just a polylines with labels:
So covert them to polylines. And then i add text, so at the end they look like this:
Text is always the same, just rotation is different. Also the same Layer. Yes, green ones are always two point Mlines in the same style but different lenght and rotation. I can easy put text and Mline to separated layers if needed.
Not all my questions have been answered yet, but as a quick starting approach:
(defun C:TAML ; = Text At MultiLines
(/ ss txt n ends end1 end2 midpt ang)
(if (setq ss (ssget "_X" '((0 . "MLINE") (8 . "YourMlineLayer"))))
(progn
(setq txt (getstring "\nText content: "))
(repeat (setq n (sslength ss))
(setq
ends (vlax-get (vlax-ename->vla-object (ssname ss (setq n (1- n)))) 'Coordinates)
end1 (list (car ends) (cadr ends) (caddr ends))
end2 (cdddr ends)
midpt (mapcar '/ (mapcar '+ end1 end2) '(2 2 2))
ang (angle end1 end2)
)
(if (and (> ang (/ pi 2)) (<= ang (* pi 1.5))) (setq ang (+ ang pi))); plan-readable direction
(command "_.text" "_c" ; ["_cen" or "_center" taken as Osnap call]
(polar midpt (+ ang (/ pi 2)) (getvar 'textsize))
"" (cvunit ang "radian" "degree") txt
)
)
)
)
(princ)
)
It does the Text in the current Style, which it assumes is defined without a fixed height, and at the current Text Height, assuming that is an appropriate size, and on the current Layer. Differences from those can be built in, as answers are provided. Edit the Layer name to suit. How well it places Text [center-justified, off the definition-point path of the Mline by the Text height] depends on the style and scale and justification of the Mlines -- if those are always the same, something can be built in.
Im sorry Im not very advanced in it. I try to answer rest of questions:
This is text Information:
Mlines are always the same width just length may vary. But length variations doesn''t matter for the text. Text stay always the same size as shown above.
Hey, I tried code:
it recognize Mlines beautifully and add text to all of it. But is it possible to add text height to 1.25m and distance 1m from Mlines?
And is your DRILLING MultiLine Style defined something like this in the MLSTYLE dialog box?
Specifically, are the Offsets plus & minus 0.5, so that we can count on the scale assigned to a give Mline to be the actual spacing between its edges, and the edges centered around the virtual line between defined endpoints?
If the answer to my previous question is yes, and if the current Text Style will always be without a fixed height, and if a meter is your drawing unit, then:
(defun C:TAML ; = Text At MultiLines
(/ ss txt n ends end1 end2 midpt ang)
(if (setq ss (ssget "_X" '((0 . "MLINE") (8 . "YourMlineLayer"))))
(progn
(setq txt (getstring "\nText content: "))
(repeat (setq n (sslength ss))
(setq
mlobj (vlax-ename->vla-object (ssname ss (setq n (1- n))))
ends (vlax-get mlobj 'Coordinates)
end1 (list (car ends) (cadr ends) (caddr ends))
end2 (cdddr ends)
midpt (mapcar '/ (mapcar '+ end1 end2) '(2 2 2))
ang (angle end1 end2)
)
(if (and (> ang (/ pi 2)) (<= ang (* pi 1.5))) (setq ang (+ ang pi))); plan-readable direction
(command "_.text" "_c" ; ["_cen" or "_center" taken as Osnap call]
(polar midpt (+ ang (/ pi 2)) (1+ (/ (vlax-get mlobj 'MlineScale) 2)))
1.25 (cvunit ang "radian" "degree") txt
)
)
)
)
(princ)
)
