ilogic to change field text in a sketched symbol

[DeepshipEngineering]

I have tried a few things but this seems a bit beyond me, does anyone have some code I could look at to change the value of a prompted entry in a sketched symbol? Inventor 2023

Thanks

[A.Acheson]

Hi @DeepshipEngineering 

@This question is better suited on the Ilogic forum but here is a start point. See this article here on setting the printed entry of Symbol 1.

This is the ilogic code in that article. 

' Set the value for the first sketched symbol
' on the current sheet
Dim oSS As SketchedSymbol
oSS = ActiveSheet.Sheet.SketchedSymbols(1)

Dim oTB As TextBox
For Each oTB In oSS.Definition.Sketch.TextBoxes
  If oTB.Text = "<MyPrompt>" Then
    Call oSS.SetPromptResultText(oTB, "NewValue")
  End If
Next

If you want to find a specific symbol then you can directly reference the symbol object by first looping through all symbols and query the name with an if statement. 

' Find the sketch symbol by name by looping through all symbols 
For Each oSS As SketchedSymbol In ActiveSheet.Sheet.SketchedSymbols(1)
  If oSS.Name = "FindMe" Then
    MessageBox.Show(oSS.Name, “Found Symbol”)
    ‘Do something now with oSS object
  End If
Next

[DeepshipEngineering]

Thanks but I cant seem to get it to work, could you attach a sketched symbol it works on so I can see where I am going wrong?

[A.Acheson]

It sounds like your Property Field name is not matching. 

[DeepshipEngineering]

I think they are correct, (the only thing is the brackets <> but I have tried both ways) Tried a new symbol with your inputs but still no joy.

Can you send a symbol that its working with?

Thanks

[A.Acheson]

The brackets are just the automatically applied formatting. if your Property Field name has none type the text string exactly. Can you share the error message your getting? Can you share images of your symbol prompt box when you manually go to fill it in? Can you share the modified code you have tried.

[jnowel]

this "(1)" is the likely cause of the error.

[DeepshipEngineering]

What does that 1 do?

[jnowel]

oSS = ActiveSheet.Sheet.SketchedSymbols(1)

 Sets oSS as the first item in the SketchSymbols collection.

Removing the (1) makes you to loop thru all the symbols.
I believe the previous post has it as a typo and meant it like this

' Find the sketch symbol by name by looping through all symbols 
For Each oSS As SketchedSymbol In ActiveSheet.Sheet.SketchedSymbols
  If oSS.Name = "FindMe" Then
    MessageBox.Show(oSS.Name, “Found Symbol”)
    ‘Do something now with oSS object
  End If
Next

[DeepshipEngineering]

That works to find my sketched symbol, how do I then change the prompted entry? thanks

[jnowel · Accepted solution]

Combined the posted code earlier.
Should look like this

edit: commented out Exit for 

edit2: should be working now

' Find the sketch symbol by name by looping through all symbols 
Dim oSS As SketchedSymbol

For Each oSS In ActiveSheet.Sheet.SketchedSymbols
	
	If oSS.Name = "FindMe" Then
	'    MessageBox.Show(oSS.Name, “Found Symbol”)
	'    Do something Now With oSS Object
	
	'Map you prompted text value as newValue
	Dim newValue As String
	newValue = "map your value here" 'change to suit
	
	'Scan all textbox then change if match
	Dim oTB As Object
	For Each oTB In oSS.Definition.Sketch.TextBoxes
		If oTB.Text = "<MyPrompt>" Then
			Call oSS.SetPromptResultText(oTB, newValue)
		End If
	Next
	End If
Next

[DeepshipEngineering]

this is the error popping up

Error on Line 14 : 'TextBox' is ambiguous, imported from the namespaces or types 'Inventor, System.Windows.Forms'.
Error on Line 15 : 'oSS' is not declared. It may be inaccessible due to its protection level.

[jnowel]

oops. check edit2 above

[DeepshipEngineering]

Perfect...  I am going to try and and change the "map your value here" to a pop up message text input box unless you have a snippet you can throw in easily?

Im not a programmer but find with a mixture of very welcome help from the forums and a bit of ChatGPT I can muddle through most stuff

[jnowel]

newValue = InputBox("Prompt", "Title", "Default Entry")

[DeepshipEngineering]

@jnowel @A.Acheson 

Thank you so much for your help, got it doing exactly what I wanted

[jnowel]

A different version resulting to a different behavior

'This version asks the newValue once and will be used to all found sketchedsymbol matching the criteria
'Previous version asks everytime the oSS is found, so you can enter a different value (if you just change the newValue inside the for loop

Dim oSS As SketchedSymbol

'Map you prompted text value as newValue
Dim newValue As String
newValue = InputBox("Prompt", "Title", "Default Entry") 'change to suit

For Each oSS In ActiveSheet.Sheet.SketchedSymbols
	
	If oSS.Name = "FindMe" Then
		
		'Scan all textbox then change if match
		Dim oTB As Object
		For Each oTB In oSS.Definition.Sketch.TextBoxes
			If oTB.Text = "<MyPrompt>" Then
				Call oSS.SetPromptResultText(oTB, newValue)
			End If
		Next
	End If

Next