Community
Is this, perhaps, a ChatGPT or other AI effort? It has the earmarks of something that makes incorrect assumptions about what AutoLisp can do and how it works.
Where did the idea come from that there are System Variables called "DAY" and "MONTH" and "YEAR"?
(mapcar 'cadr (ssnamex ss)) will return a list of just entity names only if the objects are selected in certain limited ways.
What it thinks is going to be a list of Attributes will be only the Block entity name again. And what if a Block has more than one Attribute? Surely you don't want to put the date into every one -- shouldn't there be a check for the Tag?
There are fixes for a lot of these, but I gotta go....
Kent Cooper, AIA 
@karthikeyanskm wrote:
.... It is not working for the value in the attribute
As I sort of obliquely requested in Message 3: What is the Tag of the Attribute that you want changed to contain the date text?
Kent Cooper, AIA
@Kent1Cooper wrote:
.... What is the Tag of the Attribute that you want changed to contain the date text?
If we assume the Attribute's Tag is "DATE," this [incorporating @EnM4st3r's extraction of the date text] seems to work in limited testing:
(defun C:DateText (/ cdate dateStr ss ent atts attList)
(setq
cdate (rtos (getvar 'cdate) 2 0)
dateStr (strcat (substr cdate 7 2) "/" (substr cdate 5 2) "/" (substr cdate 1 4))
); setq
(if
(setq ss
(ssget "_:L" ; only on unlocked Layer(s)
'( ; filter list
(-4 . "<OR")
(0 . "TEXT,MTEXT"); any
(-4 . "<AND") (0 . "INSERT") (66 . 1) (-4 . "AND>"); only with Attribute(s)
(-4 . "OR>")
); filter list
); ssget
); setq
(progn ; then
(repeat (setq n (sslength ss))
(setq
ent (ssname ss (setq n (1- n)))
edata (entget ent)
etype (cdr (assoc 0 edata))
); setq
(if (wcmatch etype "*TEXT"); Text or Mtext
(entmod (subst (cons 1 dateStr) (assoc 1 edata) edata)); then
(if ; else -- Block
(not ; returns T if Block contains Attribute whose Tag is "DATE"
(vl-catch-all-error-p (vl-catch-all-apply 'getpropertyvalue (list ent "DATE")))
); not
(setpropertyvalue ent "DATE" dateStr); then
); if [no else -- do nothing if doesn't have that Attribute]
); if
); repeat
); progn [then]
(prompt "\nNo eligible object(s) selected."); else
); if
(prin1)
); defun
Since (ssget) filtering can't look at whether the Block has the appropriate Attribute, it must allow selection of all Blocks with Attributes, but at least can prohibit selection of Blocks without any. The test for whether the Block contains an Attribute tagged "DATE" means it will change only the right one if the Block has more than one Attribute. And while it must allow selection of Blocks with other Attributes but not that one, it will leave the others alone.
It also allows selection of any Text/Mtext object(s), and will change their entire content, no matter what it is, to the date text. Consider whether you might want to limit that in some way, if appropriate ones would always have some filterable properties, such as by their Layer and/or Style and/or Paper vs. Model space.
It could get the usual enhancements such as Undo begin/end wrapping.
Kent Cooper, AIA
@ec-cad wrote:
.... For MText, I think that won't work, because the line:
"(entmod (subst (cons 1 dateStr)(assoc 1 edata) edata))"
Will write the date string only back to the MText value ignoring the additional Formatting
portion of the existing value. What if that MText is say 2 lines of text ? ....
Certainly it will work, in just the same way their original code was written to do. That dumping of any existing internal formatting which is a "feature" of both is why I pointed out that it will replace the entire content no matter what it is [including internal formatting, multiple lines, columns, whatever]. Since they didn't include or ask anything about limiting selection to only objects that are appropriate, it's up to them to not select objects they don't want changed in that way, or to follow up on my other suggestion, to build in such a limit on selection.
My primary purpose in Message 8 was simply for it to work with Block Attributes as well as Text/Mtext [their concern in Message 5].
Kent Cooper, AIA
@Sea-Haven wrote:
As we are talking about Text, Mtext or Attribute then why not.
.... (setq edata (entget (car (nentsel "\nPick Text Mtext or Attribute")))) ........
[That may be good for one-at-a-time picks, which for date text may be fine -- how many things would one want to have that text content in the same drawing? -- but not for multiple selection such as with (ssget), as seems to be the desired approach since it is used in Message 1.]
Kent Cooper, AIA
Forums Links
Can't find what you're looking for? Ask the community or share your knowledge.
Post to forums
