Transforming a list of lists

[Browning_Zed]

Dear sirs, tell me how to resolve the issue.
How can I transform a list like this:
((Vol-1 ("A" "B") ("C" "D") ("E" "F")) (Vol-2 (1 2) (3 4) (5 6)) (Vol-3 (x x) (y y) (z z)))
to a list of this form:
(("A" "B") ("C" "D") ("E" "F") (1 2) (3 4) (5 6) (x x) (y y) (z z))
Thank you in advance for your help.

[ВeekeeCZ · Accepted solution]

(apply 'append (mapcar 'cdr lst))

[john.uhden]

@ВeekeeCZ 

Blast it all.  You beat me.  Y'know, I have to work now and then.  😕

[pbejse · Accepted solution]

---

@Browning_Zed wrote:

How can I transform a list like this:
((Vol-1 ("A" "B") ("C" "D") ("E" "F")) (Vol-2 (1 2) (3 4) (5 6)) (Vol-3 (x x) (y y) (z z)))
to a list of this form:
(("A" "B") ("C" "D") ("E" "F") (1 2) (3 4) (5 6) (x x) (y y) (z z))

---

And because the #1 Draft pick is already taken. Here's an alternative solution

(Defun _theRestI (l / i nl)
  (repeat (setq i (length l))
    (setq nl (append (cdr (nth (setq i (1- i)) l)) nl))
  )
  nl
)

_$ (setq lst '((Vol-1 ("A" "B") ("C" "D") ("E" "F")) (Vol-2 (1 2) (3 4) (5 6)) (Vol-3 (x x) (y y) (z z))))
((VOL-1 ("A" "B") ("C" "D") ("E" "F")) (VOL-2 (1 2) (3 4) (5 6)) (VOL-3 (X X) (Y Y) (Z Z)))
_$ (apply 'append (mapcar 'cdr lst))
(("A" "B") ("C" "D") ("E" "F") (1 2) (3 4) (5 6) (X X) (Y Y) (Z Z))
_$ (_theRestI lst)
(("A" "B") ("C" "D") ("E" "F") (1 2) (3 4) (5 6) (X X) (Y Y) (Z Z))

HTH

[john.uhden]

@pbejse 

I intend to get drafted before you do...

(though the last time there was a draft I joined the National Guard instead)

(Defun _theRestJU (l / nl)
  (while l
    (setq nl (append nl (cdar l)) l (cdr l))
  )
  nl
)

[pbejse]

(defun _theRestR (l)
  (if l
    (append (cdr (Car l)) (_theRestR (cdr l))))
  )

[hak_vz]

Here is another one collected from some old LISP book, basically equal to @ВeekeeCZ 

(setq lst '((Vol-1 ("A" "B") ("C" "D") ("E" "F")) (Vol-2 (1 2) (3 4) (5 6)) (Vol-3 (x x) (y y) (z z))))

(defun mappend (fn lst)(apply 'append (mapcar fn lst)))
(mappend 'cdr lst)
(("A" "B") ("C" "D") ("E" "F") (1 2) (3 4) (5 6) (X X) (Y Y) (Z Z))

[john.uhden]

@pbejse
Recursion beats me every time. Nice!
You're drafted. Except you ship out the day after Labor Day. 😕