Hi all,
Need your help with automation. I need to create a pattern like this wrapped around cylinder.
Later, holes need to be cut at all locations. The snippets in iLogic ipt environment is resulting in error as it is not an assembly file. Could anyone please help
Hi @nsatheesan34D64 ,
Give this iLogic script a shot. Let me know if you run into any issues:
'Check that script is being run in a part document
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kPartDocumentObject Then
MessageBox.Show("Please re-run this script in a part document.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Hand, MessageBoxDefaultButton.Button1)
End If
'Set the part document variables
Dim oDoc As PartDocument = ThisApplication.ActiveDocument
Dim oCompDef As PartComponentDefinition = oDoc.ComponentDefinition
'Prompt user to select cylinderical face
Dim oCylinderFace As Face = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kPartFaceCylindricalFilter, "Select cylinder face")
'Prompt user to select the plane that the first hole will be perpendicular to
Dim oRefPlane = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kAllPlanarEntities, "Select the plane that you want the first hole to be perpendicular to")
'Get the cylinder mathematical object
Dim oCylinder As Cylinder = oCylinderFace.Geometry
'Get the cylinder radius
Dim oCylinderRadius As Double = oCylinder.Radius
'Generate the cylinder line
Dim oCylinderAxis As WorkAxis = oCompDef.WorkAxes.AddByRevolvedFace(oCylinderFace)
Try
oCompDef.WorkAxes.Item("CylinderAxis").Delete(False)
Catch
End Try
oCylinderAxis.Name = "CylinderAxis"
oCylinderAxis.Visible = False
'Get user input
Dim HoleDiameter As Double = InputBox("Enter hole diameters", "Enter hole diameters as a decimal in cm", 1)
Dim HoleDepth As Double = InputBox("Enter hole depth as a decimal in cm. If you want it to go all the way througm enter a value way larger than the cylinder diameter", "Enter hole depth", 1)
Dim NumOfHoles As Integer = InputBox("Enter the number of holes", "Enter the number of holes as a whole number", 4)
Dim AngleBetweenHoles As Double = InputBox("Enter angle between holes", "Enter angle between holes in degrees", 90)
Dim HeightDifference As Double = InputBox("Enter height difference between holes in cm", "Enter height difference between holes in decimals", 5)
'Arraylist to hold the workplanes
Dim HoleWorkPlanes As New ArrayList
'Set the initial plane to work off of
Try
Dim InitialPlane As WorkPlane = oCompDef.WorkPlanes.AddByPlaneAndTangent(oRefPlane, oCylinderFace, oCompDef.WorkPoints(1).Point)
HoleWorkPlanes.Add(InitialPlane)
Try
oCompDef.WorkPlanes.Item("InitialPlane").Delete(False)
Catch
End Try
InitialPlane.Name = "InitialPlane"
InitialPlane.Visible = False
Catch
MessageBox.Show("Please re-run this script and select a plane that can be tangent to the cylinder face.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Hand, MessageBoxDefaultButton.Button1)
Exit Sub
End Try
For i = 0 To NumOfHoles - 1
'Generate the planes to hold the sketches
Dim wPlaneAngleInRads As Double = AngleBetweenHoles * PI / 180
Dim TempPlane As WorkPlane = oCompDef.WorkPlanes.AddByLinePlaneAndAngle(oCylinderAxis, HoleWorkPlanes(i), wPlaneAngleInRads, True)
Dim HolePlane As WorkPlane = oCompDef.WorkPlanes.AddByPlaneAndOffset(TempPlane, oCylinderRadius)
HolePlane.Visible = False
HolePlane.Name = "HolePlane" & Str(i + 1)
HoleWorkPlanes.Add(HolePlane)
'Draw the sketches with circles
Dim HoleSketch As PlanarSketch = oCompDef.Sketches.Add(HolePlane)
Dim Hole2DCenter As Point2d = ThisApplication.TransientGeometry.CreatePoint2d(i * HeightDifference,0)
HoleSketch.SketchCircles.AddByCenterRadius(Hole2DCenter,HoleDiameter/2)
HoleSketch.Name = "HoleSketch" & Str(i + 1)
'Extrude the holes
Dim oProfile As Profile = HoleSketch.Profiles.AddForSolid
Dim HoleCut As ExtrudeDefinition = oCompDef.Features.ExtrudeFeatures.CreateExtrudeDefinition(oProfile, kCutOperation)
HoleCut.SetDistanceExtent(HoleDepth, kNegativeExtentDirection)
Dim Hole As ExtrudeFeature = oCompDef.Features.ExtrudeFeatures.Add(HoleCut)
Hole.Name = "Hole " & Str(i + 1)
Next
This is what the end result looked like for me:
@nsatheesan34D64 I agree with @aelqabbany you will need to provide the ipt model you are working with which will do one of two things figure out how you have manually drawn this and then this can be translated to the ilogic version. Also supply images and or a video of how you have implemented this. I have no great experience with feature creation using API as my experience is self thought like @aelqabbany so cannot offer too much advice on its interaction other than pouring hours into what each line is doing.
I would suggest for vba samples to started with the API help that comes with the software. If you get lucky you can find a sample and then dissect its operation. You will need to manually created the part then replicate the feature creation through API, looking then to search the help documents to find the objects, methods and properties required. There is no fast tracking this operation. If you get lucky you might find a sample that someone has debugged on this forum in vb.net or in this case that @aelqabbany has generously put together.
