Show Distance between two lines at fixed interval

[Anonymous]

Hi,

I have a project where a cable is laid along a road. I need to show the perpendicular distance of the cable from the road centerline at every 10m interval. I cannot do it manually as the cable length is in 100s of kms. I have been using autocad for a long time but am new to LISP. 

Is there a LISP code that can do this?

Please help.

Thanks

[devitg]

Yes, it could be possible . Please upload a dwg sample . 

[Anonymous]

Thanks for the reply devitg. PFA the sample drawing.

I have put chainage on the cable route (red line). The black line is the road centerline. I need the perpendicular distance from the cable to the road centerline at every 10m. I have done it for the first four chainage points (from 00+000 t0 00+040) points manually to make it clear. 

[ВeekeeCZ · Accepted solution]

Try this routine

Spoiler

(vl-load-com)

(defun c:DimPl2Pl ( / en1 en2 int len stt len pt1 pt2)
  
  (if (and (setq en1 (car (entsel "\nSelect 1st polyline (dim from): ")))
	   (= "LWPOLYLINE" (cdr (assoc 0 (entget en1))))
	   (setq en2 (car (entsel "\nSelect 2nd polyline (dim to): ")))
	   (= "LWPOLYLINE" (cdr (assoc 0 (entget en2))))
	   (setq int (getdist "\nInterval: "))
	   (setq len (vlax-curve-getDistAtParam en1 (vlax-curve-getEndParam en1)))
	   (not (initget 4))
	   (setq stt (cond ((getreal "\nDistance at the beginning <0>: "))
			   (0)))
	   (not (initget 4))
	   (setq len (cond ((getreal (strcat "\nDistance at the end <along the entire polyline = " (rtos len 2 2) ">: ")))
			   (len)))
	   )
    (while (and (<= stt len)
		(setq pt1 (vlax-curve-getPointAtDist en1 stt))
		(setq pt2 (vlax-curve-getClosestPointTo en2 pt1)))
      (command "_.DIMALIGNED"
	       "_none" (trans pt1 0 1)
	       "_none" (trans pt2 0 1)
	       "_none" (polar (trans pt1 0 1)
			      (+ (* 1.5 pi)
				 (angle (trans pt1 0 1) (trans pt2 0 1)))
			      1.5))
      (setq stt (if (= stt (min (+ stt int) 	; if next point is beyond the end length
				len))	
		  (+ stt int)			; then use that it because which (while) does not pass
		  (min (+ stt int)		; else use middle point or max
		       len))))
    (princ "\nWrong selection. Two LWPolylines are required.")
    )
  (princ)
)

- make sure that the first polyline (which on would be applied the interval) is in the correct direction - in your sample is NOT!

- make sure that the both polylines are correctly joined (the second polyline in your sample is NOT)

- i would recommend flat both (3d)polylines to polylines

- I think the better result you'll get if you would dimension from the cable line, not from the axis (at least at some parts.. - dim is put at the clostest point on second polyline). 

Sorry @devitg, I hope you don't mind. I just quickly adjusted some older routine of mine.

[Anonymous]

Thanks BeeKeeCZ! This is exactly what i wanted. Thanks for pointing out the blind spots. I will remember to merge the polylines before applying it.

Thanks a ton!! 🙂

[devitg]

Hi BeekeeCZ , do noy worry , all help is wellcome , I just ask the OP to upload the DWG. 
All poster think that with words, they can get answer . 
Seem to be they think  this forum is a ORACLE " A person considered to be a source of wise counsel or prophetic opinions."
 
Or in a rude way "NO CORPSE, NO COFFIN"

[Anonymous]

Hey BeekeeCZ, I was attempting to modify your code you created here.

I was attempting to modify it where it found a line perpendicular off of the first line you select, but keep running into a wall. See screenshot for intent. 

Would appreciate any direction, thanks! 

(if (and (setq en1 (car (entsel "\nSelect polyline to dimension from: ")))
	   (= "LWPOLYLINE" (cdr (assoc 0 (entget en1))))
	   (setq en2 (car (entsel "\nSelect polyline to dimension to: ")))
	   (= "LWPOLYLINE" (cdr (assoc 0 (entget en2))))
	   (setq int (getdist "\nSpecify spacing interval: "))
	   (setq len (vlax-curve-getDistAtParam en1 (vlax-curve-getEndParam en1)))
	   (not (initget 4))
	   (setq stt (cond ((getdist "\nSpecify offset from beginning <0>: ")) (0)))
	   (not (initget 4))
	   (setq len (cond ((getdist (strcat "\nSpecigy length of path to use for measurement <" (if (= (getvar 'measurement) 0) (rtos len 4 5) (rtos len 2 2)) ">: "))) (len)))
	   )

   (while (and (<= stt len)
		(setq pt1 (vlax-curve-getPointAtDist en1 stt))
		(setq pt2 (vlax-curve-getPointAtDist en1 int))
		(setq pt3 (polar (trans pt1 0 1) (+ (/ pi 2) (angle (trans pt1 0 1) (trans pt2 0 1))) 1.5))
		(setq pt4 (vlax-curve-getPointAtDist en2 stt))
		(setq pt5 (vlax-curve-getPointAtDist en2 int))
		(setq pt6 (inters pt1 pt3 pt4 pt5 nil))
		
		)
		      
	(command "_.DIMALIGNED"
	       "_none" (trans pt1 0 1)
	       "_none" (trans pt6 0 1)
		   "_none" (polar (trans pt1 0 1) (+ (* 1.5 pi) (angle (trans pt1 0 1) (trans pt6 0 1))) 1.5))
		   	  
    (setq stt (if (= stt (min (+ stt int) 	; if next point is beyond the end length
				len))	
		  (+ stt int)			; then use the beyond len which (while) does not pass
		  (min (+ stt int)		; else use middle point or max
		       len))))
			   
    (princ "\nError. Two polylines are required.")
    )

[ВeekeeCZ]

Next time post the entire code and some test dwg.

My approach would be:

(foreach pnt on pl1

 - get angle (vector of pl) at pnt using: (angle '(0 0 0) (vlax-curve-getFirstDeriv path pnt))))

 - entmakex templine, example HERE

 - find all intersection points tmp vs. pl2 using the intesectwith method, example HERE

 - if there is (are) any int-pnts, draw dim

 - erase templine)

Good luck

[brodie.mclean]

Hey, 

I know this is an old thread, but i'm wondering if this code can be modified to dimension from an Alignment to a Corridor Created Feature Line?

Thanks, 

Brodie

[devitg]

Please upload your sample.dwg 

[brodie.mclean]

Sorry my sample drawing has short-cut data and can't be uploaded. 

Here's the jist: 

- I have an alignment from which I have created a corridor from that has varying widths. 

- From the corridor i created a linked feature line 

- I now want to auto-dimension between the Alignment and Feature line at a specified interval. 

[brodie.mclean]

Here's a dwg showing what I'm after. 

[devitg]

@brodie.mclean , please check the dwg , there aren't any alignment  , and  the feature line from corridor 

Either it is in true size, od scale 1:1 

[Sea-Haven]

This appears to be a CSD dwg going by the layer names, have you looked at the peg/shift option in the CSD road software.

[brodie.mclean]

It's a civil3d drawing. Are you opening it Civil? it' shows up correctly on my computer. 

[devitg]

@brodie.mclean , hi . No. I use ACAD 2018. Please save as to ACAD 2018 

[brodie.mclean]

Does this work? 

[devitg]

@brodie.mclean , no way. Sorry 

Despite it line length, differs a lot from real  

[Sea-Haven]

Civ3d will make alignments as proxy objects in Autocad.so will not have access.

[brodie.mclean]

Here a jist of what I'm looking for in a picture then..