Align text to a picked point
I kind-of think I understand what you're asking, but can you post an image with some before-and-after illustrations? Also, are you talking about separate commands for the change-the-X and change-the-Y versions, or one command that would change whichever is the greater change [similarly to what happens when you draw a Line with ORTHO on]?
Hello
This is an illustration
This is for the "X" alignment.
Sure, I want a separate command for each: X and Y...
@ramimann wrote:
....
I need a code that can align text (from X or Y of insertion point) to "x" or "y" of a picked point. ....
To do so with as many Text objects as you want at once, try this [lightly tested, and without the usual enhancements yet]:
(defun textalign (coord / ss ali n txt txtobj inspt); subroutine used in both commands
(if
(and
(setq ss (ssget '((0 . "TEXT"))))
(setq ali (getpoint (strcat "\nPoint to align Text insertion points at its " coord " position: ")))
); and
(repeat (setq n (sslength ss))
(setq txt (ssname ss (setq n (1- n))))
(command "_.move" txt ""
"_none"
(setq inspt
(if (= (vla-get-Alignment (setq txtobj (vlax-ename->vla-object txt))) 0)
(vlax-get txtobj 'InsertionPoint); then - Left-justified
(vlax-get txtobj 'TextAlignmentPoint); else - other justifications
); if
); setq
"_none"
(list
(car (if (= coord "X") ali inspt)); X coordinate of second point
(cadr (if (= coord "Y") ali inspt)); Y coordinate
); list
); command
); repeat
); if
(princ)
); defun
(defun C:TAX () (textalign "X")); = Text Align at X coordinate
(defun C:TAY () (textalign "Y")); = Text Align at Y coordinate
(vl-load-com); if needed
If Text is of Fit or Aligned justification, it uses the right-end-of-baseline definition point. If you ever use those, and if desired, it could be adjusted to differentiate those justifications from other not-plain-Left justifications, and use the left-end point instead, or the middle of the baseline if that makes sense for your purposes.
It's for plain TEXT only -- accommodations would need to be made if you want to also use it with MTEXT, and/or Attribute Definitions.
@ramimann wrote:
....It only lacks support for Mtext and attributes...
If that's wanted, try this adjustment. Attributes are defined the same way as regular Text in regard to these things, so it's just a matter of allowing them in selection. Mtext has only the InsertionPoint property, regardless of justification, which means lumping all Mtext into a common category with only-Left-justified Text/Attdefs. Minimally tested:
(defun textalign (coord / ss ali n txt txtobj inspt); subroutine used in both commands
(if
(and
(setq ss (ssget '((0 . "*TEXT,ATTDEF"))))
(setq ali (getpoint (strcat "\nPoint to align Text insertion points at its " coord " position: ")))
); and
(repeat (setq n (sslength ss))
(setq
txt (ssname ss (setq n (1- n)))
txtobj (vlax-ename->vla-object txt); [moved earlier instead of nested later]
)
(command "_.move" txt ""
"_none"
(setq inspt
(if
(or
(= (vla-get-ObjectName txtobj) "AcDbMText"); any Mtext
(= (vla-get-Alignment txtobj) 0); Left-justified Text/Attdef
); or
(vlax-get txtobj 'InsertionPoint); then
(vlax-get txtobj 'TextAlignmentPoint); else
); if
); setq
"_none"
(list
(car (if (= coord "X") ali inspt)); X coordinate of second point
(cadr (if (= coord "Y") ali inspt)); Y coordinate
); list
); command
); repeat
); if
(princ)
); defun
(defun C:TAX () (textalign "X")); = Text Align at X coordinate
(defun C:TAY () (textalign "Y")); = Text Align at Y coordinate
(vl-load-com); if needed
Hi , could you please explain step by step how you created this macro. This one you are showing in your video .XY snap. I tried different ways it doesn’t work for me. Thank you.
