Trying to convert DXF to DXF R12 with simple script

[ThomasKCVM9]

Hello, we are having problems with splines in DXF files when sending them to our plasma software.  I have found that saving as DXF R12 works and am trying to create a simple script to make the conversion.  So far I have:

FILEDIA
0
ISAVEBAK
0
_DXFOUT

v
LT2
16
y
FILEDIA
1
ISAVEBAK
1
EXIT
_N

saved to a .scr file and ran with a .bat file.  The commands work as expected when run copy and paste to the command line.  However, if I run it as a script, I get:

"C:\Users\xxxxx\Documents\DXF_FIX_TEST\testfile.dxf": Can't open file
Command: y
Unknown command "Y". Press F1 for help.

After setting 16 as the precision.  If I type the DXFOUT commands it askes me if I want to over write the existing file at that same spot.

My question is how do I get around this?  I need to have the DXFOUT file add something to the file name or write it in a different directory where the original file does not exist.  I can program in other languages but I don't know AutoCAD's scripting at all.

Thank you.

[ronjonp]

Try this code .. it will create a script in the directory you choose that has all your DWG files. It then creates a subfolder 'DXF12' that the converted files will be placed in. I had to do something similar about 10 years ago and had the code ready to go : ).

(defun c:dxff (/ fldr dir dwglist dxf file)
  (defun fldr (message / sh folder result)
    (setq sh (vlax-get-or-create-object "Shell.Application"))
    (setq folder (vlax-invoke-method sh 'browseforfolder 0 message 0))
    (vlax-release-object sh)
    (if	folder
      (progn (setq result (vlax-get-property (vlax-get-property folder 'self) 'path))
	     (strcat (vl-string-left-trim "\\" result) "\\")
      )
    )
  )
  (if (and (setq dir (fldr "Pick a directory to process"))
	   (setq dwglist (vl-directory-files dir "*.dwg" 0))
	   (setq dxf (strcat dir "DXF12\\"))
      )
    (progn
      (setq file (open (strcat dir "dxf_convert.scr") "W"))
      (vl-mkdir dxf)
      (progn (alert (strcat dir "dxf_convert.scr"))
	     (foreach f	dwglist
	       (write-line (strcat "_.open \"" dir f "\"") file)
	       (write-line
		 (strcat "(vla-saveas (setq doc (vla-get-activedocument (vlax-get-acad-object))) "
			 (vl-prin1-to-string (strcat dxf (vl-filename-base f)))
			 " acR12_dxf)"
		 )
		 file
	       )
	       (write-line "(vla-save doc) _.close" file)
	     )
      )
      (close file)
    )
  )
  (princ)
)

If the files you're processing are already DXF simply change the extension here to "*.dxf"

(setq dwglist (vl-directory-files dir "*.dwg" 0))

[ThomasKCVM9]

Thank you! I will have a chance on Monday to try it!

[paullimapa]

Looks like code only creates a script file in the selected directory but requires user to manually run it by entering command Script and then locate and select dxf_convert.scr to start the process 

[ronjonp]

@paullimapa Or drag it into a session of CAD. Either way yes .. there is one more crucial step. 😉

[Sea-Haven]

Why not add the run script at end of dxff. 

; at end of code
(command "script" (strcat dir "dxf_convert.scr"))
(princ)
)

[ronjonp]

---

@Sea-Haven wrote:

Why not add the run script at end of dxff. 

; at end of code
(command "script" (strcat dir "dxf_convert.scr"))
(princ)
)

---

I'd rather that be left to the person .. scripts are great and also could be dangerous 😛

[ThomasKCVM9]

I apologize for not responding sooner.  I have not had a chance to figure out how to run or integrate LISP scripts.  That's the main reason I chose the the .BAT and .SCR formats.

[ec-cad]

Thanks to the above contributors. I combined their thoughts in attached .lsp file.

Instructions: If your source files are .dxf - then no change.

If your source files are .dwg - comment out : (setq dwglist (vl-directory-files dir "*.dxf" 0)); IF DXF's

and, uncomment out: ;;;;;; (setq dwglist (vl-directory-files dir "*.dwg" 0)); IF DWG's

To comment out a line, just add a few ;;; at far left in Notepad.

To uncomment out a line, remove the ;;; at far left in Notepad.

To load and run this Lisp.

First, place the lisp in a folder, say C:/mylisp  .. with filename = dxff.lsp so you end up with:

C:/mylisp/dxff.lsp  (where 'mylisp' can be any folder name you desire)

To Load the program, with Acad open, at the Command Line, type in:  (load "c:/mylisp/dxff.lsp")

To run the program at the Comand Line, type in: DXFF

(If your AutoCAD sends you an error about not wanting to run the script file, let us know, there's a fix for that)

The Lisp should run and place a copy of the .dxf output files into a folder under the current selected folder

as in:  C:/job1/DXF12 (finished folder to get the DXF 12's from.

If you cannot 'see' that hidden folder, use Windows Explorer, highlight the parent folder, right click and

pick "Properties" unset the box 'Read Only', enter OK. This will unhide that new folder.

When completed, you can delete the .scr file.

ECCAD

[ec-cad]

Ronjonp,

Excellant code.

In this particular case, since the Lisp is 'building' the script file, I would consider this as 'safe'.

If OP has to pick the script, maybe they get the wrong one ?

95% safe. 🙂

ECCAD

[paullimapa]

If you get a chance assuming you're converting dwgs to dxfs try this lisp file which uses AcCoreconsole to do the conversion without a need to open each dwg on the graphics window.