Rotate Viewport Lisp Routine Help

[greg888GP]

Hi there,

I recently upgraded to Civil 3D 2022 and am trying to use an old LISP routine that would allow you to rotate the viewport by running the command 'DVTW' then you select the angle by choosing two points along a line, and then the viewport would be rotated nicely.... now I get an error " Error: AutoCAD variable setting rejected: "cmdecho" nil" 

here is the code for reference...  

; simple dview twist 
;
(defun *error* (msg)
(princ "\nError: ")
(princ msg)
(terpri)
(princ)
)

(defun c:dvtw (/ cmde twa sna)

(princ "Pick or enter angle:")
(setq twa (getangle))
(setq sna twa)
(setq twa (angtos twa (getvar "aunits")))
(setq twa (strcat "-" twa))

(command "dview" "" "tw" twa "")
(setvar "snapang" sna)

(setvar "cmdecho" cmde)
(princ)
)

Can anyone provide a fix? I am not the best at coding!

thanks 

[pbejse · Accepted solution]

---

@greg888GP wrote:

Hi there,

Can anyone provide a fix? I am not the best at coding!

---

cmde is not defined hence the error message

(setvar "cmdecho" cmde)

either take that line out or add this

(defun c:dvtw (/ cmde twa sna)
(setq cmde (Getvar "cmdecho"));<----
(setvar "cmdecho" 0);<----
(princ "Pick or enter angle:")
...

HTH

[marko_ribar · Accepted solution]

Yes, pbe beat me...

This is correction of the code from what I saw...

(defun c:dvtw ( / *error* cmde twa sna )

  (defun *error* ( msg )
    (if cmde
      (setvar 'cmdecho cmde)
    )
    (if msg
      (prompt msg)
    )
    (princ)
  )

  (setq cmde (getvar 'cmdecho))
  (setvar 'cmdecho cmde)
  (initget 3)
  (setq twa (getangle "\nPick or enter angle : "))
  (setq sna twa)
  (setq twa (angtos twa (getvar 'aunits)))
  (setq twa (strcat "-" twa))

  (command "_.dview" "" "_tw" twa "")
  (setvar 'snapang sna)

  (*error* nil)
)