trim text and add bradkets

[Anonymous]

Hello all.  below is a small lisp routine where i can pick text and it will add brackets and an X to the front and a bracket to the end.  I would like to modify this so it will remove the last character of the text i pick before if adds the brackets and the X.  Can anyone help me modify this?

(defun c:P4( / i s x )
(if (setq s (ssget "_:L" '((0 . "TEXT") (1 . "~(*)"))))
(repeat (setq i (sslength s))
(setq e (entget (ssname s (setq i (1- i))))
x (assoc 1 e)
)
(entmod (subst (cons 1 (strcat "(X" (cdr x) ")")) x e))
)
)
(princ)
)

[dlanorh]

Please provide an example of the before and after text, as removing the last character could result in "Code" becoming "(X Cod)"; or is this a strip space or punctuation?

[Anonymous]

before = 00300+

after = (X00300)

thanx

[dlanorh]

Is it always a "+" at the end?

[Moshe-A]

@Anonymous,

check this

(defun c:P4 (/ i s x l)
 (if (setq s (ssget "_:L" '((0 . "TEXT") (1 . "~(*)"))))
  (repeat (setq i (sslength s))
   (setq e (entget (ssname s (setq i (1- i))))
         x (assoc 1 e)
	 l (strlen (cdr x))
   )
   (entmod (subst (cons 1 (strcat "(X" (substr (cdr x) 1 (1- l)) ")")) x e))
  )
 )
 (princ)
)

[Anonymous]

yes, it is always a "+"

thanx

[dlanorh · Accepted solution]

OK

Try this

(defun c:P4( / i s e x txt)
  (if (setq s (ssget "_:L" '((0 . "TEXT") (1 . "~(*)"))))
    (repeat (setq i (sslength s))
      (setq e (entget (ssname s (setq i (1- i))))
            x (assoc 1 e)
            txt (substr (cdr x) 1 (1- (strlen (cdr x))))
      )
      (entmod (subst (cons 1 (strcat "(X" txt ")")) x e))
    )
  )
  (princ)
)

[Anonymous]

Hi Moshe-A.  I see your solution was just to remove the last character.  it works for me.

thanks for you help

[Anonymous]

Hi dlanorh,

this one worked too.  that everyone for the help

[dlanorh]

Or using visual lisp

(defun c:P4( / c_doc ss)
  (vl-load-com)
  (setq c_doc (vla-get-activedocument (vlax-get-acad-object))
        ss (ssget "_:L" '((0 . "TEXT") (1 . "~(*)")))
  )      
  (if ss
    (vlax-for t_obj (vla-get-activeselectionset c_doc)
      (vlax-put-property t_obj 'textstring (strcat "(X" (vl-string-right-trim "+" (vlax-get-property t_obj 'textstring)) ")"))
    );end_for
  );end_if
  (princ)
);end_defun

[dlanorh]

@Moshe-A's solution works too. I think you need to credit him once and not me twice.

[Anonymous]

Hello all,

I appologize for not giving credit proporly to the people that help.  There was not intent just my enexperince with this form.

so thanks again to all for the quick response and good solution