Revision Cloud

[Tony_Gibbs]

Our office only uses 1 set of settings to create a Rev Cloud. Is there a way I can write this into a Lisp file using the Autocad Revision Cloud command "revcloud"? 
Example: (c:_revcloud "A" 4.5 "P" pause) 
A being for Arc size & P for Polygonals

Thank you 
Tony

[Ranjit_Singh · Accepted solution]

Maybe like this

(defun c:somefunc ( / )
(initcommandversion)
(command-s "._revcloud" "_a" 4.5 4.5 "_p"))

 

[trevor.bird.au · Accepted solution]

Hi Tony,

I hope this helps.

I first save the values of the system variables that REVCLOUD uses and then set your required values before running the command.

The system variables are restored after REVCLOUD is finished.

Regards,

Trevor

;;  TonysRevCloud.lsp by Trevor Bird
;;
;;  2017-12-16

;;------------------------------------------------------------------------------
(defun c:tonysrevcloud
  ( /
    sv_cmdecho
    sv_revcloudarcstyle
    sv_revcloudcreatemode
    sv_revcloudmaxarclength
    sv_revcloudminarclength
  )
  (setq sv_cmdecho              (getvar 'CMDECHO)
        sv_revcloudarcstyle     (getvar '*REVCLOUDARCSTYLE)
        sv_revcloudminarclength (getvar '*REVCLOUDMINARCLENGTH)
        sv_revcloudmaxarclength (getvar '*REVCLOUDMAXARCLENGTH)
        sv_revcloudcreatemode   (getvar 'REVCLOUDCREATEMODE)
  );setq

  (setvar '*REVCLOUDMINARCLENGTH 4.5)
  (setvar '*REVCLOUDMAXARCLENGTH 4.5)

;  (setvar '*REVCLOUDARCSTYLE "Calligraphy")
  (setvar '*REVCLOUDARCSTYLE "Normal")

  ;;  REVCLOUDCREATEMODE (System Variable)
  ;;  Specifies the default input for creation of revision clouds.
  ;;  Type:  Integer
  ;;  Saved in:  Registry
  ;;  Initial value:  1
  ;;  Value  =  Description
  ;;    0    =  Freehand
  ;;    1    =  Rectangular
  ;;    2    =  Polygonal
  (setvar 'REVCLOUDCREATEMODE 2)

  (initcommandversion)

  (setvar 'CMDECHO 1)
  (vl-cmdf "_.REVCLOUD" pause)

  (setvar 'CMDECHO sv_cmdecho)
  (setvar '*REVCLOUDARCSTYLE sv_revcloudarcstyle)
  (setvar '*REVCLOUDMINARCLENGTH sv_revcloudminarclength)
  (setvar '*REVCLOUDMAXARCLENGTH sv_revcloudmaxarclength)
  (setvar 'REVCLOUDCREATEMODE sv_revcloudcreatemode)

  (princ)
);c:tonysrevcloud




;;------------------------------------------------------------------------------
(princ "\nTonysRevCloud loaded. Start command with TONYSREVCLOUD.")
(princ)

Regards,

Trevor

[DanielLench_]

@trevor.bird.au, @Tony_Gibbs, @Ranjit_Singh,
My company also uses a standard arc length and style, with the addition of a standard layer "CLOUD" and polyline width "0.3".

The issue now, I believe, is the change to the REVCLOUD object from 2021. Would you be kind enough to double check the lsp for compatibility regarding the update? If you can add in the polyline width and layer, that would really fill out this tool. Thank you for your consideration and time.