seam clear hotkey script

[slava.lobanov.1990]

Hello. Can I somehow create a script that will work through a hotkey that will remove the blue seam from the model?

Now this can be done through the clamped alt in the seam editing mode. I need this option without activating this mode.

The hotkeys have Edge Sel to Pelt Seam (Add)  this marks the seam on the desired edges. I need a reverse operation on another button.

I saw a video of a paid script and there was a button to clean the seams. How to make only this option separately without everything else?

[denisT.MaxDoctor]

macroScript HideSeams
	category:"UVW Unwrap Helpers"
	toolTip:"Hide Seams"
(
	try ((modpanel.GetCurrentObject()).setPeltSelectedSeamsByNode #{} selection[1]) catch()
)

how to assign a hotkey to a macro, you probably know yourself

[denisT.MaxDoctor]

macroScript HideSeams
	category:"UVW Unwrap Helpers"
	toolTip:"Hide Seams"
(
	local modi = undefined
	fn enabled = (iskindof (modi = modpanel.GetCurrentObject()) Unwrap_UVW)
	on isEnabled do (enabled())
	on execute do if enabled() do (modi.setPeltSelectedSeamsByNode #{} selection[1])
)

[slava.lobanov.1990]

That's what you need. This is the only way he removes all the seams from the entire object at once. It is necessary to remove only from the selected edges.

[denisT.MaxDoctor · Accepted solution]

---

@slava.lobanov.1990 wrote:

That's what you need. This is the only way he removes all the seams from the entire object at once. It is necessary to remove only from the selected edges.

---

macroScript HideSeams
	category:"UVW Unwrap Helpers"
	toolTip:"Hide Seams"
(
	local modi = undefined
	fn enabled = (iskindof (modi = modpanel.GetCurrentObject()) Unwrap_UVW)
	on isEnabled do (enabled())
	on execute do if enabled() do 
	(
		ss = #{}
		if keyboard.shiftPressed do
		(
			ss = modi.getPeltSelectedSeams()
			ee = modi.getSelectedGeomEdges()
			ss -= ee
		)
		
		modi.setPeltSelectedSeams ss
	)
)

with SHIFT clear selected edges, without SHIFT clear all

[slava.lobanov.1990]

Thank.