Step through layers - if *match, then..
@Anonymous wrote:
... if there's a match of "*EXIST", it runs the function I've written up. ....
....
(setq layOld (getvar "clayer")) (setq layNew (strcat layOld "-OFF")) .... (command "-COPYTOLAYER" ss "" layNew "y" "0,0,0" "") ....
I wonder whether you really want the layNew variable like that. If the current Layer when you run the routine happens to be 0, then everything on any Layer whose name contains "EXIST" will be copied onto a Layer called "0-OFF" regardless of what Layer its source object was on. Is that the intent? Wouldn't you want things copied to Layers that are named the same as the Layers the objects are on, with the "-OFF" suffix added? If something's on a Layer called "WALLEXIST1", don't you want it copied onto a Layer called "WALLEXIST1-OFF", rather than to a Layer called "0-OFF", or "Defpoints-OFF", or some other name based on whatever the current Layer happens to be?
If that's the case, here's a different [and look how short!] approach. Don't do it by Layers, but by objects, using (ssget) to find all things on any Layer containing "EXIST" in its name, all at once. Then rather than use COPYTOLAYER, (entmake) a copy of each with a suffixed Layer name.
You don't have to exclude Xref Layers, because (ssget) won't see things on those Layers. And you don't have to check whether a newly-suffixed Layer name exists, because this kind of (entmake (subst....)) approach will create the Layer in the process. And you would need to decide what you want to do about locked Layers -- this doesn't prevent making copies of things on locked Layers, because it doesn't affect those things themselves at all. Mildly tested:
(defun C:TEST (/ ss n edata)
(if (setq ss (ssget "_X" '((8 . "*EXIST*"))))
(repeat (setq n (sslength ss))
(setq edata (entget (ssname ss (setq n (1- n)))))
(entmake (subst (cons 8 (strcat (cdr (assoc 8 edata)) "-OFF")) (assoc 8 edata) edata))
); repeat
); if
(princ)
); defun
But if you really do want the new suffixed Layer name to be based on whatever the current Layer is, and things from all those other Layers copied onto the one common suffixed Layer, just replace
(cdr (assoc 8 edata))
in the above with
(getvar 'clayer)
Kent Cooper, AIA 
@Kent1Cooper wrote:
.. Don't do it by Layers, but by objects, using (ssget) to find all things on any Layer containing "EXIST" in its name, all at once.
I concur, that's how i would approach too.
@Anonymous wrote:
One thing I noticed however is the layer properties aren't being copied over 😕
Is this a filter problem?
Also can someone please point me in the direction for a complete list of all the ssget filters?
Read the >Help entry for (ssget)<.
It's not a filter problem. It's from the fact that in the case of creating a Layer as a result of putting something on it in that way when the Layer doesn't already exist, that new Layer gets all the default properties, such as Continuous linetype and color 7. I didn't try to do anything else about that because your original didn't assign any such properties, either.
That would take some stepping through Layers, looking for those whose names end with "-OFF", digging out the properties of the same Layer name without the suffix, and assigning those to the one with it. I could probably work that out, but not tonight....
Kent Cooper, AIA
Accepted solution
@Anonymous wrote:
One thing I noticed however is the layer properties aren't being copied over....
A simpler way to do that is the same way the copies of the objects are made -- take the entity data for the Layer "object" from the table, and (entmake) another the same except for (subst)ituting a suffixed name. All the other properties are carried over into the new Layer.
(defun C:TEST2 (/ ss n edata ldata oldlay)
(if (setq ss (ssget "_X" '((8 . "*EXIST*"))))
(repeat (setq n (sslength ss))
(setq
edata (entget (ssname ss (setq n (1- n))))
ldata (entget (tblobjname "layer" (setq oldlay (cdr (assoc 8 edata)))))
)
(entmake (subst (cons 2 (strcat oldlay "-OFF")) (assoc 2 ldata) ldata))
(entmake (subst (cons 8 (strcat oldlay "-OFF")) (assoc 8 edata) edata))
); repeat
); if
(princ)
); defun
Kent Cooper, AIA
