Link Model state to view representation
Hi @DarthBane55. That sounds like a solid request, and one that might be popular, but I do not know of any built-in way to make it happen. I know that we can copy a DVR (DesignViewRepresentation) to a ModelState, and we can copy a ModelState to a DVR, but that does not create a 'link'. I know we also have a tool for linking ModelStates of an assembly with the ModelStates of top level components. I know we can monitor the events of activating a ModelState and activating a DVR, so we may be able to create an add-in to simulate the behavior you want. If a DVR is activated, then try to find a ModelState with the same name in the same document and activate that too, and the other way around. It might be worth testing that type of functionality with a rule before jumping into creating an add-in though.
The two events are as follows:
ModelStateEvents.OnActivateModelState
RepresentationEvents.OnActivateDesignView
Both give you a reference to the Document involved, and the DVR or ModelState involved.
Wesley Crihfield
(Not an Autodesk Employee)
Just be careful not to create an endless loop if you have the action going both ways (if DVR activated, then activate MS // and if MS activated, then activate DVR). 😉 And if needed, I can post a starter example of how to set up the basic event handler codes, then you can customize it as needed.
Wesley Crihfield
(Not an Autodesk Employee)
OK. Below are two different iLogic rules. The first one is primarily just for research, documentation purposes, because it just writes information to the iLogic Log window when those two events happen. The second example is a very simple working example that listens for a DVR to be activated, then it tries to activate a ModelState with the same name as the DVR (not the other way around right now).
Research example:
Sub Main
If oRepEvents Is Nothing Then oRepEvents = ThisApplication.RepresentationEvents
If oMSEvents Is Nothing Then oMSEvents = ThisApplication.ModelStateEvents
AddHandler oRepEvents.OnActivateDesignView, AddressOf oRepEvents_OnActivateDesignView
AddHandler oMSEvents.OnActivateModelState, AddressOf oMSEvents_OnActivateModelState
End Sub
Dim oRepEvents As RepresentationEvents
Dim oMSEvents As ModelStateEvents
Sub oRepEvents_OnActivateDesignView(Doc As Document, DVR As DesignViewRepresentation, _
BeforeOrAfter As EventTimingEnum, Context As NameValueMap, ByRef HandlingCode As HandlingCodeEnum)
'HandlingCodeEnum is ignored for this event
If BeforeOrAfter = EventTimingEnum.kBefore Then
Logger.Info("Before: DesignViewRepresentation named '" & DVR.Name & "' activated in " & Doc.DisplayName)
If Context.Count = 0 Then
Logger.Info("Zero Context")
Else
For i = 1 To Context.Count
Logger.Info(Context.Name(i) & " = " & Context.Item(i).ToString)
Next
End If
ElseIf BeforeOrAfter = EventTimingEnum.kAfter Then
Logger.Info("After: DesignViewRepresentation named " & DVR.Name & "' activated in " & Doc.DisplayName)
If Context.Count = 0 Then
Logger.Info("Zero Context")
Else
For i = 1 To Context.Count
Logger.Info(Context.Name(i) & " = " & Context.Item(i).ToString)
Next
End If
End If
End Sub
Sub oMSEvents_OnActivateModelState(Doc As Document, MS As ModelState, _
BeforeOrAfter As EventTimingEnum, Context As NameValueMap, ByRef HandlingCode As HandlingCodeEnum)
'no context for this event, and HandlingCodeEnum is ignored also
If BeforeOrAfter = EventTimingEnum.kBefore Then
Logger.Info("Before: ModelState named '" & MS.Name & "' activated in " & Doc.DisplayName)
ElseIf BeforeOrAfter = EventTimingEnum.kAfter Then
Logger.Info("After: ModelState named '" & MS.Name & "' activated in " & Doc.DisplayName)
End If
End SubWorking example:
Sub Main
If oRepEvents Is Nothing Then oRepEvents = ThisApplication.RepresentationEvents
AddHandler oRepEvents.OnActivateDesignView, AddressOf oRepEvents_OnActivateDesignView
End Sub
Dim oRepEvents As RepresentationEvents
Sub oRepEvents_OnActivateDesignView(Doc As Document, DVR As DesignViewRepresentation, _
BeforeOrAfter As EventTimingEnum, Context As NameValueMap, ByRef HandlingCode As HandlingCodeEnum)
'HandlingCodeEnum is ignored for this event
If BeforeOrAfter = EventTimingEnum.kAfter Then
If Doc.ModelStateName <> DVR.Name Then
Dim oMSs As ModelStates = Doc.ComponentDefinition.ModelStates
If oMSs.Count < 2 Then Return
Dim oMS As ModelState = Nothing
Try : oMS = oMSs.Item(DVR.Name) : Catch : End Try
If oMS Is Nothing Then Return
Try : oMS.Activate : Catch : End Try
End If
End If
End SubIf this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
But beware that you should only run a rule like this once per Inventor session, and you will need to close Inventor to get rid of that event handler. These solutions could be developed further to design in an 'exit plan' for removing the event handlers when some other event happens, or some other value changes. And once it is launched, you can't retrieve it or change how it works without restarting Inventor first, because it will be held in session memory.
Wesley Crihfield
(Not an Autodesk Employee)
And here is the opposite simple working example (Activate DVR when ModelState Activated).
But do not run both working examples during the same session of Inventor, or it might cause an endless loop and lock up Inventor.
Sub Main
If oMSEvents Is Nothing Then oMSEvents = ThisApplication.ModelStateEvents
AddHandler oMSEvents.OnActivateModelState, AddressOf oMSEvents_OnActivateModelState
End Sub
Dim oMSEvents As ModelStateEvents
Sub oMSEvents_OnActivateModelState(Doc As Document, MS As ModelState, _
BeforeOrAfter As EventTimingEnum, Context As NameValueMap, ByRef HandlingCode As HandlingCodeEnum)
'no context for this event, and HandlingCodeEnum is ignored also
If BeforeOrAfter = EventTimingEnum.kAfter Then
Dim RepMgr As RepresentationsManager = Doc.ComponentDefinition.RepresentationsManager
If RepMgr.ActiveDesignViewRepresentation.Name <> MS.Name Then
Dim DVRs As DesignViewRepresentations = RepMgr.DesignViewRepresentations
Dim DVR As DesignViewRepresentation = Nothing
Try : DVR = DVRs.Item(MS.Name) : Catch : End Try
If DVR Is Nothing Then Return
Try : DVR.Activate : Catch : End Try
End If
End If
End SubIf this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
