Select Individual Objects in a Selection Group

[daniel.welchLFHPQ]

Hi,

Is there a way to select multiple objects and then "next" through them one at a time?  If not, does a LISP already exist to do this?

Then click "next" and the first object selected in the group is selected.

Then click "next" and the second object selected in the group is selected and so on.

[Valentin_CAD]

@daniel.welchLFHPQ ,

Please elaborate your intended purpose.

You may want to research these links:

• To Create and Save a Selection Filter
• SELECTSIMILAR
• To Change the Settings for Selecting Similar Objects
• QSELECT

[daniel.welchLFHPQ]

@Valentin_CAD 

My goal is to be able to select multiple blocks (specifically connectors in ACADE) then next through them and change various attributes that need different values between the blocks.  For example:  Say I want to change the location on 5 different connectors to 5 different locations.  I would select all 5 of the connectors then I could "next" through each connector and change the location without having to select them individually with my mouse.

This functionality would allow me to create a script that would take in a list of locations and then next through the selected blocks and change the location attribute of each block according to the corresponding value in the list.  This would repeat for all of the selected connectors.

[Kent1Cooper · Accepted solution]

Something like this?  [minimally tested]

(defun C:SSST (); = Selection Set to Step Through
  (prompt "\nTo establish Selection Set to Step Through with STSS command,")
  (setq *SSST* (ssget))
)

(defun C:STSS (/ n); = Step Through Selection Set
  (if *SSST*
    (progn ; then
      (setq n (sslength *SSST*))
      (sssetfirst nil ; select/grip/highlight
        (ssadd ; put into unnamed selection set
          (ssname *SSST*
            (cond
              (*STSSn* (setq *STSSn* (rem (1+ *STSSn*) n)))
              ((setq *STSSn* 0))
            ); cond
          ); ssname
        ); ssadd
      ); sssetfirst
    ); progn
    (prompt "\nNo set established by SSST command yet."); else
  ); if
  (prin1)
)

[daniel.welchLFHPQ]

@Kent1Cooper 

Yes, just like this thank you!