System Variable for Crosshair Color
Unfortunately, there is no System Variable to change Crosshair Color.
You'll have to set ModelCrosshairColor property at display object.
Henrique
damian.wrobel wrote:
But there is error: too few arguments.
What is bad?
You are missing the arguments/variable list for the defun expression, hence set_xhair_clr & color are being interpreted as arguments required by the function.
Perhaps try the following code instead:
(defun c:ccch ( / c )
(if (setq c (acad_colordlg 7 nil))
(vla-put-modelcrosshaircolor
(vla-get-display (vla-get-preferences (vlax-get-acad-object)))
(LM:ACI->OLE c)
)
)
(princ)
)
;; ACI -> OLE - Lee Mac
;; Args: c - [int] ACI (AutoCAD Colour Index) Colour (1<=c<=255)
(defun LM:ACI->OLE ( c )
(apply 'LM:RGB->OLE (LM:ACI->RGB c))
)
;; RGB -> OLE - Lee Mac
;; Args: r,g,b - [int] Red, Green, Blue values
(defun LM:RGB->OLE ( r g b )
(logior (fix r) (lsh (fix g) 8) (lsh (fix b) 16))
)
;; ACI -> RGB - Lee Mac
;; Args: c - [int] ACI (AutoCAD Colour Index) Colour (1<=c<=255)
(defun LM:ACI->RGB ( c / o r )
(if (setq o (vla-getinterfaceobject (LM:acapp) (strcat "autocad.accmcolor." (substr (getvar 'acadver) 1 2))))
(progn
(setq r
(vl-catch-all-apply
'(lambda ( )
(vla-put-colorindex o c)
(list (vla-get-red o) (vla-get-green o) (vla-get-blue o))
)
)
)
(vlax-release-object o)
(if (vl-catch-all-error-p r)
(prompt (strcat "\nError: " (vl-catch-all-error-message r)))
r
)
)
)
)
;; Application Object - Lee Mac
;; Returns the VLA Application Object
(defun LM:acapp nil
(eval (list 'defun 'LM:acapp 'nil (vlax-get-acad-object)))
(LM:acapp)
)
(vl-load-com) (princ)
Colour conversion functions are from my site here.
To call Jeff Mishler's code, try
;CCCH = Color CrossHair
(defun c:CCCH ( / color flag)
(setq flag t)
(while flag
(initget 6)
(setq color (getint "\nType the value to set CrossHair's color [1/2/3/4/5/6/7]: "))
(cond ((and (= 'INT (type color))
(< 0 color 8)
)
(set_xhair_clr color)
(setq flag nil)
)
((and (= 'INT (type color))
(not (< 0 color 8))
)
(princ "\nColor value, must be from 1 to 7...")
)
((not color)
(princ "\nExiting...")
(setq flag nil)
)
)
)
(princ)
)
; http://forums.autodesk.com/t5/visual-lisp-autolisp?-and-general/crosshairs-color-system-variable/m-p/?1481297#M196118
; by Jeff Mishler
(defun set_xhair_clr (color)
(cond ((eq color 1)(setq color 255))
((eq color 2)(setq color 65535))
((eq color 3)(setq color 65280))
((eq color 4)(setq color 16776960))
((eq color 5)(setq color 16711680))
((eq color 6)(setq color 16711935))
((eq color 7)(setq color 16777215))
(t(setq color 1))
)
(vla-put-ModelCrosshairColor
(vla-get-display
(vla-get-Preferences
(vlax-get-acad-object)
)
)
color
)
)
Henrique
gpcattaneo wrote:
Also...
(defun c:ccch ( / c )
(if (setq c (acad_colordlg 7 nil))
(setenv "XhairPickboxEtc" (itoa (LM:ACI->OLE c)))
)
(princ)
)
Well found GP - I was looking for that registry key before posting! 
damian.wrobel wrote:
Lee Mac, your lisp is something what I dreamed about. Great respect.
Thank you damian.
damian.wrobel wrote:
But even more I would like lisp for "Change Color of selected Objects with the DialogBox 'Select Color'".
So it would be something like you just did for the CrossHair, but it would be for Objects.
Soon for a long time I wanted a lisp for it. When I had to change the colour of some Object, I had to go in the Properties Palette (Ctrl+1, remember)
and there I clicked in specified cell and exclusively in this moment I could change its color.
Such a program could quite easily be written, but I see no need for the program -
Why not make a selection of objects & simply use the Object Colour drop-down?
gpcattaneo wrote:
Lee_Mac wrote
Well found GP...
Hi Lee, your LM:RGB/ACI/OLE functions are fantastic.
Thanks GP!