Subtract text from a list

[carlos_m_gil_p]

Hello boys how are you.

I have this list stored in a variable.

(setq lst-dxf-panel '(-3 ("MELIA_MPANE" (1000 . "Edge = Weft") (1000 . "Panel ID = 1.1"))))

As I can subtract the value of Panel ID

In this case "1.1"

Thanks for your help and excuse my English.

[ВeekeeCZ]

(substr (cdar (cddadr lst)) 12)

or

(substr (cdr (assoc 1000 (reverse (cadr lst)))) 12)

[carlos_m_gil_p]

Hi BeekeeCZ, How are you.
Thanks for your help.

I did the tests but if Panel ID is in the other side of the list does not work for me.

The Panel ID ubicaion may vary.

(setq lst-dxf-panel '(-3 ("MELIA_MPANE" (1000 . "Edge = Warp") (1000 . "Panel ID = 1.1") (1000 . "Description = created by mesh to panel, panel 1") (1000 . "Shear Strain =0.393%") )))

Thanks

[ВeekeeCZ · Accepted solution]

Try then... (substr (cdar (vl-remove-if-not '(lambda (x) (wcmatch (cdr x) "Panel ID*")) (cdadr lst-dxf-panel))) 12)

[carlos_m_gil_p]

It works very well, thank you very much.

[john.uhden]

(setq lst-dxf-panel
  '(-3
     ("MELIA_MPANE"
        (1000 . "Edge = Weft")
        (1000 . "Panel ID = 1.1")
     )
   )
)
(setq ID
  (car
    (vl-remove-if-not
      '(lambda (x)(wcmatch (cdr x) "Panel ID*"))
       (cdadr lst-dxf-panel)
    )
  )
)
;; returns (1000 . "Panel ID = 1.1")
(setq old (substr (cdr ID) 12))
;; returns "1.1"
(setq additive -0.1)
(setq new (+ (atof old) additive))
;; returns 1.0
(setq new (rtos new 2 1))
;; returns "1.0"
(setq new (cons 1000 (strcat "Panel ID = " new)))
;; returns '(1000 . "Panel ID = 1.0")
(setq new (subst new ID (cadr lst-dxf-panel)))
(setq rev-dxf-panel (cons -3 (list new)))

[carlos_m_gil_p]

Thanks john.uhden