iLogic, move title block to top right (or other) corner

[Tigerpirro]

Basically i am setting up a code that lets me quickly swap between different borders, sizes and title blocks.

However i cant get my function for choosing in which corner i want the title block in to work.

I am guessing that I am missing something obvious since it is a built in command.

I tried 

SyntaxEditor Code Snippet

ThisDrawing.ActiveSheet.TitleBlock.SetSpacingToCorner("0","0", SheetCorner.TopRight)

Suggestions?

[MechMachineMan]

Don't know where you are finding this information... but according to my testing

ThisDrawing.ActiveSheet.Titleblock returns a string rather than a titleblock object

SyntaxEditor Code Snippet

ThisApplication.ActiveDocument.ActiveSheet.TitleBlock.Location = TitleBlockLocationEnum.kTopRightPosition

however this only a read-only call.

So you might just have to re-add the titleblock with it in the proper location, or try using the .Position method. 

[Tigerpirro]

I wanted to call the function that controls this built in functionality.

[SašoPrijatelj]

Hello,

try this on a document, that already has a title block inserted:

Dim oDrawDoc As DrawingDocument
oDrawDoc = ThisApplication.ActiveDocument

'reference to existing title block
Dim oTitleBlock As TitleBlock
oTitleBlock = oDrawDoc.Sheets(1).TitleBlock

'reference to definition of existing title block
Dim oTitleBlockDef As TitleBlockDefinition
oTitleBlockDef = oTitleBlock.Definition

'delete existing title block
oTitleBlock.Delete

'insert title block to a new location: kBottomLeftPosition, kBottomRightPosition, kTopLeftPosition, kTopRightPosition
oDrawDoc.Sheets(1).AddTitleBlock(oTitleBlockDef, TitleBlockLocationEnum.kTopLeftPosition)

[asiteur]

Indeed, readding the titleblock in the correct position seems to be the only way.

I have tried to map the titleblock using the Transformation property, but eventhough it is not read-only the titleblock doesn't seem to respond to any transformation.

[MechMachineMan]

@SašoPrijatelj's method works, but without extra coding, will delete all Prompted Entry fields and will fail to reinsert a title block with prompted entries.

[SašoPrijatelj]

This example will also carry over specific prompted entries. In this case there are 2 and are named <Pr1> and <Pr2>.

Dim oDrawDoc As DrawingDocument
oDrawDoc = ThisApplication.ActiveDocument

'reference to existing title block
Dim oTitleBlock As TitleBlock
oTitleBlock = oDrawDoc.Sheets(1).TitleBlock

Dim sPrompts(1) As String
Dim oTextBox As Inventor.TextBox
Dim sPromptedValue As String

Dim oTextBoxes As Inventor.TextBoxes
 oTextBoxes = oTitleBlock.Definition.Sketch.TextBoxes

For Each oTextBox In oTextBoxes
    sPromptedValue = oTitleBlock.GetResultText(oTextBox)
    'watch for letter case!
    If oTextBox.Text = "<Pr1>" Then
        sPrompts(0) = sPromptedValue
    ElseIf oTextBox.Text = "<Pr2>" Then
        sPrompts(1) = sPromptedValue
    End If
Next

'reference to definition of existing title block
Dim oTitleBlockDef As TitleBlockDefinition
oTitleBlockDef = oTitleBlock.Definition

'delete existing title block
oTitleBlock.Delete

'insert title block to a new location: kBottomLeftPosition, kBottomRightPosition, kTopLeftPosition, kTopRightPosition
oDrawDoc.Sheets(1).AddTitleBlock(oTitleBlockDef, TitleBlockLocationEnum.kTopLeftPosition,sPrompts)

[wtriplett]

Appreciate any help!  I have several different title blocks that need to be in the bottom left or bottom right location.  Is it possible to change the title block position when setting up a sheet as follows: 

'----------------------------------------------------------------------------------------------------
'i need this title block to be bottom right
ElseIf Parameter.Value("SheetSize") = "D" And Parameter.Value("TBStyle") = "VERTICAL" Then 
	ActiveSheet.ChangeSize("D")
	ActiveSheet.Border = "ITI DE VERTICAL"
	ActiveSheet.TitleBlock = "ITI TB VERTICAL"
	
'----------------------------------------------------------------------------------------------------
'i need this title block to be bottom left
ElseIf Parameter.Value("SheetSize") = "D" And Parameter.Value("TBStyle") = "HORIZONTAL" Then 
	ActiveSheet.ChangeSize("D")
	ActiveSheet.Border = "ITI DE HORIZONTAL"
	ActiveSheet.TitleBlock = "ITI TB HORIZONTAL"
	
'----------------------------------------------------------------------------------------------------

[A.Acheson]

@wtriplett 

Looking at the code you posted I don't believe there is an ilogic way to position the titleblock. You need to use the API and reference the  Titleblockdefinitions  contained in the sheet and then pick one definition by name to add to the active sheet. 

I found the information in the below links. I found the API online help very useful when you look at the samples. The snippets can be a bit tricky if they have not been used in a context. 

Title Block Definitions
https://adndevblog.typepad.com/manufacturing/2013/01/deleting-the-titleblockdefinition-from-a-sheet....
https://help.autodesk.com/view/INVNTOR/2021/ENU/?guid=GUID-389C7661-CA66-437B-95A4-28F2A11A7A57
TitleBlock Positioning
https://help.autodesk.com/view/INVNTOR/2021/ENU/?guid=GUID-0D142B83-F651-409E-8299-BC9D5BB0BF4C

' Set a reference to the drawing document.
' This assumes a drawing document is active.
  
Dim oDrawDoc As DrawingDocument
oDrawDoc = ThisApplication.ActiveDocument

'reference to Active Sheet
Dim oSheet As Sheet
oSheet = oDrawDoc.ActiveSheet

'reference to existing title block
Dim oTitleBlock As TitleBlock
oTitleBlock = oSheet.TitleBlock

'reference to adefinitions of Sheet title blocks by Name
Dim oTitleBlockDefs As TitleBlockDefinitions
oTitleBlockDefs = oDrawDoc.TitleBlockDefinitions

' Obtain a reference to the desired border defintion.
Dim oTitleBlockDef As TitleBlockDefinition


' Check to see if the sheet already has a title block and delete it if it does.
    If Not oTitleBlock Is Nothing Then
        oTitleBlock.Delete
    End If

	 '----------------------------------------------------------------------------------------------------
'i need this title block to be bottom right
If Parameter.Value("SheetSize") = "D" And Parameter.Value("TBStyle") = "VERTICAL" Then 
	ActiveSheet.ChangeSize("D")
	ActiveSheet.Border = "ITI DE VERTICAL"
	'ActiveSheet.TitleBlock = "ITI TB VERTICAL"
	
	'Set Titleblock definition by name
	oTitleBlockDef = oTitleBlockDefs.Item("ITI TB VERTICAL")
	'insert title block To a New location: kBottomLeftPosition, kBottomRightPosition, kTopLeftPosition, kTopRightPosition
	oSheet.AddTitleBlock(oTitleBlockDef, TitleBlockLocationEnum.kBottomRightPosition)
'----------------------------------------------------------------------------------------------------
'i need this title block to be bottom left
ElseIf Parameter.Value("SheetSize") = "D" And Parameter.Value("TBStyle") = "HORIZONTAL" Then 
		ActiveSheet.ChangeSize("D")
		ActiveSheet.Border = "ITI DE HORIZONTAL"
		'ActiveSheet.TitleBlock = "ITI TB HORIZONTAL"
		
		'Set Titleblock definition by name
		oTitleBlockDef = oTitleBlockDefs.Item("ITI TB HORIZONTAL")
		'insert title block To a New location: kBottomLeftPosition, kBottomRightPosition, kTopLeftPosition, kTopRightPosition
		oSheet.AddTitleBlock(oTitleBlockDef, TitleBlockLocationEnum.kBottomLeftPosition)
End If

Any questions let me know.