select path button

[hayriistay]

Hello, Autodesk representatives. It would be great if there was a "Select Path" button under the Path Deform parameters. It becomes challenging to handle complex models without it.

[Swordslayer]

In the meantime, you can add a button to the selected object's pathDeform WSM modifier like this and for that given modifier, it will always be there:

SpacePathDeformEx = attributes SpacePathDeformEx attribID:#(0x58d141c, 0x7eaf7fe9)
(
	rollout params "Path Options"
	(
		button btnSelectPath "Select Path"
		on btnSelectPath pressed do
		(
			local owner = custAttributes.getOwner this
			if isKindOf owner SpacePathDeform and isvalidNode owner.path do select owner.path
		)
	)
)

custAttributes.add $.modifiers[SpacePathDeform] SpacePathDeformEx

Alternatively, you can execute this macroscript once and you will have a new action available to assign hotkey to or put into menu/quadmenu to select current pathDeform WMS's path:

macroScript SelectSpacePathDeformPath
	buttonText:"Select PathDeform WSM Path"
	toolTip:"Select PathDeform WSM Path"
	category:"Shortcuts"
(
	if isKindOf (modPanel.getCurrentObject()) SpacePathDeform and isValidNode (modPanel.getCurrentObject()).path do select (modPanel.getCurrentObject()).path
)