Wall Calculate
Something could be worked out to do that, but questions arise:
Would you want [I assume] the Y distance instead of X if the difference between the two points is greater in the Y direction, automatically?
Would the walls always be in orthogonal directions, or might there be any at angles? If so, is it acceptable to require selection of the two points on the same side of the wall? Or to require selection of one of the wall Lines to establish what the angle is?
Can we formulate this request as:
Select two point along a wall at opposite ends (dx > 0 and dy > 0).
- a) width >= height --> horizontal wall, otherwise vertical wall
- b) min (dx xy) is wall width - no need ask for input if scale is 1 : 1 and drafting is precise.
- c) max (dx dy) is total wall length
- d) Points p1 and p2 will always be selected inside full space
- e) Process only segments along horizontal (vertical) center line (bisector) between points p1 and p2. Ignore
segments heading in opposite direction to wall direction. If wall is horizontal ignore all vertical segments
Divide center line in segments at intersection points with wall lines, add up only odd ones
Depending on type of the wall change text orientation angle and create text at user picked point and loop.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@hak_vz wrote:
....
- e) Process only segments along horizontal (vertical) center line (bisector) between points p1 and p2. Ignore
segments heading in opposite direction to wall direction. If wall is horizontal ignore all vertical segments
Divide center line in segments at intersection points with wall lines, add up only odd ones
....
I didn't get aspects like those out of the description in Message 1. Ask for wall height, and multiply that by overall wall length, ignoring openings, to calculate the area to put into Text content.
@k005 wrote:
.... when measuring the walls of 10? ....
---------------------------------------------0- Wall width : ? ( 10 )
1- first point, second point
2- wall height : ?
....
In light of the answers to other questions, going back to this and the Point locations in the drawing: If you would always pick points at opposite ends and on opposite sides of the wall, and if the walls are always orthogonal, then the routine can calculate the wall width -- it would not need to ask the User for that. Is that desirable?
Here is my conceptual solution for horizontal wall case (vertical is similar).
All walls are created as line entities (as in example)
After your review I can make changes. Keep in mind that code is not thoroughly tested.
To use Unicode text use TTF font.
That's all from me for now.
(defun c:warea (/ wh p1 p2 x1 x2 y1 y2 dx dy ss eo p3 p4 int_pts seg_lst i t_lst seg l)
(defun LM:Unique ( l )(if l (cons (car l) (LM:Unique (vl-remove (car l) (cdr l))))))
(setq wh (getreal "\nWall height >"))
(setq to_del (ssadd))
(setvar 'cmdecho 0)
(cond
((and(setq p1 (getpoint "\nSelect first point >") p2 (getpoint "\nSelect second point >")))
(setq a (vl-sort (list (car p1)(car p2)) '<) b (vl-sort (list (cadr p1)(cadr p2)) '<))
(setq dx (- (cadr a)(car a)) dy (- (cadr b)(car b)))
(cond
((>= dx dy)
(setq p1 (list (car a) (+ (car b) (* 0.5 dy))))
(setq p2 (list (cadr a) (+ (car b) (* 0.5 dy))))
(setq ss (ssget "F" (list p1 p2) '((0 . "Line") )))
;(command "_.line" p1 p2 "")
(setq i -1)
(cond
((and ss)
(while (< (setq i (1+ i))(sslength ss))
(setq eo (vlax-ename->vla-object(ssname ss i)))
(setq p3 (vlax-get eo 'StartPoint))
(setq p4 (vlax-get eo 'EndPoint))
(setq m (inters p1 p2 p3 p4 nil))
(if (and m) (setq int_pts (cons m int_pts)))
)
(setq int_pts (cons p1 int_pts))
(setq int_pts (cons p2 int_pts))
(setq int_pts (LM:Unique (vl-sort int_pts '(lambda (x y)(< (car x)(car y))))))
(while int_pts
(setq t_lst (cons (list (car int_pts)(cadr int_pts)) t_lst))
(setq int_pts (cdr int_pts))
)
(setq t_lst (reverse t_lst))
(while t_lst
(setq seg_lst (cons (car t_lst) seg_lst))
(setq t_lst (cddr t_lst))
)
(setq seg_lst (reverse seg_lst))
(setq L 0)
(while seg_lst
(setq seg (car seg_lst) seg_lst (cdr seg_lst))
(setq L (+ L (distance (car seg)(cadr seg))))
(command "_.line" (car seg)(cadr seg) "")
(ssadd (entlast) to_del)
)
(setq p1 (getpoint "\nText insertion point >"))
(setq text (strcat (rtos dy 2 0) " luk Duvar : " (rtos (* L wh) 2 2) " m\U+00B2"))
(entmake
(list
(cons 0 "TEXT")
(cons 100 "AcDbText")
(cons 10 p1)
(cons 40 5)
(cons 1 text)
(cons 50 0)
(cons 100 "AcDbText")
)
)
(princ (strcat (rtos dy 2 0) " luk Duvar : " (rtos (* L wh) 2 2) " m2"))
(command "_.erase" to_del "")
(setvar 'cmdecho 0)
(princ)
)
)
)
)
)
)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
Ok. I'll make changes later trough the week. As I told, vertical case needs to be coded.
Please create some sample images, and attach to this post, about what you want to be added or not to add. It's pick up all the details from single sample.
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@k005 Test this. To exit loop hit <enter> on input p1 p2.
To change text height look at
(cons 40 5) ; 5 is text height
(defun c:warea (/ wh p1 p2 a b dx dy new_text *error* )
(defun *error* ( msg )
(if (not (member msg '("Function cancelled" "quit / exit abort")))
(princ)
)
)
(setq wh (getreal "\nWall height >"))
(while
(and(setq p1 (getpoint "\nSelect first point >") p2 (getpoint "\nSelect second point >")))
(setq a (vl-sort (list (car p1)(car p2)) '<) b (vl-sort (list (cadr p1)(cadr p2)) '<))
(setq dx (- (cadr a)(car a)) dy (- (cadr b)(car b)))
(cond
((>= dx dy)
(setq p1 (getpoint "\nText insertion point >"))
(setq new_text (rtos (* 0.0001 dx wh) 2 2))
(cond
((not (vl-string-position (ascii ".") new_text))
(setq new_text (strcat new_text ".00"))
)
((= (-(strlen new_text)(vl-string-position (ascii ".") new_text)) 2)
(setq new_text (strcat new_text "0"))
)
)
(setq new_text (strcat (rtos dy 2 0) " luk Duvar : " new_text " m\U+00B2"))
(entmake
(list
(cons 0 "TEXT")
(cons 100 "AcDbText")
(cons 10 p1)
(cons 40 5)
(cons 1 new_text)
(cons 50 0)
(cons 100 "AcDbText")
)
)
(princ (strcat (rtos dy 2 0) " luk Duvar : " new_text " m2"))
(princ)
)
((< dx dy)
(setq p1 (getpoint "\nText insertion point >"))
(setq new_text (rtos (* 0.0001 dy wh) 2 2))
(cond
((not (vl-string-position (ascii ".") new_text))
(setq new_text (strcat new_text ".00"))
)
((= (-(strlen new_text)(vl-string-position (ascii ".") new_text)) 2)
(setq new_text (strcat new_text "0"))
)
)
(setq new_text (strcat (rtos dx 2 0) " luk Duvar : " new_text " m\U+00B2"))
(entmake
(list
(cons 0 "TEXT")
(cons 100 "AcDbText")
(cons 10 p1)
(cons 40 5)
(cons 1 new_text)
(cons 50 (* 0.5 pi))
(cons 100 "AcDbText")
)
)
(princ (strcat (rtos dx 2 0) " luk Duvar : " new_text " m2"))
(princ)
)
)
)
)
Miljenko Hatlak
Did your question get successfully answered? Then click on the ACCEPT SOLUTION button.
@k005 wrote:
....
3. After writing the article should continue again. without asking the wall height...
4. If I exit the command, and re-enter it, it should ask for the wall height.....
It seems to me this can be somewhat simpler. Try this, which when you exit and re-enter, asks for wall height but also offers your previous wall height as the default, so you can press Enter and not type it in again:
(defun C:WAL ; = Wall Area Label [horizontal/vertical walls only]
(/ pt1 pt2 delta)
(initget (if _WALht_ 6 7)); no zero, no negative, no Enter if no prior value
(setq _WALht_ ; global variable for default
(cond
( (getdist
(strcat
"\nWall Height"
(if _WALht_ (strcat " <" (rtos _WALht_) ">") ""); prior default if present
": "
); strcat
); getdist
); User-input condition
(_WALht_); on Enter with prior value default
); cond
); setq
(while
(and
(setq pt1 (getpoint "\nWall end point: "))
(setq pt2 (getpoint "\nOther end on opposite side: "))
); and
(setq delta (reverse (cdr (reverse (mapcar 'abs (mapcar '- pt2 pt1)))))); XY only
(command "_.text"
"_mc" "_non" (mapcar '/ (mapcar '+ pt1 pt2) '(2 2 2)); justification/ins. pt
"" ;; <-- current Text height
(if (> (car delta) (cadr delta)) "0" "90")
(strcat
(rtos (apply 'min delta) 2 0); wall thickness
" luk duvar : "
(rtos (/ (* _WALht_ (apply 'max delta)) 10000) 2 2); area
" m²"
); strcat
); command
); while
(princ)
); defun
It uses the current Text height and Style, but those can have fixed values built in, or something could be calculated based on the wall thickness. And it puts the Text on the current Layer, but that could also be specified.
Hak_vz did you have a look at the image I posted, takes into account stacked walls ie window opening. The windows have a bottom line and a top line both with "Thickness".
