ilogic and work plane visibility

Anonymous · ‎03-23-2012

Is there a way to turn off visibility on work planes using ilogic? Also, is there a way to change an extrusion type from an assymetrical extrusion to a one direction extrusion using ilogic?

CJ.10E-10mm · ‎10-03-2013

Hi Curtis,

I came across your comprehensive reply and wondered if you could help me with a simpler problem please?

I have an assembly made up of identical sub assembles which in turn deploy identical parts. Thus I want to be able to turn off all work planes and just select a particular workplane in a particular sub-assembly to switch on and then off when I have finished with it. Otherwise my model is obscured often by hundreds of identical workplanes. At the moment I am having to select them individually in the Browser.

Thus I want a message box that allows me to turn on the workplane which I have physically selected in my browser. So that after selecting a particular work plane I could then choose either the 'Visible' or 'Invisible' Button in my message Box.

I am not sure if you will receive this message but if you do and you can help I would be most and I do mean MOST grateful.

Thank you.

CJ

niksasa · ‎10-20-2013

Curtis_Waguespack написано:
Hi rjones0215,

Here's another rule that toggles all of the workplanes on/off.

I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
'define document
Dim oDoc As PartDocument
oDoc = ThisDoc.Document
'look at the workplane collection
For Each oWorkPlane In oDoc.ComponentDefinition.WorkPlanes
'toggle all work planes
If oWorkPlane.Visible = True Then
oWorkPlane.Visible = False
ElseIf oWorkPlane.Visible = False Then
oWorkPlane.Visible = True
End If
Next

If you want to turn on the visibility of a specified component?
ThisApplication.CommandManager.Pick (SelectionFilterEnum.kAssemblyOccurrenceFilter, "Select component")

САПР - это инструмент, но только при условии грамотного подхода.

CJ.10E-10mm · ‎10-20-2013

Hi Niksasa,

I am most grateful but can you help further please with this error message:

Error in rule: WorkPlanes, in document: ???.iam

Unable to cast COM object of type 'Inventor._DocumentClass' to interface type 'Inventor.PartDocument'. This operation failed because the QueryInterface call on the COM component for the interface with IID '{29F0D463-C114-11D2-B77F-0060B0F159EF}' failed due to the following error: No such interface supported (Exception from HRESULT: 0x80004002 (E_NOINTERFACE)).

As I am in the top level Assembly with sub assemblies within sub assemblies and I too would like to be able to control all work features; would I be better using Curtis' alternative proposal of:

'get user input
oInput = InputRadioBox("Select work feature visibility:", _
"Turn ON work features for all components", _
"Turn OFF work features for all components", "False", "iLogic")

' set a reference to the assembly component definintion.
Dim oAsmCompDef As AssemblyComponentDefinition
oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition

'Define the open document (top level assembly)
Dim openDoc As Document
openDoc = ThisDoc.Document
'define view rep
Dim oViewRep As DesignViewRepresentation
Dim sVRep as String
'change to something else if Default is used for something already
sVRep = "Default"

'create or activate view rep in the top level assembly
Try
oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
Catch
'create new View Rep
oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
End Try

'create or activate view rep in subassemblies
Dim docFile As Document
For Each docFile In openDoc.AllReferencedDocuments
Dim subDoc As AssemblyComponentDefinition
If docFile.DocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
subDoc = docFile.ComponentDefinition
Try
subDoc.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
Catch
'create new View Rep
subDoc.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
End Try
Else
End If
Next

    'toggle work features in the open document (top level assembly)
    For Each oWorkPlane In openDoc.ComponentDefinition.WorkPlanes
    If oInput = True Then
    oWorkPlane.Visible = True
    ElseIf oInput = False Then
    oWorkPlane.Visible = False
    End If
    Next

    For Each oWorkAxis In openDoc.ComponentDefinition.WorkAxes
    If oInput = True Then
    oWorkAxis.Visible = True
    ElseIf oInput = False Then
    oWorkAxis.Visible = False
    End If
    Next

    For Each oWorkPoint In openDoc.ComponentDefinition.WorkPoints
    If oInput = True Then
    oWorkPoint.Visible = True
    ElseIf oInput = False Then
    oWorkPoint.Visible = False
    End If
    Next

'look at only the subassemblies
Dim subDocFile As Document
For each oCompOcc in oAsmCompDef.Occurrences
If oCompOcc.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
oCompOcc.SetDesignViewRepresentation(sVRep,, True) 'True sets the view rep to be associative
Else
End If
Next

'Look at all of the files referenced in the open document
For Each docFile In openDoc.AllReferencedDocuments

    'toggle work features in the components
    For Each oWorkPlane In docFile.ComponentDefinition.WorkPlanes
    If oInput = True Then
    oWorkPlane.Visible = True
    ElseIf oInput = False Then
    oWorkPlane.Visible = False
    End If
    Next

    For Each oWorkAxis In docFile.ComponentDefinition.WorkAxes
    If oInput = True Then
    oWorkAxis.Visible = True
    ElseIf oInput = False Then
    oWorkAxis.Visible = False
    End If
    Next

    For Each oWorkPoint In docFile.ComponentDefinition.WorkPoints
    If oInput = True Then
    oWorkPoint.Visible = True
    ElseIf oInput = False Then
    oWorkPoint.Visible = False
    End If
    Next
Next
iLogicVb.UpdateWhenDone = True

Although this returns the error of:

Error in rule: WorkPlanes, in document: ???.iam

Unspecified error (Exception from HRESULT: 0x80004005 (E_FAIL))

Can you help further please?

Many, many thanks,

CJ

niksasa · ‎10-21-2013

CJ.10E-10mm написано:
Hi Niksasa,

I am most grateful but can you help further please with this error message:

Error in rule: WorkPlanes, in document: ???.iam

Unable to cast COM object of type 'Inventor._DocumentClass' to interface type 'Inventor.PartDocument'. This operation failed because the QueryInterface call on the COM component for the interface with IID '{29F0D463-C114-11D2-B77F-0060B0F159EF}' failed due to the following error: No such interface supported (Exception from HRESULT: 0x80004002 (E_NOINTERFACE)).
Although this returns the error of:
Error in rule: WorkPlanes, in document: ???.iam
Unspecified error (Exception from HRESULT: 0x80004005 (E_FAIL))

Can you help further please?

Many, many thanks,

CJ

Hi CJ. I'm new to ilogic. So do not know if I can help

PS: sorry for bad english

САПР - это инструмент, но только при условии грамотного подхода.

CJ.10E-10mm · ‎10-21-2013

Not a problem Nicksasa,

Join the club! lol.

CJ

Millehuse · ‎01-07-2014

I'm playing around with sample #4 - cause I often find myself opening old assemblies and being confronted with a million (at least) work planes, axis' odd stuff (see attachment) - and having to turn the visibility off manually - is time consuming.

I know you can hide the work features easilly with "Object Visibility" - but I want to turn the visibility off completely as part of our cleanup routine.

I get the following error though - when using sample #4 iLogic

Error in rule: WP, in document: 810.50.001.IAM

Member not found. (Exception from HRESULT: 0x80020003 (DISP_E_MEMBERNOTFOUND))

System.Runtime.InteropServices.COMException (0x80020003): Member not found. (Exception from HRESULT: 0x80020003 (DISP_E_MEMBERNOTFOUND))
   at Microsoft.VisualBasic.CompilerServices.LateBinding.LateGet(Object o, Type objType, String name, Object[] args, String[] paramnames, Boolean[] CopyBack)
   at LmiRuleScript.Main()
   at Autodesk.iLogic.Exec.AppDomExec.ExecRuleInAssembly(Assembly assem)
   at iLogic.RuleEvalContainer.ExecRuleEval(String execRule)

Edited: Should clarify - it's the modified version of sample #4 - that handles all work features - not just work planes

Added extra error code information

Any thoughts?

Anonymous · ‎06-23-2014

A small addition to make also sketches invisible.

Thanks for the source !!

For Each oSketches In openDoc.ComponentDefinition.Sketches
    If oInput = True Then
    oSketches.Visible = True
    ElseIf oInput = False Then
    oSketches.Visible = False
    End If
    Next

and

    For Each oSketches In docFile.ComponentDefinition.Sketches
    If oInput = True Then
    oSketches.Visible = True
    ElseIf oInput = False Then
    oSketches.Visible = False
    End If
    Next

'get user input
oInput = InputRadioBox("Select work feature visibility:", _
 "Turn ON work features for all components", _
 "Turn OFF work features for all components", "False", "iLogic")

' set a reference to the assembly component definintion.
Dim oAsmCompDef As AssemblyComponentDefinition
oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition

'Define the open document (top level assembly)
Dim openDoc As Document
openDoc = ThisDoc.Document
'define view rep 
Dim oViewRep As DesignViewRepresentation
Dim sVRep As String
'change to something else if Default is used for something already
sVRep = "Default"

'create or activate view rep in the top level assembly
Try     
oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate    
Catch
'create new View Rep
oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
End Try

'create or activate view rep in subassemblies
Dim docFile As Document
For Each docFile In openDoc.AllReferencedDocuments                
Dim subDoc As AssemblyComponentDefinition
If docFile.DocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
subDoc = docFile.ComponentDefinition
Try     
subDoc.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate    
Catch
'create new View Rep
subDoc.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
End Try
Else 
End If
Next

    'toggle work features in the open document (top level assembly)
    For Each oWorkPlane In openDoc.ComponentDefinition.WorkPlanes
    If oInput = True Then
    oWorkPlane.Visible = True
    ElseIf oInput = False Then
    oWorkPlane.Visible = False
    End If
    Next

    For Each oWorkAxis In openDoc.ComponentDefinition.WorkAxes
    If oInput = True Then
    oWorkAxis.Visible = True
    ElseIf oInput = False Then
    oWorkAxis.Visible = False
    End If
    Next

    For Each oWorkPoint In openDoc.ComponentDefinition.WorkPoints
    If oInput = True Then
    oWorkPoint.Visible = True
    ElseIf oInput = False Then
    oWorkPoint.Visible = False
    End If
    Next
	
    For Each oSketches In openDoc.ComponentDefinition.Sketches
    If oInput = True Then
    oSketches.Visible = True
    ElseIf oInput = False Then
    oSketches.Visible = False
    End If
    Next

'look at only the subassemblies
Dim subDocFile As Document
For Each oCompOcc in oAsmCompDef.Occurrences
If oCompOcc.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
oCompOcc.SetDesignViewRepresentation(sVRep,, True) 'True sets the view rep to be associative
Else 
End If
Next


'Look at all of the files referenced in the open document
For Each docFile In openDoc.AllReferencedDocuments                

    'toggle work features in the components
    For Each oWorkPlane In docFile.ComponentDefinition.WorkPlanes
    If oInput = True Then
    oWorkPlane.Visible = True
    ElseIf oInput = False Then
    oWorkPlane.Visible = False
    End If
    Next

    For Each oWorkAxis In docFile.ComponentDefinition.WorkAxes
    If oInput = True Then
    oWorkAxis.Visible = True
    ElseIf oInput = False Then
    oWorkAxis.Visible = False
    End If
    Next

    For Each oWorkPoint In docFile.ComponentDefinition.WorkPoints
    If oInput = True Then
    oWorkPoint.Visible = True
    ElseIf oInput = False Then
    oWorkPoint.Visible = False
    End If
    Next
	
	For Each oSketches In docFile.ComponentDefinition.Sketches
    If oInput = True Then
    oSketches.Visible = True
    ElseIf oInput = False Then
    oSketches.Visible = False
    End If
    Next
Next
iLogicVb.UpdateWhenDone = True

CJ.10E-10mm · ‎06-23-2014

Dear nomé,

Thank you for your kind contribution.

I will try this out tonight and revert back to you.

Thank you once again.

CJJ

amichaudJ6E3R · ‎11-17-2020

Hi Curtis,

I'm looking to do something similar, but maybe simpler. I have this assembly with parts in it. I want to be able to toggle the visibility of workplanes in specific components. Not all of them at the same time. Is it possible?

'catch and skip errors
On Error Resume Next
'define the active assembly
Dim oAssyDoc As AssemblyDocument
oAssyDoc = ThisApplication.ActiveDocument

'get user input as True or False
wfBoolean = InputRadioBox("Turn all Work Features On/Off", "On", "Off", False, "iLogic")

'Check all referenced docs 
Dim oDoc As Inventor.Document
For Each oDoc In oAssyDoc.AllReferencedDocuments
    'set work plane visibility
    For Each oWorkPlane In oDoc.ComponentDefinition.WorkPlanes
    oWorkPlane.Visible = wfBoolean
    Next
    'set work axis visibility
    For Each oWorkAxis In oDoc.ComponentDefinition.WorkAxes
    oWorkAxis.Visible = wfBoolean
    Next
    'set work point visibility
    For Each oWorkPoint In oDoc.ComponentDefinition.WorkPoints
    oWorkPoint.Visible = wfBoolean
    Next    
    'set sketch visibility
    For Each oSketch In oDoc.ComponentDefinition.Sketches
    oSketch.Visible = wfBoolean
    Next
Next

'update the files
InventorVb.DocumentUpdate()

I found this snippet online (that I think you may have wrote?) Anyway, I tried using as is, didn't work. I tried modifying it to fit my needs, didn't work either.

caroline_ccc · ‎03-04-2021

Can use this to turn off all work features.

ThisDoc.Document.ObjectVisibility.AllWorkFeatures = False

fixmepm · ‎11-04-2024

Hi. Thanks for the code. how can i make it work for CC parts as well?

CJ.10E-10mm · ‎11-04-2024

I was not the source of the Code, just a hapless repeater. Sorry.

kresh.bell · ‎11-05-2024

Hi @Curtis_Waguespack

this is a great iLogic, very useful. Would you modify it? When it is run, to turn off the visibility of all working planes without asking. Also without the option to make them visible. Also for sketches

Curtis_Waguespack · ‎11-05-2024

Hi @kresh.bell, see this example.

Hope that helps, Curtis

Sub Main

	Dim oAsmCompDef As AssemblyComponentDefinition
	oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition

	'Define the open document (top level assembly)
	Dim openDoc As Document
	openDoc = ThisDoc.Document
	'define view rep 
	Dim oViewRep As DesignViewRepresentation
	Dim sVRep As String
	sVRep = "Default"

	'create or activate view rep in the top level assembly
	Try
		oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
	Catch
		'create new View Rep
		oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
	End Try

	'create or activate view rep in subassemblies
	Dim docFile As Document
	For Each docFile In openDoc.AllReferencedDocuments
		Dim subDoc As AssemblyComponentDefinition
		If docFile.DocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
			subDoc = docFile.ComponentDefinition
			Try
				subDoc.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
			Catch
				'create new View Rep
				subDoc.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
			End Try
		End If
	Next

	'turn off features in top level
	Call TurnOff(openDoc)

	'look at only the subassemblies
	Dim subDocFile As Document
	For Each oCompOcc In oAsmCompDef.Occurrences
		If oCompOcc.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
			oCompOcc.SetDesignViewRepresentation(sVRep, , True) 'True sets the view rep to be associative
		End If
	Next

	'Look at all of the files referenced in the open document
	For Each docFile In openDoc.AllReferencedDocuments
		Call TurnOff(docFile)
	Next

	iLogicVb.UpdateWhenDone = True
End Sub

Sub TurnOff(oDoc As Document)

	Dim oDef As ComponentDefinition = oDoc.ComponentDefinition

	For Each oWorkPlane In oDef.WorkPlanes
		oWorkPlane.Visible = False
	Next

	For Each oWorkAxis In oDef.WorkAxes
		oWorkAxis.Visible = False
	Next

	For Each oWorkPoint In oDef.WorkPoints
		oWorkPoint.Visible = False
	Next

	For Each oSketch In oDef.Sketches
		oSketch.Visible = False
	Next

End Sub

Curtis_Waguespack · ‎11-05-2024

Hi @fixmepm, here are 2 versions that will handle CC parts also.

Hope this helps, Curtis

This version just turns everything off:

Sub Main

	Dim oAsmCompDef As AssemblyComponentDefinition
	oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition

	'Define the open document (top level assembly)
	Dim openDoc As Document = ThisDoc.Document
	'define view rep 
	Dim oViewRep As DesignViewRepresentation
	Dim sVRep As String = "Default"

	'create or activate view rep in the top level assembly
	Try
		oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
	Catch
		'create new View Rep
		oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
	End Try

	'turn off features in top level
	Call TurnOff(openDoc)

	'create or activate view rep in subassemblies
	Dim docFile As Document
	For Each docFile In openDoc.AllReferencedDocuments
		Dim subDoc As AssemblyComponentDefinition
		If docFile.DocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
			subDoc = docFile.ComponentDefinition
			Try
				subDoc.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
			Catch
				'create new View Rep
				subDoc.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
			End Try
		End If
	Next

	'look at only the subassemblies
	Dim subDocFile As Document
	For Each oCompOcc As ComponentOccurrence In oAsmCompDef.Occurrences
		If oCompOcc.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
			oCompOcc.SetDesignViewRepresentation(sVRep, , True) 'True sets the view rep to be associative
		Else
			If oCompOcc.Definition.IsContentMember = True Then oCompOcc.Visible = False
		End If	

	Next

	'Look at all of the files referenced in the open document
	For Each docFile In openDoc.AllReferencedDocuments
		Call TurnOff(docFile)
	Next

	iLogicVb.UpdateWhenDone = True
End Sub

Sub TurnOff(oDoc As Document)

	Dim oDef As ComponentDefinition = oDoc.ComponentDefinition

	For Each oWorkPlane In oDef.WorkPlanes
		oWorkPlane.Visible = False
	Next

	For Each oWorkAxis In oDef.WorkAxes
		oWorkAxis.Visible = False
	Next

	For Each oWorkPoint In oDef.WorkPoints
		oWorkPoint.Visible = False
	Next

	For Each oSketch In oDef.Sketches
		oSketch.Visible = False
	Next

End Sub

This version turns things on or off:

Sub main
	'get user input
	oInput = InputRadioBox("Select work feature visibility:", _
	"Turn ON work feats, sketches, CC parts", _
	"Turn OFF work feats, sketches, CC parts", "False", "iLogic")

	' set a reference to the assembly component definintion.
	Dim oAsmCompDef As AssemblyComponentDefinition
	oAsmCompDef = ThisApplication.ActiveDocument.ComponentDefinition

	'Define the open document (top level assembly)
	Dim openDoc As Document = ThisDoc.Document
	'define view rep 
	Dim oViewRep As DesignViewRepresentation
	Dim sVRep As String = "Default"

	'create or activate view rep in the top level assembly
	Try
		oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
	Catch
		'create new View Rep
		oAsmCompDef.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
	End Try

	'create or activate view rep in subassemblies
	Dim docFile As Document
	For Each docFile In openDoc.AllReferencedDocuments
		Dim subDoc As AssemblyComponentDefinition
		If docFile.DocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
			subDoc = docFile.ComponentDefinition
			Try
				subDoc.RepresentationsManager.DesignViewRepresentations.Item(sVRep).Activate
			Catch
				'create new View Rep
				subDoc.RepresentationsManager.DesignViewRepresentations.Add(sVRep)
			End Try
		End If
	Next

	'set visibility work features in the open document (top level assembly)
	Call SetVis(openDoc, oInput)

	Dim subDocFile As Document
	For Each oCompOcc In oAsmCompDef.Occurrences
		If oCompOcc.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
			oCompOcc.SetDesignViewRepresentation(sVRep, , True) 'True sets the view rep to be associative
		Else
			'handle Content Center Parts
			If oCompOcc.Definition.IsContentMember = True Then oCompOcc.Visible = oInput
		End If
	Next

	'Look at all of the files referenced in the open document
	For Each docFile In openDoc.AllReferencedDocuments
		'set visibility or work features
		Call SetVis(docFile, oInput)
	Next
	iLogicVb.UpdateWhenDone = True

End Sub

Sub SetVis(oDoc As Document, oInput As Boolean)

	Dim oDef As ComponentDefinition = oDoc.ComponentDefinition

	For Each oWorkPlane In oDef.WorkPlanes
		oWorkPlane.Visible = oInput
	Next

	For Each oWorkAxis In oDef.WorkAxes
		oWorkAxis.Visible = oInput
	Next

	For Each oWorkPoint In oDef.WorkPoints
		oWorkPoint.Visible = oInput
	Next

	For Each oSketch In oDef.Sketches
		oSketch.Visible = oInput
	Next

End Sub

fixmepm · ‎11-05-2024

@Curtis_Waguespackworked but not for CC parts. Thanks again

fixmepm · ‎11-05-2024

Im using Inventor 2019, does it matter for ilogic?

Curtis_Waguespack · ‎11-05-2024

@fixmepm, 2019 should not be a factor.

I'll need more information about your CC parts to understand why it doesn't work on your end. It worked on my test assembly with standard cap screws that were placed from CC.

Also, be sure you're using one of the versions from post 35 and not post 34

kresh.bell · ‎11-05-2024

Thanks @Curtis_Waguespack

perfect, works for me

fixmepm · ‎11-06-2024

Im a bit confused. Is this script supposed to turn work features of the assembly on/off? i was looking for something to turn on / off work features of the different parts. I im trying to achieve another illogic that handles CC parts as well, and I want to see how to access CC via the script. im not a programmer but trying my best..

Community

ilogic and work plane visibility

ilogic and work plane visibility

ilogic and work plane visibility