Select assembly constraints to rename them with VBA

[Anonymous]

Hi everybody,

I am trying to write a macro in VBA that should do the following:

1) The user selects a specific assembly constraint in the browser using the mouse

2) the user runs the macro and the macro renames the selected constraint using the displaynames of occurrenceone and occurencetwo.

The only Problem here is that I cannot get the API to recognize the selected constraint like using ComponentOccurrence for the Parts.

Is there any method or idea I could use to implement it? Something like ConstraintOccurrence or an alternative way to do that?

Thank you very much!

[JaneFan]

Hello @Anonymous, 

We can get assembly constraints via API in this way: 

Dim oDoc As AssemblyDocument
Set oDoc = ThisApplication.ActiveDocument
Dim oCons As AssemblyConstraint
Set oCons = oDoc.ComponentDefinition.Constraints.Item(1)

'Or go over each constraint

'For Each oCons In oDoc.ComponentDefinition.Constraints

[smilinger]

I don't think you need to do this, you can set the option in Application Settings, Assembly to show the information you need automatically.

[Anonymous]

Hello @JaneFan,

thank you, but in your example it is not possible to use the mouse to select the constraint. What I mean is using the mouse to select the constraint like you can do with ComponentOccurrence to select components.

[Anonymous]

@smilinger I cannot find the Options you metioned . Could you be please more specific?

[smilinger]

In Application Options, Assembly Tab, Select "Display component names after relationship names".

[Anonymous]

Thank you,

it Looks better. But it is still not what I want to have. As you can see, we rename out browser components with large names. This produces that the names for the constraint become too large. I just Need the Information contained in titel (in red on the Image). And just for certain constraints. This is why I want that the user first selects the desired contraint to be renamed with the mouse and then runs the macro. But it Looks like at the Moment it is not possible to do it from the Inventor API.

[smilinger · Accepted solution]

Try this in iLogic:

Dim doc As AssemblyDocument = ThisDoc.Document
Dim comp As AssemblyComponentDefinition = doc.ComponentDefinition
For Each constrt As AssemblyConstraint In doc.SelectSet
	Dim constrtType As String
	Select Case constrt.Type
		Case ObjectTypeEnum.kFlushConstraintObject
			constrtType = "Flush"
		Case ObjectTypeEnum.kMateConstraintObject
			constrtType = "Mate"
		Case ObjectTypeEnum.kAngleConstraintObject
			constrtType = "Angle"
		Case ObjectTypeEnum.kInsertConstraintObject
			constrtType = "Insert"
		Case ObjectTypeEnum.kTangentConstraintObject
			constrtType = "Tangent"
		Case ObjectTypeEnum.kSymmetryConstraintObject
			constrtType = "Symmetry"
		Case Else
			constrtType = "Constraint"
	End Select
	
	constrt.Name = constrtType & " (" & iProperties.Value(constrt.OccurrenceOne.Name, "Summary", "Title") _
	& ", " & iProperties.Value(constrt.OccurrenceOne.Name, "Summary", "Title") & ")"
Next

[Anonymous]

@smilinger

That works :D!

Thank you!!!

[smilinger]

The last line of code should be:

constrt.Name = constrtType & " (" & iProperties.Value(constrt.OccurrenceOne.Name, "Summary", "Title") _
	& ", " & iProperties.Value(constrt.OccurrenceTwo.Name, "Summary", "Title") & ")"