Toggle mask fror mtext to work on mleaders too?

[DC-MWA]

Good morning,

I have a cool littl lisp that toggles the background mask on/off for selected mtext objects.

Wondering if anyone has something similar that will work on Mleaders as well? Or maybe a toggle lisp for mleaders that I can add to this routine to get what I'm looking for.

I have attached the lisp file.

Thanks!

[CodeDing]

@DC-MWA ,

I have this one laying around. Should do the trick.

EDIT:

I was perhaps a bit hasty. My approach merely APPLIES a background mask. It does not toggle. Maybe I can configure something new real quick...

EDIT 2:

Ok, I have updated the code below to TOGGLE. Give that a go.

(defun c:BM ( / ss e cnt)
  (prompt "\nSelect objects to toggle background mask: ")
  (if (setq ss (ssget '((0 . "MULTILEADER,MTEXT"))))
    (progn
      (repeat (setq cnt (sslength ss))
        (setq e (ssname ss (setq cnt (1- cnt))))
        (if (eq "MTEXT" (cdr (assoc 0 (entget e))))
          (progn
            (setpropertyvalue e "BackgroundFill" (abs (1- (getpropertyvalue e "BackgroundFill"))))
            (setpropertyvalue e "UseBackgroundColor" (abs (1- (getpropertyvalue e "UseBackgroundColor"))))
          );progn
          (setpropertyvalue e "MText/BackgroundFill" (abs (1- (getpropertyvalue e "MText/BackgroundFill"))))
        );if
      );repeat
      (command "_.REGEN")
      (prompt "\nBackground Masks have been Toggled.")
    );progn
  ;else
    (prompt "\nMust select either a Multileader or MText.")
  );if
  (setq ss nil)
  (princ)
);defun

Best,

~DD

[DC-MWA]

Thank you...

This is what I was looking for. How hard is it to make toggle on/off?

[CodeDing · Accepted solution]

@DC-MWA ,

I updated the code, please check again.

 Best,

~DD

[DC-MWA]

Perfect!

Thank you so very much. You gurus always amaze me with your knowledge and skills.

Have a great weekend!!!

[pbejse]

---

@DC-MWA wrote:

.. has something similar that will work on Mleaders as well? Or maybe a toggle lisp for

Thanks!

---

Here you go

(defun c:BM (/ ss e i prop)
  (if (setq ss (ssget ":L" '((0 . "MULTILEADER,MTEXT"))))
    (repeat (setq i (sslength ss))
      (setq e (ssname ss (setq i (1- i))))
      (setpropertyvalue
	e
	(setq prop
	       (if (eq (getpropertyvalue e "LocalizedName") "MText")
	  		"BackgroundFill" "MText/BackgroundFill" )
	  )
	  (boole 6 1 (getpropertyvalue e prop))
	)
      )
    )
  (princ)
)

HTH 

[ccnoah]

When I run this on MTEXT entities, to toggle on the background mask, it is using fill color 200,200,200 for the background color.  Anyway to have it force "use drawing background color" ?

thank you

[ccnoah]

okay, figured out if i comment out this line, it works like i want.

(setpropertyvalue e "UseBackgroundColor" (abs (1- (getpropertyvalue e "UseBackgroundColor"))))