Request to make a Lisp for line Fillet

[smallƑish]

Any chance to make an LISP to make this process?

inner line fillet radius 0.25 * Width

Outer line fillet radius 1.25 * Width

Request; the lisp needed to work with lines. (not polylines) 

 

[Sea-Haven]

Your double posting you have already asked for this in your other post, if there was an admin here would ask to merge with your other post. Read my suggestion.

Solved: lisp for Double fillet? - Autodesk Community - AutoCAD

[smallƑish]

Dear  @Sea-Haven

Sir, 

I was unable to find a Solution. I apologize for the post duplication.

[ВeekeeCZ · Accepted solution]

You should learn to write this simple stuff... not just exploit other users' willines.

(vl-load-com)

(defun c:FilletProcess ( / o1 p1 i1 o2 p2 i2 ao ai r w)
  
  (and (setq o1 (entsel "\nSpecify 1st side outer: "))
       (setq p1 (vlax-curve-getclosestpointto (car o1) (trans (cadr o1) 1 0)))
       (setq i1 (entsel "\nSpecify 1st side inner: "))
       (setq p2 (vlax-curve-getclosestpointto (car i1) p1 T))
       (setq i2 (entsel "\nSpecify 2nd side inner: "))
       (setq o2 (entsel "\nSpecify 2nd side outer: "))
       (setq r (getvar 'filletrad))
       (setq w (distance p1 p2))
       (setvar 'filletrad (* 1.25 w))
       (vl-cmdf "_.fillet" o1 o2)
       (setq ao (entlast))
       (setvar 'filletrad (* 0.25 w))
       (vl-cmdf "_.fillet" i1 i2)
       (setq ai (entlast))
       (entmake (list '(0 . "LINE") (cons 10 (vlax-curve-getstartpoint ao)) (cons 11 (vlax-curve-getstartpoint ai))))
       (entmake (list '(0 . "LINE") (cons 10 (vlax-curve-getendpoint ao)) (cons 11 (vlax-curve-getendpoint ai))))
       (setvar 'filletrad r)
       )
  (princ)
)

[smallƑish]

Thank you very much for the code. It's working perfectly. I respect your words. Will start writing.

Again thank you so much.

[smallƑish]

😀