Recording keyboard sequences

[mjohnson]

Is it possible to record keyboard sequences to shorten a repeated series of mouse clicks and keyboard entries that I find I am doing over and over throughout the work day?  I was able to do this with Creo software and was hoping it is available for Inventor.

[fidel.makatiaD5W7V]

Hi @Anonymous , please have a look at the Inventors docs on events

Inventor 2022 Help | Triad Events | Autodesk

Inventor 2022 Help | Using measure events | Autodesk

There is a lot you can do with interactive events in Inventor 

[mjohnson]

Both of them worked!  Thankyou for taking the time to put those together.

Another issue I am running into is on bent parts.  A lot of our sheet metal parts have flanges so d0 or d1 may not capture the overall length in the folded model.  To solve this I go to the flat pattern, create a sketch on the surface and add two dimensions(to capture the over all lengths).  In the parameter dialog box they appear as d0 and d1.  I then go back to the folded model parameter dialog box and make sure to rename d0 and d1 to something different.  When I run the rule it cannot find d0 or d1 in the "Flat Pattern" state for some reason.  Probably because there are separate parameters, one set for the folded Model, and another for the flat pattern but I'm not sure.

I can solve this by unfolding the sheet metal part, adding the dimensions, and refolding it in the "Folded Model" state but just adds a couple extra steps but no a big deal.

This has been a great help!  You have been a great help.

Is there an easy way to save this rule into Inventor to avoid having to cut and paste each time I need to run it?

[cadman777 · Accepted solution]

If it's a VBA macro, you just need to add it to any of your tool pallets.

You can make a custom icon or substitute any icon you find, as long as it's 16x16 (small) or 32x32 (...

To make it easy, I just do a search for all the icons on my hard drive and pick the ones I think will remind me of the macro/rule it represents. Just open it in Paint and save it as a bmp file. Then you can use it as a macro button. But you first may have to make the background magenta color so it shows up right in the tool bar.

If it's an iLogic rule, you can run it from a VBA macro.

But first you have to save your iLogic rule as an External Rule in a txt file.

Then just add it to your tool pallets.

Here'a some code that may work for you (forgot where I found it):

Public Sub IDW_FP_DIM_SELECT()
'From https://www.cadlinecommunity.co.uk/hc/en-us/articles/115000859309
Dim addIn As ApplicationAddIn
Dim addIns As ApplicationAddIns
Set addIns = ThisApplication.ApplicationAddIns
    For Each addIn In addIns
        If InStr(addIn.DisplayName, "iLogic") > 0 Then
                        addIn.Activate
            Dim iLogicAuto As Object
            Set iLogicAuto = addIn.Automation
            Exit For
        End If
    Next
Debug.Print addIn.DisplayName
 
Dim RuleName1 As String
EXTERNALrule = "external_rule_filename" 'this is where you put the filename of your EXTERNAL rule
Dim RuleName2 As String
INTERNALrule = "internal_rule_filename" 'this is where you put the filename of your INTERNAL rule
 
  Dim oDoc As Document
 
  Set oDoc = ThisApplication.ActiveDocument
  If oDoc Is Nothing Then
    MsgBox "Missing Inventor Document"
    Exit Sub
  End If
 
iLogicAuto.RunRule oDoc, INTERNALrule 'for internal rule
iLogicAuto.RunExternalRule oDoc, EXTERNALrule 'for external rule

End Sub

You can also go to the Autodesk app store. You may find something that works in there.

I put most of my rules on the AddIns tab, b/c it's pretty much empty and has lots of room to add tool bar buttons.

Also, you know where they are when you need them. And you put you rules on the AddIns tab in the type of file they will be used in (assembly, part, drawing).

[mjohnson]

Awesome, thanks for your help!

[mjohnson]

Hi cadman777,

If I wanted the code to export "do" and "d1" from the flat pattern parameters how would the code appear.  When I run the code below it goes to the folded model parameters and exports d0 and d1 from there?

In order to get the correct overall dimensions with sheet metal parts that have a flange I create a sketch(see screen shot below) on the flat pattern and place the d0 and d1 dimensions.  I need the code to pull it from here and not from the folded model parameters.  I'm guessing the code change would be in the area where the text is green below but I'm not sure....

Any suggestions?

Sub Main
DocType = ThisApplication.ActiveDocument.DocumentType

If DocType = DocumentTypeEnum.kAssemblyDocumentObject Then
MessageBox.Show("it's an assembly file - Exiting!", "iLogic")

ElseIf DocType = DocumentTypeEnum.kPartDocumentObject Then

'Get the document we want to work with
Dim partDoc As PartDocument
partDoc = ThisApplication.ActiveDocument
Try
'Pass document and parameter to sub routine
ParameterExport(partDoc, "Thickness")
ParameterExport(partDoc, "do")
ParameterExport(partDoc, "d1")
Catch
MessageBox.Show("One of the parameters is missing", "iLogic")
End Try
' Get the User Defined property set.
Dim UserDefinedPropSet As PropertySet
UserDefinedPropSet = partDoc.PropertySets.Item("Inventor User Defined Properties")

' Get the Size property.
Dim SizeProp As Inventor.Property
Try
SizeProp = UserDefinedPropSet.Item("Size")
Catch
' Failed to get the property, which means it doesn't exist so we'll create it.
UserDefinedPropSet.Add("", "Size")
SizeProp = UserDefinedPropSet.Item("Size")
End Try

'Add an expression to custom property
SizeProp.Expression = _
"=<Thickness> X <d1> X <d0> LG."
MessageBox.Show("Size: " & SizeProp.Value, "iLogic- Success iProp Updated")
ElseIf DocType = DocumentTypeEnum.kDrawingDocumentObject Then
MessageBox.Show("it's a drawing file - Exiting!", "iLogic")
End If
End Sub

Sub ParameterExport(oPartDoc As Document, oParam As String)
'Export parameters as custom iproperty (Tick the box)
Dim param As Inventor.Parameter
Dim oFormat As CustomPropertyFormat
param = oPartDoc.ComponentDefinition.Parameters.Item(oParam)
param.ExposedAsProperty = True
'Carry out formatting
oFormat = param.CustomPropertyFormat
oFormat.PropertyType = Inventor.CustomPropertyTypeEnum.kTextPropertyType
oFormat.Units = "in"
oFormat.ShowUnitsString = True
oFormat.Precision = Inventor.CustomPropertyPrecisionEnum.kSixteenthsFractionalLengthPrecision
End Sub

[A.Acheson]

You can store this rule as an external rule, I suspect you have stored it as an internal rule in the document. The external rule is visible to all documents. This post here goes through how to set this up. You will be asked to provide a disk location to save the rule either save it local or on a shared drive. When the rule is done I usually add it to a global form as a button this way it is readily accessible and doesn't involve running it through a vba macro and creating buttons on the browser. See attached image 

The extra screen shots showed more of your workflow. I can see you want to get the size of sheetmetal parts. Previously we have chosen to look at the manual entry parameters you use to create the part. There is actually built in properties that we can use to get the flat pattern size once it has been created. So as long as the parts are all created on the same planes and are consistent it should come out accurate. If however parts are derived or have inconstant flat pattern orientation the values could have some errors in there so worth double checking. Another think to check is if the documents all have constant units. 

This is the built in property to retrieve the flat pattern sizes after the flat pattern has been created. 

SheetMetal.FlatExtentsLength

SheetMetal.FlatExtentsWidth

SheetMetal.FlatExtentsArea

 In the  rule below I have chosen to created the flat pattern even on non folded parts as it will aid in retrieving the size without much user input. However you could choose to revert to your original d0,d1 method if you don't like this approach. You would need to just change the filter statements around. This post here was helpful to prepare this rule an dis also a good discussion.

Sub Main
DocType = ThisApplication.ActiveDocument.DocumentType

If DocType  = DocumentTypeEnum.kAssemblyDocumentObject Then
	MessageBox.Show("it's an assembly file - Exiting!", "iLogic")
 
ElseIf DocType = DocumentTypeEnum.kPartDocumentObject Then
 
	'Get the document we want to work with
	Dim partDoc As PartDocument
	partDoc = ThisApplication.ActiveDocument
               
                 ' Call the sub routine to get sheetmetal part sizes
                 SheetmetalProcessing (partDoc)
                
       'Pass document and parameter to sub routine to export parameters
	Try
	ParameterExport(partDoc, "extents_length")
	ParameterExport(partDoc, "extents_width")
	ParameterExport(partDoc, "Thickness")
	Catch
	MessageBox.Show("One of the parameters is missing", "iLogic")
	End Try

	' Get the User Defined property set.
	Dim UserDefinedPropSet As PropertySet
	UserDefinedPropSet = partDoc.PropertySets.Item("Inventor User Defined Properties")

	' Get the Size property.
	Dim SizeProp As Inventor.Property
	Try
	SizeProp = UserDefinedPropSet.Item("Size")
	Catch
	' Failed to get the property, which means it doesn't exist so we'll create it.
	UserDefinedPropSet.Add("", "Size")
	SizeProp = UserDefinedPropSet.Item("Size")
	End Try

	'Add an expression to custom property
	SizeProp.Expression = _
	                     "=<Thickness> X <extents_width> X <extents_length> LG."
	
	MessageBox.Show("Size: " & SizeProp.Value, "iLogic- Success iProp Updated")

ElseIf DocType = DocumentTypeEnum.kDrawingDocumentObject Then
	MessageBox.Show("it's a drawing file - Exiting!", "iLogic")
End If
End Sub

Sub SheetmetalProcessing(oPartDoc as Document)

'See if this part is a sheetmetal part
If oPartDoc.SubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then
      Dim oDef As SheetMetalComponentDefinition 
      oDef = oPartDoc.ComponentDefinition
      
      'Add parameters needed to store flat pattern sizes
       AddParameters (oPartDoc)

       If oDef.HasFlatPattern = False
           'Create flat pattern
            oDef.Unfold
            'Return to folded part
            oDef.FlatPattern.ExitEdit  
        End If
        'After flat pattern creation get size of flat pattern
         Parameter("extents_length") = SheetMetal.FlatExtentsLength
         Parameter("extents_width")  = SheetMetal.FlatExtentsWidth
End If

End Sub

Sub AddParameters(oPartDoc as Document)

'Get reference to reference parameters
Dim oRefParams As ReferenceParameters 
oRefParams = oPartDoc.ComponentDefinition.Parameters.ReferenceParameters

Dim extents_length, extents_width,  As ReferenceParameter

'Create Parameters
Try
oRefParam = oPartDoc.ComponentDefinition.Parameters("extents_length")
Catch 	
'If the parameter was not found, then create a new one.
oRefParam = oRefParams.AddByExpression(0, "in","extents_length")
End Try	

Try
oRefParam = oPartDoc.ComponentDefinition.Parameters("extents_width")
Catch 	
'If the parameter was not found, then create a new one.
oRefParam = oRefParams.AddByExpression(0, "in","extents_width") 
End Try
End Sub

Sub ParameterExport(oPartDoc As Document, oParam As String)
'Export parameters as custom iproperty (Tick the box)
Dim param As Inventor.Parameter
Dim oFormat As CustomPropertyFormat
param = oPartDoc.ComponentDefinition.Parameters.Item(oParam)
param.ExposedAsProperty = True
'Carry out formatting
oFormat = param.CustomPropertyFormat
oFormat.PropertyType = Inventor.CustomPropertyTypeEnum.kTextPropertyType
oFormat.Units = "in"
oFormat.ShowUnitsString = True
oFormat.Precision = Inventor.CustomPropertyPrecisionEnum.kSixteenthsFractionalLengthPrecision
End Sub

[mjohnson]

Thankyou for sending the code.

It seems to be getting hung up on line 79, see below.

[A.Acheson]

 Whoops, I left a comma in there by mistake. Please remove comma so it looks like the below line. I haven't tested the code as a whole so hoping it works your end. 

Dim extents_length, extents_width As ReferenceParameter

[mjohnson]

Sorry to keep bothering you.  This code will be a tremendous help for us wants it works.  Thank you for your time and effort.  I will be studying up on this when time allows.

I removed the comma and ran it again I received the error message below

[A.Acheson]

No problem, I didn’t get to test that so hopefully no unforeseen cases would be found. Could you possibly attach the more info error message box. It provides a little more info on what might have caused the issue. Did any of the Parameters get created? How far do you think the rule got? Was it ran on a sheetmetal part? 

[mjohnson]

It was run on a sheet metal part.

It looks like "extents_length" and extents_width" were created. 

I'm not able to tell how far the code got.

Below shows the "More Info" error box message.

Thanks.

[A.Acheson]

There was a few things wrong. The reference parameters used cannot be modified once created they can only be delete and added. If you want to modify that value it can be added as a user parameter. Also the flat pattern units  were being added as system units and not document  units. Seems to be all working now.

Here is the working code.

Sub Main
DocType = ThisApplication.ActiveDocument.DocumentType

If DocType  = DocumentTypeEnum.kAssemblyDocumentObject Then
	MessageBox.Show("it's an assembly file - Exiting!", "iLogic")
 
ElseIf DocType = DocumentTypeEnum.kPartDocumentObject Then
 
	'Get the document we want to work with
	Dim partDoc As PartDocument
	partDoc = ThisApplication.ActiveDocument
         'See if this part is a sheetmetal part
	If partDoc.SubType = "{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then      
	    'Call the sub routine to get sheetmetal part sizes
	     SheetmetalProcessing(partDoc)
	Else
		MessageBox.Show("Not a sheetmetal file - Exiting!", "iLogic")
	End If
ElseIf DocType = DocumentTypeEnum.kDrawingDocumentObject Then
	MessageBox.Show("it's a drawing file - Exiting!", "iLogic")
End If
End Sub

Sub SheetmetalProcessing(oPartDoc As Document)

      Dim oDef As SheetMetalComponentDefinition 
      oDef = oPartDoc.ComponentDefinition
   
       If oDef.HasFlatPattern = False
           'Create flat pattern
            oDef.Unfold
			 'Add parameters needed to store flat pattern size
            'Return To folded part
            oDef.FlatPattern.ExitEdit 
			
			AddParameters (oPartDoc)
      End If
     
		'Pass document and parameter to sub routine to export parameters
	Try
	ParameterExport(oPartDoc, "FlatPatternLength")
	ParameterExport(oPartDoc, "FlatPatternWidth")
	ParameterExport(oPartDoc, "Thickness")
	Catch
	MessageBox.Show("One of the parameters is missing", "iLogic")
	End Try

	' Get the User Defined property set.
	Dim UserDefinedPropSet As PropertySet
	UserDefinedPropSet = oPartDoc.PropertySets.Item("Inventor User Defined Properties")

	' Get the Size property.
	Dim SizeProp As Inventor.Property
	Try
	 SizeProp = UserDefinedPropSet.Item("Size")
	Catch
'			' Failed to get the property, which means it doesn't exist so we'll create it.
		UserDefinedPropSet.Add("", "Size")
		SizeProp = UserDefinedPropSet.Item("Size")
	
	End Try
	
	Try
	'Add an expression to custom property
	SizeProp.Expression = _
	                     "=<Thickness> X <FlatPatternWidth> X <FlatPatternLength> LG."
	
	MessageBox.Show("Size: " & SizeProp.Value, "iLogic- Success iProp Updated")
	Catch
		MessageBox.Show("One of the parameters is missing", "iLogic")
	End Try 
	


End Sub


Sub AddParameters(oPartDoc As Document)
Dim oDef As ComponentDefinition
oDef = oPartDoc.ComponentDefinition
'Get reference to reference parameters
Dim oRefParams As ReferenceParameters 
oRefParams = oPartDoc.ComponentDefinition.Parameters.ReferenceParameters

Dim oLength,oWidth As String
oLength = "FlatPatternLength"
oWidth = "FlatPatternWidth"

Dim oW, oL As Boolean
'Check if parameter exists
oL = ParaExist(oLength)
oW = ParaExist(oWidth)

'Because reference parameter is read only the value cannot be changed. Delete and recreate
'Delete parameter if it exists
If oL = True Or  oW = True
On Error Resume Next
	For Each oRefParam As ReferenceParameter In oRefParams
		If oRefParam.Name = oLength Or oRefParam.Name = oWidth Then
			oRefParam.Delete
		End If	
	Next
End If

'https://forums.autodesk.com/t5/inventor-ilogic-api-vba-forum/automated-flat-pattern-dimensions/m-p/9778601#M116522
Dim UoM As UnitsOfMeasure = oPartDoc.UnitsOfMeasure
'Convert from Database length units to length units of document
Dim SheetMetalLength As Double = UoM.ConvertUnits(oDef.FlatPattern.Length, UnitsTypeEnum.kDatabaseLengthUnits, UoM.LengthUnits)
Dim SheetMetalWidth As Double = UoM.ConvertUnits(oDef.FlatPattern.Width, UnitsTypeEnum.kDatabaseLengthUnits, UoM.LengthUnits)

oRefParams.AddByExpression(SheetMetalLength,"in", oLength)'"AddByValue" will add the value using system units (cm) even if units specified as inches
oRefParams.AddByExpression(SheetMetalWidth,"in", oWidth)'"AddByExpression" will add the value Using Document units 
End Sub

Function ParaExist(sName) As Boolean
'https://forums.autodesk.com/t5/inventor-forum/verify-if-parameter-exists-ilogic/td-p/3687348
Dim blTag As Boolean
blTag = False

Dim oDoc As PartDocument
oDoc = ThisApplication.ActiveDocument

Dim oCompDef As PartComponentDefinition
oCompDef = oDoc.ComponentDefinition

For i = 1 To oCompDef.Parameters.Count
If oCompDef.Parameters(i).Name = sName Then
blTag = True
Exit For
End If
Next

ParaExist = blTag
End Function

Sub ParameterExport(oPartDoc As Document, oParam As String)
'Export parameters as custom iproperty (Tick the box)
Dim param As Inventor.Parameter
Dim oFormat As CustomPropertyFormat
param = oPartDoc.ComponentDefinition.Parameters.Item(oParam)
param.ExposedAsProperty = True
'Carry out formatting
oFormat = param.CustomPropertyFormat
oFormat.PropertyType = Inventor.CustomPropertyTypeEnum.kTextPropertyType
oFormat.Units = "in"
oFormat.ShowUnitsString = True
oFormat.Precision = Inventor.CustomPropertyPrecisionEnum.kSixteenthsFractionalLengthPrecision
End Sub

[mjohnson]

Wow, that works great!  

On existing sheet metal parts where the flat pattern already exists I discovered I have to delete the flat pattern before before I run the code to get it to work but that's not a big deal at all.  This will be a huge time saver.

In our part descriptions of sheet metal parts that are thinner then 1/4" we use the gauge description.   

an example of a 10GA plate would be.  10GA x 12 1/4 x 20".

Would there be an easy way to add code that would  input the GA size into the part description according to the the material thickness?  The gauges we use are listed below?

(.1793) 7GA

(.1345) 10GA

(.1196) 11GA

(.1046) 12GA

You have been a great help, who do I make my check out to? LOL.  You have been a great help.  Thanks!

[mjohnson]

One other minor detail. 

It many cases with our parts the sheet metal part is revised to change the overall length or width.  It doesn't appear that the part description dimensions update automatically when the width or length changes.  When I changed the overall size of the sheet metal part the  "FlatPatternLength" and "FlatPatternWidth" remains the original length. 

I did find that it will update by deleting the flat pattern and re-running the rule which is not a big deal but adds a few extra steps.

[A.Acheson]

For the existing Flat pattern we need to call the AddParameters (oPartDoc) sub routine if no flattpattern found. Replace top section with bottom section.  

If oDef.HasFlatPattern = False
           'Create flat pattern
            oDef.Unfold
			 'Add parameters needed to store flat pattern size
            'Return To folded part
            oDef.FlatPattern.ExitEdit 
			
			AddParameters (oPartDoc)
      End If

 Add in 

code. 

If oDef.HasFlatPattern = False
           'Create flat pattern
            oDef.Unfold
			 'Add parameters needed to store flat pattern size
            'Return To folded part
            oDef.FlatPattern.ExitEdit 
			
			AddParameters (oPartDoc)
      ElseIf oDef.HasFlatPattern = True Then

AddParameters (oPartDoc)

End If

For the gauge  thickness try the below. Instead of just exporting the thickness value check first what the thickness is then choose to export as fraction above a certain value or display as text if =to a known value. 

(.1793) 7GA

(.1345) 10GA

(.1196) 11GA

(.1046) 12GA

If Parameter("Thickness") >"0.1793"Then

ParameterExport(oPartDoc, "Thickness")

ElseIf Parameter("Thickness") = "0.1793" Then
iProperties.Value("Custom", "Thickness") = "(.1793) 7GA" 
 
’………
End If 

[A.Acheson]

That would be correct. All sizes are coming directly from the flat pattern. This has to be regenerated after each folded/unfolded change. I have this set up in my files so I can push a button called refresh which generates flat pattern and switches back to the model part. It could also be set up to run automatically using event triggers on the save event. So every time you save everything is refreshed and accurate. 

[mjohnson]

Thank you!  it now works on sheet metal parts with existing flat patterns.

In regards to the gauge material, no matter where I insert the code below to call in 7GA when thickness is 0.1793 I receive an error message.  I have no experience with coding so imagine it is something simple. 

Where in the code should this be inserted?   

Would I just repeat that code for the other gauges?

[A.Acheson · Accepted solution]

Here is where you insert, correct for the other gauges follow the pattern of the first ElseIF statement replacing the values. 

	If Parameter("Thickness") >"0.1793" Then

	ParameterExport(oPartDoc, "Thickness")

	ElseIf Parameter("Thickness") = "0.1793" Then
	iProperties.Value("Custom", "Thickness") = "(.1793) 7GA" 
       'ElseIf ..............................Then'  Do a comparison of something if True code inside runs
         'Do Something Here
	End If 

[mjohnson]

Awesome! works great!

Thanks you for your time and effort on this.

[A.Acheson]

No Problem, a bit of learning for you and me. Not quite the macro recording you were after, but a timesaver it can be. If you want to set this up as to run each time a part file saves you can. If it is a normal part it will just exit without doing anything. Just drag the external rule into the events trigger under part and your done.