Picking a block from a drawing and copying into another
That is because you passed WRONG parameter type to the first argument of CopyObject() method: the argument expect an ARRAY of object, but you passes a SINGLE object of AcadBlockReference
The code should look like something below (whether you may have multiple BlockReferences to be copied or not):
Dim ent As AcadEntity
Dim blk As AcadBlockReference
Dim sourceObjs() As object
Dim i As Integer
Dim copyDwg As AcadDocument
Dim pasteDwg As AcadDocument
Set copyDwg=ThisDrawing
For Each ent In copyDwg.ModelSpace
If TypeOf ent Is AcadBlockReference Then
Set blk = ent
'' Use EffectiveName would be safer, in case the block is dynamic one
If UCase(blk.EffectiveName)="TESTE" Then
Redim Preserve sourceObjs(i)
Set sourceObjs(i)=blk
i = i + 1
End If
End If
Next
'' Only do copying if at least a target block reference is found
If UBound(sourceObjs)>=0 Then
'' Go to the other drawing/ or Open it
Set pasteDwg = ....
copyDwg.CopyObject sourceObjs, pasteDwg.ModelSpace
End If
Well, you DEFINITELY need to pass CopyObjects() an array of object to be copied.
The cause of issue (after passing an array of objects!) very likely is because of opening the paste drawing. Since AutoCAD2015 an breaking change was introduced: switching active drawing (in your case, open the drawing for pasting) would cancel current command. This change would also cancel code execution in most, if not all, cases. So, you need to have the destination drawing per-opened before executing your copying code. Following code works OK with my Acad2018/2020, where I have 2 drawing opened, and one has a block "Teste", whoch is to be copied to another:
Option Explicit
Public Sub CopyTest()
Dim ent As AcadEntity
Dim blk As AcadBlockReference
Dim sourceObjs() As Object
Dim i As Integer
Dim copyDwg As AcadDocument
Dim pasteDwg As AcadDocument
Dim dwg As AcadDocument
For Each dwg In Documents
Select Case UCase(dwg.Name)
Case "DRAWING1.DWG"
Set copyDwg = dwg
Case "DRAWING3.DWG"
Set pasteDwg = dwg
End Select
Next
If copyDwg Is Nothing Then
MsgBox "Source drawing is not open!"
Exit Sub
End If
If pasteDwg Is Nothing Then
MsgBox "Destination drawing is not open!"
Exit Sub
End If
For Each ent In copyDwg.ModelSpace
If TypeOf ent Is AcadBlockReference Then
Set blk = ent
If UCase(blk.EffectiveName) = "TESTE" Then
ReDim Preserve sourceObjs(i)
Set sourceObjs(i) = blk
i = i + 1
End If
End If
Next
If VarType(sourceObjs) <> vbEmpty And UBound(sourceObjs) >= 0 Then
copyDwg.CopyObjects sourceObjs, pasteDwg.ModelSpace
End If
End Sub
Notice that I have a bit code to make sure both source/destination drawings are currently open in AutoCAD. Because I use drawing name to identify them, so, which one is active drawing does not matter when the code execution begins.
If you do want to only open the destination drawing when the source objects are found in source drawing, you may try open the destination drawing in memory only as ObjectDBX document, so the code execution would not be break by active drawing switch.
Well, if you start the process from external app (Excel VBA), you can certainly have both source and destination drawing open in AutoCAD first. I'd imagine the steps would be:
1. User runs Excel macro, which get an existing runing AutoCAD session, or create one (using GetObject()/CreateObjeect());
2. VBA code in Excel opens source drawing, and destination drawing(s) in AutoCAD;
3. VBA Code in Excel load the AutoCAD VBA project and then run the AutoCAD VBA macro to actually do the copying and saving the change to destination drawing(s);
Technically, you can do the copying all with VBA code in Excel, so that you have only one place to manage the code. However, that would slow down the execution significantly; I'd prefer the drawing processing work (copying) run inside AutoCAD as AutoCAD VBA macro.
I am also not fond of having to run 2 apps (Excel and AutoCAD) for such a simple work. I'd prefer do all in AutoCAD VBA. That is, you just need to read data from Excel sheet (if the data is stored as CSV file, the VBA code to read it would be a lot simpler, and running Excel app to reach the data is completely not needed).
Here's the Help topic for the Explode method. As shown, the return object needs to be a variant. If you tried Variant, It should be working. Show your code so we can see what went wrong.
Ed
Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
How to post your code.
@charley.rocha wrote:
Sorry for bothering you with this matter again, but I've been working with this project as I told you previously, and now I'm starting to write the real code. Almost everything is working fine: I'm able to open a template drawing, copy the correct block and place it on the final drawing. After that I can even move the block to its correct location. However, I just realized that I need to explode the blocks after pasting them. I tried
destObjs(0).Move blk.InsertionPoint, newPoint destObjs(0).Explode
with no success. The blocks remain as blocks.
Do you have any idea of what could possibly be going on here?
Your code (destObjs(0).Explode) should work, and I bet it must have worked and you just did not noticed:
AcadBlockReference.Explode() method works a bit differently from command "EXPLODE" - besides generate all the entities in the block definition in the same space as the block reference by "exploding it", the original block reference REMAINS UNCHANGED. It is up to you as programmer to decide you want to delete or not. The command "EXPLODE" combines the 2 steps in one (i.e. the block reference is removed after exploding API call).
You can verify it after AcadBlockReference.Explode() call without deleing the original block rerference: in AutoCAD editor, you should find all the block component entities and the block reference itself.
Yes, you would only need to set explodedObjs if you planned to do something with them after exploding.
Ed
Did you find this post helpful? Feel free to Like this post.
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
How to post your code.
