IGES Export Options

[Raider_71]

Hi, what would the options for "Spline Fit Accuracy" and "Include Sketches" be when exporting Iges files?

This is what is in the help file, but it's not including the two new options added since...

oOptions.Value("GeometryType") = 1
' 0 = Surfaces, 1 = Solids, 2 = Wireframe

oOptions.Value("SurfaceType") = 0
' 0 = 143(Bounded), 1 = 144(Trimmed)

' To set other translator values:
oOptions.Value("SolidFaceType") = 0
' 0 = NURBS, 1 = Analytic

Thanks

[WCrihfield · Accepted solution]

Hi @Raider_71.  Here is a self help tool you can use for those types of situations.  I use this fairly often for helping others with these types of questions.  It uses the iLogic Logger, which became available in 2019 I believe, so if you have an earlier version, you may need to use an alternate means of writing out or showing the results.

Sub Main
	Dim oDoc As Document = ThisDoc.Document
	Dim oTranslator As TranslatorAddIn
	For Each oAppAddin As ApplicationAddIn In ThisApplication.ApplicationAddIns
		If oAppAddin.DisplayName = "Translator: IGES" Then
			oTranslator = oAppAddin
		End If
	Next
	LogTranslatorOptions(oDoc, oTranslator)
End Sub

Sub LogTranslatorOptions(oDocToExp As Document, oTransAddIn As TranslatorAddIn)
	Dim oContext As TranslationContext = ThisApplication.TransientObjects.CreateTranslationContext
	oContext.Type = IOMechanismEnum.kUnspecifiedIOMechanism
	Dim oOptions As NameValueMap = ThisApplication.TransientObjects.CreateNameValueMap
	If oTransAddIn.HasSaveCopyAsOptions(oDocToExp, oContext, oOptions) Then
		Dim oItem As Integer = 1
		For Each oPair In oOptions
			Logger.Trace("Option Name =   " & oOptions.Name(oItem) & vbCrLf & "Option Value =   " & oOptions.Value(oOptions.Name(oItem)).ToString)
			oItem = oItem + 1
		Next
	End If
End Sub

I'm using 2022.4, and got the following results:

INFO| 1: >>---------------------------
TRACE|Option Name = IncludeSketches
Option Value = True
TRACE|Option Name = GeometryType
Option Value = 1
TRACE|Option Name = SurfaceType
Option Value = 0
TRACE|Option Name = SolidFaceType
Option Value = 0
TRACE|Option Name = export_fit_tolerance
Option Value = 0.001