xlist function
@Anonymous wrote:
.... I use the XLIST function to check. However, ... I am not able to know exactly which layer the line is on in the xref file. Therefore, I am not able to edit the specific layer unless reopen the xref file. Any ideas?
Slightly stale thread, but since it's been revived....
If all you need is the Layer of a nested object, will this do?
(cdr (assoc 8 (entget (car (nentsel)))))
Kent Cooper, AIA 
@Anonymous wrote:
.... to know exactly which layer the line is on in the xref file ... to edit the specific layer ...
So suppose a Line or something is drawn on Layer 0 and is part of a Block definition? If you want to edit the Layer on which it appears, i.e. the Layer whose properties determine how it looks in the drawing, to change that if you change the Layer's color or linetype or something, then you don't want to be told Layer 0 if you pick on it, but rather the Layer that the Block is inserted on. [My previous suggestion will give you Layer 0, being the lowest-nested-level Layer of the object.] And what if that Block is also inserted on Layer 0 and is nested into another Block definition? And maybe another? And what if that one's nested in an Xref? And that's nested in another Xref?
Here's a command that finds the "apparent" layer, i.e. the lowest-nested-level Layer that is not Layer 0, of any selected object or nested object, to any nesting level. [It also works on top-level objects, not just nested ones.]
(defun C:LNO
; = Layer of Nested Object [not Layer 0 if nested in object on another Layer]
(/ ent edata lay)
(setq
edata (entget (car (setq ent (nentsel))))
lay ; = Layer it's on
(if (= (cdr (assoc 8 edata)) "0"); deepest-nested on Layer 0
(cond ; then
((> (length ent) 2); nested entity [other than Attribute] in Block/Xref
(setq nestlist (last (nentselp (cadr ent)))); stack of references nested in
(while
(and
nestlist ; still nesting level(s) remaining
(= (setq nlay (cdr (assoc 8 (entget (car nestlist))))) "0"); = Nested Layer still 0
); and
(setq nestlist (cdr nestlist)); move up a level if present
); while
nlay
; return lowest-level non-0 Layer of nested or containing reference(s);
; 0 if that all the way up
); non-Attribute nested entity on Layer 0 condition
((= (cdr (assoc 0 edata)) "ATTRIB"); Attribute in Block
(cdr (assoc 8 (entget (cdr (assoc 330 edata))))); Block's Layer
); Attribute on Layer 0 condition
("0"); none-of-the-above condition
); cond - then
(cdr (assoc 8 edata)); else - Layer of entity/nested entity
); if & lay
); setq
); defun
Kent Cooper, AIA
