Automatic dimensioning of arcs VBA

[basnederveen]

Hi

I'm trying to do some automatic dimensioning in VBA. I want to give outer dimensions to a part, but not from a sketch. For this I will need to dimension parts from point to point. This is no problem when the points are on lines, since then I can use start, mid and end points which is always a corner. Sometimes its not a line but an arc and this is where my problem occurs. 

It seems like the snap points created when you activate the dimension command and hover your mouse over a point on the arc are not available through the API. So I am trying to use the midpoint of an arc to to create a dimension to another point. When I try this the dimension keeps being created at the centerpoint instead. 

Is it possible to create a dimension with VBA from an CircularArcCurve.midpoint to another point? 

And can you get a geometry intent just by giving a point2d and the curve? So I can dimension to any point?

this is the code i used to try it out, and i attached a screenshot, left is what i want right is what i get

Sub test()

Dim dwg As DrawingDocument
Set dwg = ThisApplication.ActiveDocument

Dim oview As DrawingView
Set oview = ThisApplication.CommandManager.Pick(kDrawingViewFilter, "Pick a view")

Dim arc As DrawingCurve
For Each arc In oview.DrawingCurves
    If arc.CurveType = kCircularArcCurve Then Exit For
Next

Dim crv As DrawingCurve
Set crv = oview.DrawingCurves.Item(2)

Dim int1 As GeometryIntent
Set int1 = dwg.ActiveSheet.CreateGeometryIntent(crv, crv.MidPoint)

Dim int2 As GeometryIntent
Set int2 = dwg.ActiveSheet.CreateGeometryIntent(arc, arc.MidPoint)

Call dwg.ActiveSheet.DrawingDimensions.GeneralDimensions.AddLinear(oview.Position, int2, int1, kHorizontalDimensionType)

End Sub

[basnederveen]

Does anyone know how to use the midpoint of an arc and add a dimension?

[dgreatice]

Hi,

can you show by screenshot, result of dimension?

[basnederveen]

It's included in my original post. Right is what I get, left is what I am trying to get. I'm taking the midpoint of an arc, but it always takes the centerpoint. I can use the midpoint of a straight line though..

[basnederveen]

Hi dgreatice, do you know if this is possible at all?

[dgreatice]

hi @basnederveen

I try to get midpoint, but same result, it always go to center point of arc.

maybe this bug, try to request answer from Autodesk.

[basnederveen]

Yeah same here. Any suggestions on how to ask Autodesk apart from posting here in the forum? Posted a few times in here but with no success.

[dgreatice · Accepted solution]

Hi, 

now I find out, how to get Mid Point Intent

use PointIntentEnum.kMidPointIntent

Set int1 = dwg.ActiveSheet.CreateGeometryIntent(crv, PointIntentEnum.kMidPointIntent)

Set int2 = dwg.ActiveSheet.CreateGeometryIntent(arc, PointIntentEnum.kMidPointIntent)

[#9 · Accepted solution]

Set int1 = dwg.ActiveSheet.CreateGeometryIntent(crv, PointIntentEnum.kMidPointIntent)

[#10 · Accepted solution]

Set int2 = dwg.ActiveSheet.CreateGeometryIntent(arc, PointIntentEnum.kMidPointIntent)

[basnederveen]

Thanks! Strange that this is not necessary for a regular curve but it is for an 'kCircularArcCurve'

[dgreatice]

the result of arc.midpoint is Double (position of x & y), and that is not intent object

[dgreatice]

You can find information about Geometry Intent Object :

http://help.autodesk.com/view/INVNTOR/2018/ENU/?guid=GUID-86A7861A-F382-4DF9-BD9D-9526F290CDD1

[basnederveen]

Thanks alot! Do you know if it is also possible to create an intent on any location on an arc?

In specific it would be nice to be able to create an intent on the min/max x,y coordinates of an arc. These intents seem to be created when you hover your mouse over them.

[basnederveen]

Found it!! Been looking for this for ages!! 

PointIntentEnum.kCircularRightPointIntent -> the kCircular....Intent gives the max x/y right left top bottom point!!!