Hello everyone,
Been moving alot of blocks manually for a couple of months now and it is really sucking alot of energy out of me haha.
is there a option to resolve this problem with a lisp? Images included for explanation!
All the help would be really appreciated! thanks in advance!
@t_pladet wrote:
There are certain blocks that are in the middle of a line those also need to move to the closest vertex near them. so not necessarily to a endpoint perse. But most of them do have a endpoint where they need to be snapped on too!
(Defun c:MoveMe ( / _Points _DistanceFrom ss i e ent ANCollection CableIDCollection)
(defun _Points (e / l )
(repeat (setq p (1+ (fix (vlax-curve-getEndParam e))))
(setq l (cons (vlax-curve-getPointAtParam e (setq p (1- p))) l))
)
)
(defun _DistanceFrom (pt pts)
(Car (vl-sort pts '(lambda (a b)(< (distance pt a)(distance pt b)))))
)
(setq ss (ssget '((-4 . "<OR")
(-4 . "<AND")(0 . "LWPOLYLINE")(8 . "AccessNet")(-4 . "AND>")
(-4 . "<AND")(0 . "INSERT")(66 . 1)(2 . "KabelID")(-4 . "AND>")
(-4 . "OR>")
)
)
)
(progn
(repeat (setq i (sslength ss))
(setq e (ssname ss (setq i (1- i))))
(if (eq (cdr (assoc 0 (Setq ent (entget e)))) "LWPOLYLINE")
(setq ANCollection (cons (list (_Points e) e ) ANCollection )
)
(setq CableIDCollection (cons (list (cdr (assoc 10 ent)) e) CableIDCollection))
)
)
(and ANCollection
(Foreach this CableIDCollection
(setq thisPoint (Car this) ent (entget (Cadr this))
theNearestLWPolyline
(vl-sort (mapcar '(lambda (en)
(cons (distance thisPoint
(vlax-curve-getClosestPointTo (Cadr en) thisPoint)) en)) ANCollection)
'(lambda (a b)(< (Car a)(Car b))))
_thePoint (_DistanceFrom thisPoint (Cadr (Car theNearestLWPolyline)))
)
(entmod (subst (Cons 10 _thePoint) (assoc 10 ent) ent))
;; (setq ANCollection (vl-remove (cdr (Car theNearestLWPolyline)) ANCollection))
)
)
)(princ)
)
This section will remove the Polyline closest to the Block from the collection reducing the number of Polylines for evaluation.
(setq ANCollection (vl-remove (cdr (Car theNearestLWPolyline)) ANCollection)) I opted to comment this out and would suggest the user to select by areas instead of the entire drawing at one time.
You can take out the ";" on the comment block, but it will have an adverse effect if the "AccessNet" cables are one continuous polyline, but the program will be slower as the number of selection increase.
HTH
I was thinking a routine could simply apply Osnap ENDpoint to the insertion points of Blocks to find the Polyline vertex nearby, if they're all within Osnap distance of where they should end up. But the Donut "dots" that are part of the Block are themselves Polylines, and have ENDpoints of their arc segments that I assume might sometimes be closer to the insertion point than the intended Polyline vertex point, so ENDpoint Osnap wouldn't be reliable. So an approach could be to search for a Polyline in the vicinity of a Block's insertion point, using a crossing-window box built around it at some distance that you think will always be enough, and find its nearest vertex.
BUT could you redefine the Block to use CIRCLEs instead of Donut Polylines for those dots? Then there wouldn't be any ENDpoint to Osnap to except for the desired Polyline vertex, which would greatly simplify a routine to do what you want.
@Kent1Cooper wrote:
....
BUT could you redefine the Block to use CIRCLEs instead of Donut Polylines for those dots? Then there wouldn't be any ENDpoint to Osnap to except for the desired Polyline vertex, which would greatly simplify a routine to do what you want.
If the Block is edited that way, for example like this:
then Zoomed out to where I can see all of them, this is all it takes to do it in your sample drawing:
(defun C:B2V (/ ss n blk); = Blocks {to} Vertices
(if (setq ss (ssget "_X" '((2 . "KabelID"))))
(repeat (setq n (sslength ss))
(setq blk (ssname ss (setq n (1- n))))
(setpropertyvalue blk "Position" (osnap (getpropertyvalue blk "Position") "_end"))
); repeat
); if
(prin1)
)
It assumes there aren't other things around that could have closer endpoints than the Polyline vertices to the Block insertion points. The selection filter can be adjusted for other Block names, limited to certain Layers, ask for User selection [such as windowing an area] instead of just finding all such Blocks, etc.
@t_pladet wrote:
How could I change the block though to look like that? could you help me with that? ....
REFEDIT the Block definition. ERASE the Donut Polyline, and draw a CIRCLE [or more than one] in its place, or OFFSET the little one in the middle to some appropriate size(s). You just need to have no ENDpoints in the Block that Osnap can jump to, forcing it to jump to the closest ENDpoint of the path Polyline.
