AutoCAD LT lisp assistance

DC-MWA · ‎08-03-2024

Hello,

I have a lisp I use for tagging. It creates a layer, inserts a multileader and puts the layer back when done.

In AcadLT 2025 it creates the layer, does the multileader and then puts the multileader back to the orig layer and puts layer back to original.

I'm baffled on whey this is happening. My other lisps that make layer/insert block/put layer back seem to work fine.

I'm hoping this is not big deal and has a simple fix.

Thank you in advance for any assistance.

Moshe-A · ‎08-03-2024

@DC-MWA hi,

check this corrections, untested.

Moshe

(defun c:stag (/ newlayer dscl landist bfind1 bfind2)
 (setvar "cmdecho" 0)
 (setvar "orthomode" 0)
 (setvar "osmode" 512)
 (setvar "attreq" 1)
 (setvar "attdia" 0)
  
;| No need to insert block all the way if only the block
   definition is needed

(setq bfind1 (tblsearch "block" "DC-TAG"))
 (if bfind1 
  (princ "\nDC-TAG found...")
  (progn
   (command "-insert" "DC-TAG" "0,0,0" "" "" "" "1")
   (entdel (entlast))
  );pr
 );if |;

 ; instead cancel command function immediately after supplying block name
  
 (if (null (tblsearch "block" "dc-tag"))
  (progn
   (command "-insert" "dc-tag")
   (command)
  ); progn
 ); if

;| (setq bfind2 (tblsearch "block" "DC-TAGLEADERSTYLES"))
 (if bfind2 
  (princ "\nDC-TAGLEADERSTYLES found...\n")
  (progn
   (command "-insert" "DC-TAGLEADERSTYLES" "0,0,0" "" "" "" "1")
   (entdel (entlast))
  );pr
 );if |;

 (if (null (tblsearch "block" "dc-tag"))
  (progn
   (command "-insert" "dc-tagleaderstyles")
   (command)
  ); progn
 ); if

 ;(DO_KNOTE_LAYER)
 (setq olayer (getvar "clayer")) ;save layer
 (command "layer" "m" "test" "c" "red" "" "")
 (setvar "cmleaderstyle" "dc-tags")
 (setvar "mleaderscale" (getvar "dimscale"))
 (prompt "\nPOINT AT?")
 (setq dscl (getvar "dimscale"))
 (setq landist (* dscl 0.08))
 (command "_.mleader" "_Options" "_Content type" "_Block" "dc-tag" "_leader lAnding" "_yes" landist "eXit Options")
 (prompt "\nPick Tag location...")
  
 (while (/= (getvar "cmdecho") 0)
  (command pause)
 )
  
 (setvar "attdia" 1)
 (setvar "clayer" olayer) ;return to previous layer
 (setvar "cmdecho" 1)
);end c:stag

DC-MWA · ‎08-03-2024

error, see below.

DC-MWA · ‎08-03-2024

Also,

This:

(while (/= (getvar "cmdecho") 0)
  (command pause)
 )

triggers the dialog entry which requires an additional mouse click. No good.

Moshe-A · ‎08-03-2024

As I said I did not test it cause you did not post your blocks

Instead cmdecho change it to cmdactive (sorry my mistake)

DC-MWA · ‎08-03-2024

See attached...

The issue is that it does not store and put the layer back when done.

It places the mleader on the current layer, not the layer created?

ec-cad · ‎08-03-2024

Took the liberty of changing posted code. Hope you don't mind..

(defun c:stag (/ newlayer dscl landist bfind1 bfind2)
 (setvar "cmdecho" 0)
 (setvar "orthomode" 0)
 (setvar "osmode" 512)
 (setvar "attreq" 1)
 (setvar "attdia" 0)
  
;| No need to insert block all the way if only the block
   definition is needed

(setq bfind1 (tblsearch "block" "DC-TAG"))
 (if bfind1 
  (princ "\nDC-TAG found...")
  (progn
   (command "-insert" "DC-TAG" "0,0,0" "" "" "" "1")
   (entdel (entlast))
  );pr
 );if |;

 ; instead cancel command function immediately after supplying block name
  
 (if (null (tblsearch "block" "dc-tag"))
  (progn
   (command "-insert" "dc-tag")
   (command)
  ); progn
 ); if

;| (setq bfind2 (tblsearch "block" "DC-TAGLEADERSTYLES"))
 (if bfind2 
  (princ "\nDC-TAGLEADERSTYLES found...\n")
  (progn
   (command "-insert" "DC-TAGLEADERSTYLES" "0,0,0" "" "" "" "1")
   (entdel (entlast))
  );pr
 );if |;

 (if (null (tblsearch "block" "dc-tag"))
  (progn
   (command "-insert" "dc-tagleaderstyles")
   (command)
  ); progn
 ); if

 ;(DO_KNOTE_LAYER)
 (setq olayer (getvar "clayer")) ;save layer
 (command "layer" "m" "test" "c" "red" "" "")
 (setvar "clayer" "test"); assure we are at layer 'test' <----- added
 (setvar "cmleaderstyle" "dc-tags")
 (setvar "mleaderscale" (getvar "dimscale"))
 (prompt "\nPOINT AT?")
 (setq dscl (getvar "dimscale"))
 (setq landist (* dscl 0.08))
 (command "_.mleader" "_Options" "_Content type" "_Block" "dc-tag" "_leader lAnding" "_yes" landist "eXit Options")
 (prompt "\nPick Tag location...")
  
 (while (/= (getvar "cmdactive") 0); <------ changed
  (command pause)
 )
  
 (setvar "attdia" 1)
 (setvar "clayer" olayer) ;return to previous layer
 (setvar "cmdecho" 1)
);end c:stag

ECCAD

DC-MWA · ‎08-04-2024

I appreciate the input. None of this seems to help.

I have many other programs that store current layer, do task, put layer back without issue.

I'm guessing it has something to do with the mleader function. Maybe it's changed in 2025??

komondormrex · ‎08-04-2024

hey there,

(initcommandversion) at 31 will definitely do the thing

(defun c:stag (/ newlayer dscl landist bfind1 bfind2)
	(setvar "cmdecho" 0)
    (setvar "orthomode" 0)
	(setvar "osmode" 512)
	(setvar"ATTREQ" 1)
    (setvar "ATTDIA" 0)
	(setq bfind1 (tblsearch "block" "DC-TAG"))
	(if bfind1 
		(princ "\nDC-TAG found...")
		(progn
			(command "-insert" "DC-TAG" "0,0,0" "" "" "" "1")
			(entdel (entlast))
		);pr
	);if
	(setq bfind2 (tblsearch "block" "DC-TAGLEADERSTYLES"))
	(if bfind2 
		(princ "\nDC-TAGLEADERSTYLES found...\n")
		(progn
			(command "-insert" "DC-TAGLEADERSTYLES" "0,0,0" "" "" "" "1")
			(entdel (entlast))
		);pr
	);if
	;(DO_KNOTE_LAYER)
	(setq olayer (getvar 'clayer)) ;save layer
	(command "layer" "m" "test" "c" "red" "" "")
	(setvar "cmleaderstyle" "DC-tags")
	(setvar "mleaderscale" (getvar "dimscale"))
	(prompt "\nPOINT AT?")
	(setq dscl (getvar "dimscale"))
	(setq landist (* dscl 0.08))
	(initcommandversion)
	(command "_.mleader" "o" "c" "B" "DC-tag" "a" "yes" landist "x" pause)
    (prompt "\nPick Tag location...")
    (command PAUSE)
    (setvar "ATTDIA" 1)
	(setvar 'clayer olayer) ;return to previous layer
	(setvar "cmdecho" 1)
);end defun c:stag

DC-MWA · ‎08-06-2024

This didn't work.

pendean · ‎08-07-2024

@DC-MWA wrote:
...Maybe it's changed in 2025??

So this/these LISP work in LT2024?

Do you have the LT2025.1 update installed? That seems to have added quite the mess of things (CLayer command related) for some users.

ec-cad · ‎08-07-2024

If you 'insert' blocks, they will be on 'current' layer, so when you do a leader, with that block, it will still be on

the current layer..

So, move these (2) lines up near top. Before you insert those blocks.

(setq olayer (getvar 'clayer)) ;save layer
	(command "layer" "m" "test" "c" "red" "" "")

Also, add the (setvar "clayer" "test").

ECCAD

pendean · ‎08-07-2024

@ec-cad wrote:
.... Also, add the (setvar "clayer" "test").

@DC-MWA This actually works instead of the otherwise excellent tip in LT2025.1 (CLAYER issues abound there)

So it looks like you need to stay away from CLAYER in LT2025.1 until the next update out to fix it from Autodesk is available. Next step, change this (aka don't use CLAYER)

or roll back to LT2024, even with it's latest updates, your original LISP works just fine there.

pkenewell6347 · ‎08-08-2024

The problem is not with CLAYER, it is with the mleader command exiting cleanly on Attributes. Your current solution works because it forces the command execution to be completed before the code continues. Consider this example change to your code; it works because the mleader command exits cleanly before the code continues.

(defun c:stag (/ newlayer olayer dscl landist bfind1 bfind2 p1 p2 cn)
   (setvar "cmdecho" 0)
   (setvar "orthomode" 0)
   (setvar "osmode" 512)
   (setvar"ATTREQ" 1)
   (setvar "ATTDIA" 0)
   (setq bfind1 (tblsearch "block" "DC-TAG"))
   (if bfind1
      (princ "\nDC-TAG found...")
      (progn
         (command "-insert" "DC-TAG" "0,0,0" "" "" "" "1")
         (entdel (entlast))
      );pr
   );if
   (setq bfind2 (tblsearch "block" "DC-TAGLEADERSTYLES"))
   (if bfind2
      (princ "\nDC-TAGLEADERSTYLES found...\n")
      (progn
         (command "-insert" "DC-TAGLEADERSTYLES" "0,0,0" "" "" "" "1")
         (entdel (entlast))
      );pr
   );if
   ;(DO_KNOTE_LAYER)
   (setq olayer (getvar "clayer")) ;save layer
   (command "layer" "m" "test" "c" "red" "" "")
   (setvar "cmleaderstyle" "DC-tags")
   (setvar "mleaderscale" (getvar "dimscale"))
   (setq dscl (getvar "dimscale"))
   (setq landist (* dscl 0.08))
   (setq p1 (getpoint "\nSelect Starting Point: ")
            p2 (getpoint p1 "\nPick Tag Location: ")
            cn (getstring "\nEnter TagNumber: ")
   )
   (initcommandversion)
   (command "_.mleader" "o" "c" "B" "DC-tag" "a" "yes" landist "x" p1 p2 cn)
   (setvar "clayer" olayer) ;return to previous layer
   (setvar "ATTDIA" 1)
   (setvar "cmdecho" 1)
);end defun c:stag

DC-MWA · ‎08-10-2024

This is what I needed.

I ended up using the following:

(initcommandversion)
(prompt "\nPOINT AT?")
(command "_.mleader" "o" "c" "B" "DC-tag" "a" "yes" landist "x" pause)
(prompt "\nPick Tag location...")
(command PAUSE (getstring "\nEnter Tag Number: "))

Thank you very much for your assistance!!!

Community

AutoCAD LT lisp assistance

AutoCAD LT lisp assistance

AutoCAD LT lisp assistance