Autocad Lisp, remove all text after layer name
@kieran.leadbetter wrote:
... if my layer name was
A200_Demolitions
But there was a variant of this within the drawing, A200_demolitions123, could I have any characters before or after the layer *A200_Demolitions* ....
Something like this, as a starting point? Minimally tested:
(defun C:CLNN ; = Change to Layer with Nested Name
(/ tln ss n edata)
(setq tln (getstring "\nNested Layer Name: "))
(if (setq ss (ssget "_X" (list (cons 8 (strcat "*" tln "*")))))
(repeat (setq n (sslength ss)); then
(setq edata (entget (ssname ss (setq n (1- n)))))
(entmod (append edata (list (cons 8 tln))))
); repeat
(prompt "\nNothing found on Layer(s) with appended names.")
); if
(prin1)
)You would answer your example A200_Demolitions to the prompt for the nested Layer name. You could make a list of "base" names and apply the same functionality to each, instead of asking the User for the nested name, with a small adjustment.
If the nested Layer doesn't exist, a benefit of the appending-to-entity-data approach is it will be created in the process [with default color 7 and continuous linetype].
It doesn't get rid of the longer-name Layers, just moves things on them to the nested-name Layer. It could be enhanced to ensure they're unlocked, etc. LAYMRG could be used to get rid of them, but it would need to know every specific variant name involved, whereas this can find everything on variant Layers without caring exactly what the variants are.
@kieran.leadbetter wrote:
....
How would I make a "list of base names" like you mentioned, I am attempting to make this an automatic task so I would have all our standard layers inputted into this lisp and it would tidy all the rouge layers into it
....
And what do you mean by "It doesn't get rid of the longer-name Layers, just moves things on them to the nested-name Layer. "
What is the nested-name layer, would this lisp not merge any rouge layers like A200_Demolitions123... to A200_Demolitions?
....
(setq BaseLayerNames '("A200_Demolitions" "ABC" "DEF" "XYZ" "Batman" "MarilynMonroe"))
(foreach LayName BaseLayerNames
(.... run the same operation on that Layer Name instead of asking the User for it ....)
)
I mean just what it says. The [I think you mean] rogue [not rouge] Layers remain in the drawing, but everything on them gets moved to the base-named Layer. The reason I did that is because if the base name is "ABC", it can find things on Layers "ABC123" and "whatABCwhere" and "98ABC" and "ABCDEF" all collectively with the wildcards around the base name in the (ssget) filter -- "*ABC*". It doesn't matter what the rogue-nesses are like -- extra characters before, after, both, etc. -- nor how many rogue Layers are involved. Those all get put into the base-named Layer. To eliminate those Layers using LAYMRG requires finding all those things on them and stepping through each one for its specific Layer name to apply in the command, resulting in potentially a large number of individual LAYMRG operations. Obviously that can be done, or a different approach than object selection can be used [see @ВeekeeCZ's suggestion], with more complex code, but this was my quickie version.
The nested-name Layer is the one with its name in the list -- the one you want to keep.
Try this [untested]:
(defun C:CLNN (/ BaseLayerNames ss n edata); = Change Layer to Nested Name
(setq BaseLayerNames '("A200_Demolitions" "ABC" "DEF" "XYZ" "Batman" "MarilynMonroe"))
(foreach LayName BaseLayerNames ; for every name in the list, do the following:
(if (setq ss (ssget "_X" (list (cons 8 (strcat "*" LayName "*"))))); things on Layers containing listed part
(repeat (setq n (sslength ss)); then
(setq edata (entget (ssname ss (setq n (1- n)))))
(entmod (append edata (list (cons 8 LayName))))
); repeat
(prompt (strcat "\nNothing found on Layer(s) containing " LayName ".")); else
); if
); foreach
(prin1)
)
[Of course, you don't want my list of wacky names.]
If you did this always in Model Space and all eligible things are always there [or as long as all eligible objects are in the current space, whatever that is], it could be simplified to just use a CHPROP command on all the things it finds, all at once, to change their Layer, without needing to step through them. Stepping through is needed if they might occur in different spaces -- Model vs. Paper vs. different Paper Space Layouts -- because editing commands involving object selection can "see" only things in the current space.
@kieran.leadbetter wrote:
.... When I run this lisp it just runs through all the standard layers stating
"Nothing found on Layer(s) containing A200_Demolitions."....
I set up a simpler situation, with "base" Layer names "ABC" and "DEF" and some "rogue" Layer names having extra characters either before or after the base three letters, or both, like "ABC123" and "4DEF5". That simpler base Layer name list was the only change I made in your code in Message 11, and it worked for me -- all objects on the rogue Layers got changed to the corresponding base Layers. Are you sure you spelled everything right? [You have powerful-long Layer names, giving greater opportunity for typos.] Are any of your Layers locked? [It shouldn't be case-sensitive, but have you tried it with full letter-case agreement?]
But no, so far it doesn't eliminate the rogue Layers, but only empties them [that is, top-level objects on them -- I didn't get into nested objects yet]. I'd want to get the consolidating working before going on to the elimination of Layers [which could be by PURGE if everything's top-level, rather than LAYDEL or LAYMRG].
