Alternative to LAYMCUR that works in noun verb mode.
It has to be slightly more restrictive than just accepting pre-selection -- it needs to be pre-selection of only one object. Try this:
;|
LMC command [like LAYMCUR but accepting single pre-selected object]
Kent Cooper, 2 November 2023
|;
(defun C:LMC (/ getobj ss ent); = Layer Make Current
(defun getobj ()
(while (not ent)
(setq ent (car (entsel "\nSelect one object to set its Layer current: ")))
); while
); defun
(cond ; OBJECT SELECTION
( (and
(setq ss (ssget "_I")); something pre-selected
(= (sslength ss) 1); only one object
); and
(setq ent (ssname ss 0))
); first condition [single pre-selected object]
( (ssget "_I"); more than one object selected
(sssetfirst nil); un-select multiple objects
(getobj); User select
); second condition
((getobj)); User select [nothing pre-selected]
); cond
(setvar 'clayer (cdr (assoc 8 (entget ent))))
(prin1)
); defun
@ВeekeeCZ wrote:
Just out of interest. What versions are you all talking about? AFAIK the built-in LAYMCUR version accepts both methods... ..
You're right, it works with pre-selection in Acad2024, either by typing in or picking the ribbon icon. And like my LMC command, if you have more than one thing selected, it clears them and asks you to pick one. [I'll be able to check 2020 from a different location later.]
EDIT: Same in Acad2020. So @John_in_NZ, are you using an older version in which perhaps it doesn't work? Need updates? Re-installation? Does it work in some drawings but not others, and would AUDITing those others fix it?
@komondormrex wrote:
hey there,
.... reactor is better thing to do it. pick an object and instantly current layer becomes one of the picked object. ....
[That's an interesting concept, and some people may find it useful, but it would never work for me. I far too often have any number of reasons to select something when I don't need or want its Layer to become current, for example just to Move (or Rotate or Copy or....) something by grip-editing, or edit some Text/Mtext content, or just look at some property or other. The current Layer would be constantly jumping around for no reason. But it's an option available to those who want it.]
Does noun-verb operation work in other commands? If not, look into the PICKFIRST System Variable. If that's already set for it, I don't what else to suggest other than to check for updates, or maybe a re-installation or something.
@john.uhden wrote:
That's funny to me that you used (ssget "_I") as I always use (ssgetfirst), but I don't think there's any difference. ....
There's a difference in code length / number of functions / amount of parentheses, if that matters. You're looking for a selection set, but since (ssgetfirst) returns a list, of which the selection set you want is only the second item, to get that set into a variable you need to do:
(setq test (cadr (ssgetfirst)))
[or, if you prefer, (last)], whereas this gives you that selection set directly:
(setq test (ssget "_I"))
