Community
hi mtofts,
Here's an example that gets the font for a named sketch and pushes it to a custom iProperty.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
oDoc = ThisDoc.Document
Dim oSketches As Inventor.PlanarSketches
Dim oSketch As PlanarSketch
Dim oSketchToGet As String
oSketchToGet = "Sketch1"
oSketches = oDoc.ComponentDefinition.Sketches
For Each oSketch In oSketches
If oSketch.Name = oSketchToGet Then
'get text font
oFont = oSketch.TextBoxes.Item(1).Style.Font
MessageBox.Show(oFont, "iLogic")
'write font to iProperty
iProperties.Value("Custom", "FontName") = oFont
Exit For
End If
Next
Hi mtofts,
I used to have to create these simple drawings for labels and we put the font and size info on the drawing, so the person creating the labels could use that info for initial setup, and/or verification.
So how about this:
- We'll create an iLogic rule that runs from your drawing file and it will look at the model file that is used in View1 of the drawing.
- Then it will look for a named sketch, or a named feature, or however you can best identify the feature that contains the sketch that contains the font you're interested in.
- Then we'd find the font, and write that to a sketched symbol on the drawing sheet.
- We'd set that up to run each time the drawing is saved.
I'd recommend setting this up as a single external iLogic rule that runs on every drawing file when it is saved. That rule looks for certain things ( in this case, it would look for the sketched symbol) and if it finds it, it runs the font rule (or the font code in that rule.
If that sounds interesting post back and I'll work up a simple example.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
There is more than meets the eye in the OP example:
1) My computer does not have the OP’s font installed, and therefore is unable to recognise it: If I open the IPT and hover the mouse over the Sketch2 containing the text, we can see that the text and relevant extrusion do not align properly:
2) If I edit the text and highlight a portion of it, we can see that the font is not being recognised;
3) If I run that iLogic Rule it will work (in so far as changing the text size according to the parameter) but it will also change the Font (to the default - Tahoma, in my case).
Whenever I send files to the Silkscreen Printers, I send them as solid hatch filled profile in DXF format at the required size, 1:1 scale, with 0 thickness lines or polylines, without any fonts embedded (or send a PDF version of that DXF, or even Gerber format for laser printing, if needed). That way, all mistakes, errors, or extra work (related to fonts) can be avoided.
Sorry if this doesn’t help much the OP with automating / documenting the changes in font and its size, but I hope it helps a bit with clarifying where errors might occur when someone tries to reproduce a Logo, text or similar that uses uncommon fonts.
Hi mtofts,
I'm a bit behind in the discussion, but here is an iLogic rule that you can run from your drawing ( I used part of what mcgyvr posted from the blog link).
- It looks at the view1 and finds the model file from that
- then it looks at that file for a sketch called "Engraved Text". ( Change that as needed, just make sure the part sketch has the name same as the code.)
- Then it gets the text value, font name, and font size
- Then it creates a sketch in the drawing file, and writes those values to a textbox at an insert point x:4,y:4
- You can then reposition the sketch as needed
Post back if this doesn't work or you need some tweaks to it.
I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com
Edit: I made a quick update to handle the situation that Daniel248 mentioned, where the font is not present (which returned an error).
'defines the named sketch
'to work with in the part model
Dim oSketchToGet As String
oSketchToGet = "Engraved Text"
'get the model used in the first
'view of this drawing
oDoc = ThisDrawing.ModelDocument
Dim oSketches As Inventor.PlanarSketches
oSketches = oDoc.ComponentDefinition.Sketches
Dim oSketch As PlanarSketch
Try
oSketch = oSketches(oSketchToGet)
Catch
MsgBox("Error: Check that the model file has a sketched named: " & oSketchToGet)
Return
End Try
'assumes only one text box in sketch
oFormattedText = _
oSketch.TextBoxes.Item(1).FormattedText
Dim iStart As Integer
Dim iEnd As Integer
Dim oText As String
'find text value
iStart = InStr(oFormattedText, "'>") + 1
iEnd = InStr(oFormattedText, "</Style") - 1
oText = Mid(oFormattedText, iStart + 1, iEnd - iStart)
'find font
iStart = InStr(oFormattedText, "Font='") + 5
If iStart > "5" Then
iEnd = InStr(iStart+1,oFormattedText, "'")
oFont = Mid(oFormattedText, iStart+1, iEnd-1 - iStart)
Else
oFont = "?"
End If
'find font size
iStart = InStr(oFormattedText, "FontSize='") + 9
If iStart > "9" Then
iEnd = InStr(iStart+1,oFormattedText, "'")
oFontSize = Mid(oFormattedText, iStart+1, iEnd-1 - iStart)
Else
oFontSize = "?"
End If
'''now create a text on the drawing
' Set a reference to the drawing document.
' This assumes a drawing document is active.
Dim oDrawDoc As DrawingDocument
oDrawDoc = ThisApplication.ActiveDocument
' Create a new sketch on the active sheet.
Dim oDSketch As DrawingSketch
oDSketch = oDrawDoc.ActiveSheet.Sketches.Add
' Open the sketch for edit
oDSketch.Edit
Dim oTG As TransientGeometry
oTG = ThisApplication.TransientGeometry
Dim oTextBox As TextBox
'create string
sText = "Text Value: " & oText _
& vbLf & "Font: " & oFont _
& vbLf & "Font Size: " & oFontSize
'create text box on drawing at x:4, y:4
oTextBox = oDSketch.TextBoxes.AddFitted _
(oTG.CreatePoint2d(4, 4), sText)
'exit sketch
oDSketch.ExitEdit
Forums Links
Can't find what you're looking for? Ask the community or share your knowledge.
Post to forums
