Blechabwicklung als step exportieren (evtl. mit VBA)

[Andre_Becker]

Hallo zusammen,

ich wollte mal nachfragen ob irgendjemand eine Möglichkeit sieht eine Blechabwicklung als step-Datei zu exportieren? Gerne würde ich es mittels VBA realisieren aber ich befürchte das es nicht umsetzbar ist. Ist das korrekt oder seht ihr da eine Chance das zu verwirklichen?

Leider kenne ich nur den Weg über den Export als .sat-Datei um diese dann als .step umzuwandeln. Wie ich finde, sehr umständlich.  Aber ich lasse mich gerne eines Besseren belehren.

Freue mich über ein paar Antworten.

[Andre_Becker]

Was ich vergessen hatte zu erwähnen. Ich arbeite mit Inventor 2017 Professional Build: 256, Release 2017.4.7.

[S_May]

Hallo @Andre_Becker,

schau mal bitte hier rein...Exportieren von Abwicklungen

[ca-d.one]

Hi Andre,

ich hätte da eine ganz kurze, "Schnell und Schmutzig"- Lösung  😉

Wenn du mal bei deinen Inventor unter i-Logic nachschaust, findest du, z.B bei einer neu angelegten Regel

den Reiter "Benutzerdefiniert"

Dort gibt es ein vorbereitetes Snippet....siehe Bild 😉

Dann einfach die Abwicklung aktivieren, Regel ausführen und fertig.

Das STEP-File landet im Arbeitsordner.

Etwas simpel, zugegeben, aber blitzschnell erledigt!

lg

+dirk+

[S_May]

@ca-d.one,

es exportiert aber nicht die Abwicklung ...

[Juergen_Wagner]

1. Manuell ist der Export der Abwicklung möglich als SAT, DXF und DWG. 

2. Über die API wird wohl dann max. auch nur diese Exportformate zur Verfügung stehen.

Hier Beispielcode für den Export als DXF und SAT.

Public Sub Abwicklung_SAT()
   
    Dim oDoc As PartDocument
    Set oDoc = ThisApplication.ActiveDocument

    Dim oDataIO As DataIO
    Set oDataIO = oDoc.ComponentDefinition.DataIO
    
    Dim sOut As String
    sOut = "FLAT PATTERN SAT"

    oDataIO.WriteDataToFile sOut, "C:\temp\flat2.sat"
End Sub

Public Sub Abwicklung_DXF()
   
    Dim oDoc As PartDocument
    Set oDoc = ThisApplication.ActiveDocument

    Dim oDataIO As DataIO
    Set oDataIO = oDoc.ComponentDefinition.DataIO
    
    Dim sOut As String
    sOut = "FLAT PATTERN DXF"

    oDataIO.WriteDataToFile sOut, "C:\temp\flat2.dxf"
End Sub

Wenn du wirklich STP brauchst (warum?) dann müsste mal sowas programmieren:

Export SAT > Re-Import SAT in Inventor als IPT => Export IPT als STP. 

Was sollte technisch kein Problem sein. Ist halt ein bisschen Arbeit.

[Andre_Becker]

Hallo und erstmal vielen Dank für die Antworten.

Das habe ich leider auch schon alles gesehen und bemerkt. Entweder ist nicht der richtige Dateityp dabei oder es wird nicht die Abwicklung exportiert.
Aber das mit dem Re-Import der SAT-Datei wird wohl die Lösung sein.

Wenn ich das Makro fertig haben sollte, werde ich es hier gerne zur Verfügung stellen.
Also, nochmals vielen Dank für die Hinweise

[TFoerst]

Hi @Andre_Becker,

nur mal so ne kurze Frage. 

Exportiert man von Blechteilen nicht das gefaltete Modell als STEP? Daraus können die aktuellen Kantmaschinen ja dann eine entsprechende Abwicklung generieren (inkl. Abzugswerten).

Aber eine Abwicklung als STEP? Mich würde die praktische Anwendung nur mal interessieren 

[TFoerst · Accepted solution]

Hab dir mal schnell ein iLogic Skript gebaut:

'Create a FlatPattern as SAT File, and convert it to a STEP
'The STEP file gets the same name as the part and is stored paralell to the part file

ThisFile = ThisDoc.PathAndFileName(False)
Try
	Dim oDoc As PartDocument
	oDoc = ThisApplication.ActiveDocument

	Dim oCompDef As SheetMetalComponentDefinition
	oCompDef = oDoc.ComponentDefinition

	Dim oDataIO As DataIO
	oDataIO = oDoc.ComponentDefinition.DataIO

	Dim sOut As String
	sOut = "FLAT PATTERN SAT"

	'Create FlatPattern if needed
	If oCompDef.HasFlatPattern = False Then
		oCompDef.Unfold
	Else
		oCompDef.FlatPattern.Edit
	End If

	'create SAT File
	oDataIO.WriteDataToFile(sOut, ThisFile & ".sat")

	'Convert SAT File to STEP (Hidden)
	satDoc = ThisApplication.Documents.Open(ThisFile & ".sat", False)
	satDoc.SaveAs(ThisFile & ".step", True)
	satDoc.Close()

	'Delete SAT File
	My.Computer.FileSystem.DeleteFile(ThisFile & ".sat")

Catch

End Try

[Andre_Becker · Accepted solution]

Hallo @TFoerst,

erstmal vielen Dank für die super funktionierende iLogic-Regel. 100%ig ... So habe ich mir das vorgestellt.

Der Grund warum wir eine Blechabwicklung als step-Datei benötigen ist, dass unser Lieferant für unsere Blechbauteile eine neue Software benutzt mit der er nur noch step Dateien einliest (will oder kann). Diese kantet er auch für uns. Dafür bräuchten wir natürlich keine Abwicklung der Bauteile. Es gibt aber Ausnahmen in denen wir die Bauteile selber kanten und nur die abgewickelten Zuschnitte benötigen. Wie z.B. Blechtrichter eckig auf rund.

Wie dem auch sei...vielen Dank nochmals für Eure Unterstützung.

[h.woerner]

Hallo zusammen,

händisch könnte man den Umweg über den Befehl "Abwickeln" gehen und dann das "gefaltete" Modell exportieren, somit hätte man die Abwicklung exportiert.

Viele Grüße

[fpanther]

Vielen Dank, super!