To Find Self Intersection of LWPOLYLINE
I didn't make it in 1 second:
Команда: SELFINTERS
Pick LWPOLYLINE to find self-intersecting points...
Elapsed time : 318047 milliseconds...
Команда: SELFINTERS
Pick LWPOLYLINE to find self-intersecting points...
Elapsed time : 208078 milliseconds...
((7653912.613957368 6229064.962335566) (7653912.613957532 6229064.962335717))
Команда: SELFINTERS
Pick LWPOLYLINE to find self-intersecting points...
Elapsed time : 169422 milliseconds...
((7653288.087277066 6229052.952317797) (7653288.08727723 6229052.952317947) (7652990.315149783 6229574.36978839) (7652990.079111385 6229574.941561909))
I still haven't given up. Read the remarks within the code (below).
Try this one out including the time test. I can't do any time testing because:
- I'm not going to make a 4,500 vertex polyline.
- I'm still running ACAD2002.
- My computer is just slightly faster than a paralyzed slug.
Notice the difference in results between E2, E4, and E5. E2 has an invalid self intersection at parameter 5. It appears that vlax-curve-getdistatpoint sometimes screws up with clockwise arced segments. Same is true for vlax-curve-getparamatpoint.
(defun selfinters2 (e / @2d @remdupes @dupes -pts -dupes -obj -flat -ints -items -found -selfs)
;; John F. Uhden (11-22-2024 through 12-28-2024)
;; Function finds all self intersections of a LWPolyline,
;; including intersections between vertices and at vertices
;; where parameters are not consecutive.
;; Can return a list of self intersections...
;; Just change the last line from (if selfs T nil) to just selfs
;; This version neither copies nor explodes a copy of the polyline.
;; I don't know if it's any faster or not.
;; This version places a red circle at each vertex
;; and a slightly larger green circle at each self intersection.
;; Feel free to remove or rem out the lines containing (entmakex ...).
(foreach atom '(@2d @remdupes @dupes pts dupes obj flat ints param items found selfs) (set atom nil))
(defun @2d (p)(mapcar '* p '(1 1)))
;; Considering that a list may be all numbers (real and/or integer),
;; then we should account for a fuzz factor:
(defun @remdupes (old fuzz / new)
(foreach item old
(if (vl-every '(lambda (x)(not x))(mapcar '(lambda (x)(equal item x fuzz)) new))(setq new (cons item new)))
)
(reverse new)
)
(defun @dupes (pts fuzz / dupe dupes)
(foreach p pts
(if (>= (length (vl-remove-if-not (function (lambda (x)(equal p x fuzz))) pts)) 2)
(setq dupes (cons p dupes))
)
)
(@remdupes dupes fuzz)
)
(and
(setq pts (mapcar 'cdr (vl-remove-if-not (function (lambda (x)(= (car x) 10))) (entget e))))
(foreach p pts (entmakex (list '(0 . "CIRCLE")(cons 10 p)(cons 40 0.2)(cons 62 1))))
;; Dupes are where two or more vertices meet at the same point:
(setq dupes (@dupes pts 1e-8) selfs dupes)
(setq pts (mapcar (function (lambda (x)(cons (vlax-curve-getdistatpoint e x) x))) pts))
(setq pts (vl-sort pts (function (lambda (a b)(< (car a)(car b))))))
(setq obj (vlax-ename->vla-object e))
(setq flat (vlax-invoke obj 'intersectwith obj 0)) ;; flat list
(while flat
(repeat 3 (setq item (cons (car flat) item) flat (cdr flat)))
(setq ints (cons (@2d (reverse item)) ints) item nil)
1
)
(setq ints (mapcar (function (lambda (x)(cons (vlax-curve-getdistatpoint e x) x))) ints))
(setq ints (vl-sort ints (function (lambda (a b)(< (car a)(car b))))))
;; Find self intersections between vertices, if any,
;; by comparing distances along the path:
(foreach int ints
(setq found nil items pts)
(while (and (not found)(>= (length items) 2))
(setq found (< (caar items)(car int)(caadr items)) items (cdr items))
;; or maybe
;; (setq found (vl-remove-if-not (function (lambda (a b)(< (car a)(car int)(car b)))) pts))
)
;; (print found)
(if found (setq selfs (cons (cdr int) selfs)) 1)
)
(or (terpri) 1)
(foreach p selfs (entmakex (list '(0 . "CIRCLE")(cons 10 p)(cons 40 0.3)(cons 62 3))))
)
(if selfs T nil)
)
The yellow circles are what's not found:
Nothing found in million coordinates.
But with “houses” it's found.
Except for scaling, this version appears to work properly.
Please test for satisfaction and time.
(defun selfinters3 (e / @2d @fence -obj -item -flat filter ss -ints -selfs)
;; John F. Uhden (11-22-2024 through 01-01-2025)
;; Function finds all self intersections of a LWPolyline,
;; including intersections between vertices and at vertices
;; where parameters are not consecutive.
;; Returns T for any self-intersections or nil if none.
;; This version neither copies nor explodes a copy of the polyline.
;; Nor does it use distances anlong the polyline path.
;; This version uses a square fence to ssget the polyline at all intersections
;; and ssnamex to determine the number of spokes coming out of each point.
;; More than 2 spokes means a self intersection.
;; This version places a red circle at each intersection
;; and a slightly larger green circle at each self intersection.
;; Feel free to remove or rem out the lines containing (entmakex ...).
(foreach atom '(@2d @fence obj item flat ints selfs) (set atom nil))
(defun @2d (p)(mapcar '* p '(1 1)))
(defun @fence (p w)
;; where w is actually half width
(list
(mapcar '+ p (list w w)) ;; upper right
(mapcar '+ p (list (- w) w)) ;; upper left
(mapcar '- p (list w w)) ;; lower left
(mapcar '+ p (list w (- w))) ;; lower right
(mapcar '+ p (list w w)) ;; upper right (beginning but not closed)
)
)
(setq obj (vlax-ename->vla-object e))
(setq flat (vlax-invoke obj 'intersectwith obj 0)) ;; flat list
(while flat
(repeat 3 (setq item (cons (car flat) item) flat (cdr flat)))
(setq ints (cons (@2d (reverse item)) ints) item nil)
)
(setq filter (list '(0 . "LWPOLYLINE")))
(foreach p ints
(entmakex (list '(0 . "CIRCLE")(cons 10 p)(cons 40 0.2)(cons 62 1)))
(and
(setq ss (ssget "_F" (@fence p 0.25) filter))
(> (length (mapcar 'cadr (cdddr (last (ssnamex ss 0))))) 2)
(setq selfs (cons p selfs))
(entmakex (list '(0 . "CIRCLE")(cons 10 p)(cons 40 0.3)(cons 62 3)))
)
)
(if selfs T nil)
)
О! Now almost everything is found!
Except for two cases in my test start_test_100-100_ju3_test.dwg, everything is found:
Unstable results in my test mill_pl.dwg with coordinates in millions - either finds nothing or finds a lot of unnecessary things.
I attach a polyline with a small number of vertices, in normal coordinates, where false results are obtained - pl181.dwg.
