To Find Self Intersection of LWPOLYLINE
@MehtaRajesh wrote:
....
I am posting useful function to find Self Intersection for selected LWPOLYLINE.
You might be having other options....
Below Function to get the Coordinate list of LWPOLYLINE
....
The (inters) approach in yours [which considers only the straight-line directions between designated points] would miss intersecting arc segments, such as a situation like this:
Here's a way to test for self-intersection that will catch those. It's worth reading other posts on this thread that it comes from, for various considerations, other attempts and their shortcomings, remaining limitations of this one, etc.
;; Function name: PSC = Polyline Self-Crossing
;; To determine whether a Polyline of any type Crosses itSelf.
;; With 3D Polylines, must have true intersection in 3D, not apparent in 2D.
;; Returns T if self-crossing, nil if not.
(defun PSC (poly / pltyp plobj plverts plints)
(setq
pltyp (cdr (assoc 0 (entget poly)))
plobj (vlax-ename->vla-object poly)
plverts (length (safearray-value (variant-value (vla-get-Coordinates plobj))))
plints (/ (length (safearray-value (variant-value (vla-intersectwith plobj plobj acExtendNone)))) 3)
); end setq
(setq plverts (/ plverts (if (= pltyp "LWPOLYLINE") 2 3)))
(if (vlax-curve-isClosed poly)
(< plverts plints); then - closed
(if (equal (vlax-curve-getStartPoint poly) (vlax-curve-getEndPoint poly) 1e-8); else - open
(<= plverts plints); then - start/end at same place
(<= plverts (1+ plints)); else - open
); if
); if
); defun
(vl-load-com)
Usage: (PSC PolylineEntityName)
And although the above doesn't use this method to get them, here's a more concise way to get the Coordinates list of LWPolyline vertices [with its entity-data list as the 'lst' argument], directly, without the need for variables or (cons) or (reverse) functions:
(defun lwpverts (lst)
(mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) lst))
)
patrice.braud wrote:....
I am looking for a routine to detect (get them as a selection at the end of the routine)
from a classic ACAD selection of MANY 2D Plines and 2D LWPlines ?
....
If ALL 2D Plines and 2D LWPlines have NO SelfIntersect, the current selection will be empty at the end ...
....
Welcome to these Forums! [Any relation to @braudpat?]
Certainly that can be done. In barest terms, something like this [untested]:
(setq
PSS (ssget '((0 . "*POLYLINE"))); Polyline Selection Set
SIPSS (ssadd); initially empty Self-Intersecting Polyline Selection Set
); setq
(if PSS
(repeat (setq n (sslength PSS))
(setq PL (ssname PSS (setq n (1- n))))
(if (PSC PL) (ssadd PL SIPSS)); if it's self-intersecting, put it into SIPSS
); repeat
); if
The SIPSS selection set should then have any self-intersecting Polylines from the selection in it, or be empty [but not nil] if none were found.
Or, if you want to just remove those that don't intersect themselves from the original set, rather than make a different set:
(setq PSS (ssget '((0 . "*POLYLINE")))); Polyline Selection Set
(if PSS
(repeat (setq n (sslength PSS))
(setq PL (ssname PSS (setq n (1- n))))
(if (not (PSC PL)) (ssdel PL SIPSS)); if it's not self-intersecting, remove it from PSS
); repeat
); if
Hello Kent
1) The most important : THANKS !
2) You are Mr Sherlock HOLMES : of course I am "braudpat" !
3) SORRY I was walking through Forums with the wrong Login ...
Regards, Patrice
If you are happy with my answer please mark "Accept as Solution" and if very happy please give me a Kudos (Felicitations) - Thanks
Patrice BRAUD
@bergerF5EFQ wrote:
Unfortunately this code can't detect some simple self-intersecting polylines ....
That has to do with self-intersecting points being at vertices. See the last sentence before the code in Message 2 -- that is specifically one of the shortcomings discussed in the linked topic.
Whether that can be accounted for in a way that would cover all possibilities, I'm not sure. Going through the vertices to see whether there are any repeats would catch those self-intersections. But it won't be enough -- the test fails for even a self-intersection by a vertex lying somewhere along another segment but not at another vertex:
If you define intersecting as any two segments that share a point, then all polylines are self-intersecting. You can iterate the segments and remove where the end is the same as the beginning of the next, but how about where the beginning and end coincide?
import traceback
from pyrx_imp import Rx, Ge, Gi, Db, Ap, Ed
def PyRxCmd_doit() -> None:
try:
es = Ed.Editor.entSel("\nSelect: ", Db.Polyline.desc())
tol = Ge.Tol.current().equalPoint()
pl = Db.Polyline(es[1])
cl = pl.getAcGeCurve().explode()
cllen = len(cl)
for lidx in range(cllen):
for ridx in range(lidx + 1, cllen):
cci = Ge.CurveCurveInt3d(cl[lidx], cl[ridx])
for i in range(cci.numIntPoints()):
prs = cci.getIntParams(i)
print(prs)
if prs[1] < tol:
continue
if prs == (1.0, 0.0):# or (0.0, 1.0)?
continue
Ed.Core.grDrawCircle(cci.intPoint(i), 5, 20, 3)
except Exception as err:
traceback.print_exception(err)
@john.uhden wrote:
... wouldn't (vla-intersectwith obj obj) return the self-intersecting coordinates, excluding corners?
No [easy enough to try], it includes the corners, as "intersections" of segments. That's exactly how the code in Message 2 works: it compares the number of vertices with the number of intersections that (intersectwith) returns. The latter number includes everything in the former number plus any self-intersections that do not coincide with vertices, so that result would be larger if there are self-intersections. But it counts any particular location only once, even if more than one thing happens there, which is why it can't be relied on if vertices coincide, or if a vertex lies somewhere along another segment.
Um... Probably, cases with "houses" can not be considered cases of self-crossing?.. Um...
Attached his other simplest example.
PSC returns T if this polyline is not Closed. And returns nil if Closed.
@АлексЮстасу wrote:
....
PSC returns T if this polyline is not Closed. And returns nil if Closed.
For me, if it's drawn around to its beginning and then closed, for a zero-length closing segment, it returns nil. But if it's closed in the normal way, without the zero-length closing segment, it returns T. I'm sure the coincident vertices and zero-length segment [which intersects both the first and otherwise-last segments] are to blame. No, it's not universally foolproof under all possible circumstances, but I hope is good for "typical" or "clean" scenarios -- see the Topic linked to in Message 2, which discusses such things.
@АлексЮстасу wrote:
.... Then I decided to draw a typical house as a joke, but your function for it returns nil, no self-crossing.....
That's specifically because of what is described in the last sentence in Message 11.