Looking for a way in mel to constrain a transform to a vert.

[malcolm_341]

Hi there, I'm looking for a way to constrain a locator or other transform to a vert, I've tried all the constraints, but those only work on meshes that have non-overlapping UVs, I need this to work on meshes with overlapping UVs. Is there some secret mel trick to get the vert to drive the locator's transform?

[mcw0]

Did you look at the emitter approach?  Maybe that's a simpler solution?  I do the edge approach all the time so I think nothing of it.  🙂 

[mcw0]

There's also "surfaceAttach" under Maya muscles that will allow you to constrain to a point on a mesh.  Can't remember if that one uses UV values or not.  My edge approach is UV independent.

[mcw0]

While you can't parent a locator under a vert, you can parent it under a curve.  That's what happens when you intersect curves.  Maya places a locator at the intersection location.  And that locator is parented under the curve shape node.  I've never had to do that myself so I'm not familiar with what's involved.  But since Maya does it, it can be done.  Just another option.

[malcolm_341]

I'm writing code to detect if the locator lands in the wrong spot on the motion path, hopefully I don't run into any other unforeseen issues.

[mcw0]

that depends on how the motion path is created...the start and end frames and the current frame on the timeline.  That's why I think the pointOnCurveInfo node is a better approach.

[malcolm_341 · Accepted solution]

I got it working with the curve method, it's a bit of code, but it works and it's robust because no UVs needed.

I think I also need to put some error checking in for if the edge is actually attached to the initial vert you select. Thanks for your help.

//Store vert position
float $vertPOS[];
MoveTool;
$vertPOS = `manipMoveContext -q -position "Move"`;

//Convert to edges
ConvertSelectionToEdges;
string $edges[] = `ls -sl -fl`;
select $edges[0];
//Check if edge has correct vert attached to it

string $curveAttach[] = `polyToCurve -form 0 -degree 1`;
CreateLocator;
string $locator[] = `ls -sl`;
scale 10 10 10;
select $curveAttach;
select -add $locator;
pathAnimation -fractionMode true -follow true -followAxis x -upAxis y -worldUpType "vector" -worldUpVector 0 1 0 -inverseUp false -inverseFront false -bank false -startTimeU 0 -endTimeU 1;
select $locator;

//Find motion path name
string $motionPath[] = `listConnections -type motionPath`;
//print ($motionPath[0] + "_uValue");
selectKey -k -t 0 -t 1 ($motionPath[0] + "_uValue");
cutKey -clear;

//Store locator position
float $locatorPOS[];
$locatorPOS = `manipMoveContext -q -position "Move"`;
//If locator lands at wrong end of curve move it back
if ($vertPOS[0] != $locatorPOS[0] || $vertPOS[1] != $locatorPOS[1] || $vertPOS[2] != $locatorPOS[2])
{
    float $uValue = `getAttr ($motionPath[0] + ".uValue")`;
    if ($uValue == 0)
    {
        setAttr ($motionPath[0] + ".uValue") 1;        
    }
    
    else
    {
        setAttr ($motionPath[0] + ".uValue") 0;   
    }
}

[mcw0]

Glad it's working for you.  Here are some pointers to streamline your code.

With the vertex selected, you can get the edges with the following:

string $edges[] = ls("-flatten", `polyListComponentConversion -fv -te`);

This will alleviate the need to verify that the edge is attached to the curve since you are converting the vertex to edges.

Cast the motion path as a variable at the time of creation (saves looking for a motion path later):

string $mp = `pathAnimation....`;

Since you created the motionPath with "pathAnimation", there will definitely be an animCurve attached.  So...

delete `listConnections -s 1 -d 0 -type "animCurve" ($mp+".uValue")`;

[malcolm_341]

My test for if the locator lands at the wrong spot would sometimes fail even if the float value of the locator and vert were exactly the same? I think this is a bug, the way I think I've gotten around it was to toggle the uValue of the motion path even if it was in the right spot adden to the code above

     //Refresh locator position to fix bug below
        float $uValue = `getAttr ($motionPath[0] + ".uValue")`;
        if ($uValue == 0)
        {
            setAttr ($motionPath[0] + ".uValue") 1;
        }
        else
        {
            setAttr ($motionPath[0] + ".uValue") 0;
        }

        //Store locator position
        $locatorPOS = `manipMoveContext -q -position "Move"`;
        //If locator lands at wrong end of curve move it back
        if ($vertPOS[0] != $locatorPOS[0] || $vertPOS[1] != $locatorPOS[1] || $vertPOS[2] != $locatorPOS[2])
        {
            float $uValue = `getAttr ($motionPath[0] + ".uValue")`;
            if ($uValue == 0)
            {
                setAttr ($motionPath[0] + ".uValue") 1;        
            }
    
            if ($uValue == 1)
            {
                setAttr ($motionPath[0] + ".uValue") 0;   
            }
            print "Not the same;";
        }

[malcolm_341]

Oh does the point on curve make it zero or one always rather than part of the curve length?

[mcw0]

If you'll note on the curve that was converted from an edge, the minMaxRange is 0:1.  So it's either at the start of the curve or at the end that the locator will be at the desired vertex.  And float values are tricky.  When checking to see which end of the curve you want, just get the minimum distance between the locator and the 2 vertices.  The larger distance will obviously be the wrong vertex.