Set text to center on circle by lisp

[ramoneramone]

I 'd like to set text to center on circle by lisp.

I tried it,but failed. Anyone teach how to?

1. select text

2. select circle for getting x.y.z

3. set text to center on circle

(progn

(setq sourceobj (entget (car (entsel "select text"))))

(setq circle(entget(car(entsel "select circle"))))

(setq var (cdr (assoc 10 circle)))

(entmod (subst (cons 11 var)(assoc 11 sourceobj) sourceobj))

(entmod (subst (cons 73 4)(assoc 73 sourceobj) sourceobj))

)

[paullimapa · Accepted solution]

this should take care of Text various insertion points:

(if(and(zerop (cdr (assoc 72 sourceobj)))(zerop (cdr (assoc 73 sourceobj))))
  (progn ; then, it's left-justified, so 
   (entmod (subst (cons 10 var)(assoc 10 sourceobj) sourceobj)) ; (cdr(assoc 10 sourceobj)) is the insertion point...
  )
  (progn ; ...else, it's some other justification, so
   (entmod (subst (cons 11 var)(assoc 11 sourceobj) sourceobj)) ; (cdr (assoc 11 sourceobj)) is the insertion point...
  )
) ; if

[Sea-Haven · Accepted solution]

Try this also resets text to Middle centre.

(defun c:wow (/ ss p11 circle pc sourceobj)
(setq sourceobj (car (entsel "select text")))
(setq ss (ssadd))
(setq ss (ssadd sourceobj ss))
(acet-tjust ss "MC")
(setq p11 (cdr (assoc 11 (entget sourceobj))))
(setq circle (entget (car (entsel "select circle"))))
(setq pc (cdr (assoc 10 circle)))
(command "move" sourceobj "" p11 pc)
(princ)
)
(c:wow)

[ramoneramone]

I have solved.

Thanks 

[ВeekeeCZ]

---

@ramoneramone wrote:

I 'd like to set text to center on circle by lisp.

I tried it,but failed. Anyone teach how to?

1. select text

2. select circle for getting x.y.z

3. set text to center on circle

(progn

(setq sourceobj (entget (car (entsel "select text"))))

(setq circle(entget(car(entsel "select circle"))))

(setq var (cdr (assoc 10 circle)))

(entmod (setq sourceobj (subst (cons 11 var)(assoc 11 sourceobj) sourceobj)))

(entmod (subst (cons 73 4)(assoc 73 sourceobj) sourceobj))

)

---

Aside other issues mentioned above, note that you need to SAVE the definition with the blue change otherwise the red change is applied to the original definition (without blue change).

[Sea-Haven · Accepted solution]

That explains why the text was jumping to wrong place when setting assoc 11.

[komondormrex · Accepted solution]

(defun c:m_text_center_circle (/ m_text_object circle_object)
  (prompt "\nPick M_Text: ")
  (setq m_text_object (vlax-ename->vla-object (ssname (ssget "_:S+." '((0 . "*text"))) 0)))
  (prompt "\nPick circle: ")
  (setq circle_object (vlax-ename->vla-object (ssname (ssget "_:S+." '((0 . "circle"))) 0)))
  (mapcar 'vlax-put (list m_text_object m_text_object)
    (if (= "AcDbText" (vla-get-objectname m_text_object))
     (list 'Alignment 'TextAlignmentPoint)
    (list 'Attachmentpoint 'InsertionPoint)
          )
           (if (= "AcDbText" (vla-get-objectname m_text_object))
         (list 4 (vlax-get circle_object 'center))
       (list 5 (vlax-get circle_object 'center))
          )
  )
)

[Kent1Cooper · Accepted solution]

If it's of any interest, this can certainly be done without changing the justification, by using the bounding box.

[Kent1Cooper]

---

@Kent1Cooper wrote:

If it's of any interest, this can certainly be done without changing the justification, by using the bounding box.

---

In which case, you can use it for Text or Mtext if you want, without caring about justification, but also for any other kind of object:

(defun C:O2CC (/ ent cir); = Object {to} Circle's Center
  (if
    (and
      (setq esel (entsel "\nSelect object to center in Circle: "))
      (setq csel (entsel "\nSelect Circle to center it in: "))
      (member '(0 . "CIRCLE") (setq cdata (entget (car csel))))
    ); and
    (progn ; then
      (setq ent (car esel))
      (vla-getboundingbox (vlax-ename->vla-object ent) 'minpt 'maxpt)
      (command "_.move" ent ""
        "_non" (mapcar '/ (mapcar '+ (vlax-safearray->list minpt) (vlax-safearray->list maxpt)) '(2 2 2))
        "_non" (cdr (assoc 10 cdata))
      )
    ); progn
    (prompt "\nMissed in selection, or second object was not a Circle.")
  ); if
  (prin1)
)

It could pretty easily be enhanced to let you select a Circle that's nested in a Block or Xref, if that's needed.