vla-get-centroid error

[SAPER59]

I have a problem with some regions, when getting the centroid, function  crashes, and if I go to the object properties, centroid said  Automation Error. Region is not on the UCS plane

I tried setting the UCS to region object, before accessing centroid property, but crashes the same

It happens in many dxf files when creating region from original polyline, but in many others works perfectly

(setq en (car(entsel)))
(setq obj1 (vlax-ename->vla-object en))
(setq pc (vla-get-centroid obj1));

;;;;here crashes and can not control with error trap in order to know before getting centroid and continue
(vlax-release-object obj1)

If somebody knows how to solvethis. thanks

[-didier-]

Bonjour @SAPER59 

Actually I see the same concern but without “crash” just an error in the search of the centroid.

The concern is the entity not the software, it must be redesigned “properly” and everything will come back into order.

Amicalement

[SAPER59]

Thanks but the point is when the app is running I must detect the error before, in order not to let the function crashes , and go on alerting the user about that object has a problem.

The function handle hundred of dxf inserting , modifying and exporting, and if crashes, there are many dxf that have not been prcessed.

Thanks anyway

[sigmmadesigner]

Try It.....

(defun CENTROID_EXE (e / obj ll ur)
(if (not (vl-catch-all-error-p
(vl-catch-all-apply 'vla-getboundingbox
(list (setq obj (vlax-ename->vla-object e))
'll
'ur))))
;; Calcula o centro do bounding box
(mapcar '/
(apply 'mapcar
(cons '+ (mapcar 'vlax-safearray->list (list ll ur))))
'(2 2))
)
)

(defun c:centro-textobb ( / ent pt)
(vl-load-com)
(setq ent (car (entsel "\n ADD OBJ: ")))
(if ent
(progn
(setq pt (CENTROID_EXE ent))
(if pt
(progn
(vla-addText
(vla-get-ModelSpace (vla-get-ActiveDocument (vlax-get-acad-object)))
"Centro"
(vlax-3d-point pt)
2.5
)
)
(prompt "\n NOT CENTER")
)
)
(prompt "\n NOT SELECT.")
)
(princ)
)

[SAPER59]

Thanks sigmmadesigner, but this is the center of max/min coordinates of a polyline obtained by bound...

Thanks anyway

[-didier-]

Bonjour @SAPER59 

I understand, then may be with a test like this you can loop over the bad object and continue with the rest

(setq ent (car (entsel "Select region")))
(setq vla (vlax-ename->vla-object ent))
(setq result (vlax-safearray->list (vlax-variant-value (vla-get-Centroid vla))))
(if (not (= 'LIST (type result)))
  (alert "Error in centroid search ")
  )
)

Amicalement

[paullimapa · Accepted solution]

@SAPER59 try this:

(defun rgtest (/ en obj1 pc pt ss)
 (vl-load-com)
 (command "_.UCS" "_OB" pause)
 (setq pt (getvar "lastpoint"))
 (if (setq ss (ssget pt))
  (if (and 
        (eq (cdr (assoc 0 (entget (setq en (ssname ss 0))))) "REGION")
        (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-get-centroid (list (setq obj1 (vlax-ename->vla-object en))))))
      ) 
      (setq pc (vla-get-centroid obj1))
  )
 )
 (command "_.UCS" "_P")
 pc
)

[SAPER59]

Thanks paullimapa, I coudln't find the right use of catching error

Works perfectly and let me avoid object with problem and continue with others without crashing

Thanks again

[paullimapa]

you are welcome...cheers!!!