Request For and OSNAP Profile Lisp
[It already is an AutoLisp routine, but I know what you mean....] Another AutoLisp way to do it is by setting the OSMODE System Variable value -- for that particular combination of modes:
(setvar 'osmode 563)
[But I suggest you not include NEArest in your running Osnap modes. You will never be able to Osnap to a MIDpoint except by tabbing through to get to that while hovering in the vicinity, because otherwise, NEArest will always "win" over MIDpoint except when you happen to have the cursor positioned precisely at the midpoint.]
How many combinations would you need? If it's not too many, and if people could be informed of what mode combination each profile represents, you could do something like this:
(defun C:OSP (/ osp)
(setq OSPlist '(("1osp" 3) ("2osp" 33) ("3osp" 51) ("4osp" 163)))
(initget "1osp 2osp 3osp 4osp")
(setq osp (getkword "\nOffset Profile [1osp/2osp/3osp/4osp]: "))
(setvar 'osmode (cadr (assoc osp OSPlist)))
(prin1)
)
I did them with names starting with a number followed by lower-case letters because the number is then the abbreviation for the keyword. It gives the User the option to type just the number, or more of the name if they want, or as formatted, pick the option in the prompt. [If they were called something like OSP1, OSP2, etc., it would be necessary to type in the whole name of the one you want.]
It could be enhanced to offer the current setting as default, or a particular option as initial default on first use, and/or report what it set OSMODE to, or....
@timothy_crouse wrote:
....
Seems useful enough, but the value of 7 and 8 is a bit off, I need to look at the state values a little more
I expect that's because APParent-intersection and FROm Osnap are not just single-pick modes, so they don't make much sense as "running" modes -- some other mode you have involved will take over on picking something.
Would you want it to report just an option number, or spell out the modes involved?
Would you want it to offer an option to change the current Osnap Profile?
[You're missing a closing right parenthesis in setting OSPlist.]
Here's a start -- a simple reporting of which option number, if the setting matches any of them. If OSMODE is set to anything else, it does the alert and asks for a choice.
(defun C:OSP (/ osp)
(setq
OSPlist '(("1osp" 3255) ("2osp" 789) ("3osp" 203) ("4osp" 513) ("5osp" 7423))
OSPlist2 (mapcar 'reverse OSPlist); with numbers first in each sub-list
osm (getvar 'osmode)
); setq
(if (assoc osm OSPlist2); current value is among options
(prompt ; then
(strcat
"\nOsnap Profile is "
(substr (cadr (assoc osm OSPlist2)) 1 1); number from front of option
"."
); strcat
); prompt
(progn ; else
(alert
(strcat
"OSNAP PROFILES:"
"\n1 = END,MID,PER,CEN,GCE,INT,APP,QUA"
"\n2 = END,NEA,TAN,QUA,CEN"
"\n3 = END,MID,PER,NOD,INS"
"\n4 = END,NEA"
"\n5 = KITCHEN SINK"
) ; strcat
) ; alert
(initget "1osp 2osp 3osp 4osp 5osp")
(setq osp (getkword "\nOffset Profile [1osp/2osp/3osp/4osp/5osp]: "))
(setvar 'osmode (cadr (assoc osp OSPlist)))
) ; progn
) ; if
(princ)
)BUT: Suppose it's set to one of those combinations, but turned off [F3]? That would trigger the alert, too, and the User wouldn't know whether it's already set to the combination they want, and they just need to turn it on. Should the routine assume that if you invoke the command, you want to have running Osnap turned on, and turn it on if it's off, before testing for a matching option? It could be made more sophisticated, and determine that condition, and ask whether to just turn it on.
Try this:
(defun C:OSP (/ OSPnew OSPlist OPSlist2 osm OSP# OSPx)
(defun OSPnew ()
(alert
(strcat
"OSNAP PROFILES:"
"\n 1 = END,MID,PER,CEN,GCE,INT,APP,QUA"
"\n 2 = END,NEA,TAN,QUA,CEN"
"\n 3 = END,MID,PER,NOD,INS"
"\n 4 = END,NEA"
"\n 5 = KITCHEN SINK"
"\nPick OK and choose an option."
) ; strcat
) ; alert
(initget "1osp 2osp 3osp 4osp 5osp")
(setq OSP# (getkword "\nOffset Profile [1osp/2osp/3osp/4osp/5osp]: "))
(setvar 'osmode (caddr (assoc OSP# OSPlist)))
); defun
(setq
OSPlist
'(
("1osp" "END,MID,PER,CEN,GCE,INT,APP,QUA" 3255)
("2osp" "END,NEA,TAN,QUA,CEN" 789)
("3osp" "END,MID,PER,NOD,INS" 203)
("4osp" "END,NEA" 513)
("5osp" "KITCHEN SINK" 7423)
)
OSPlist2 (mapcar 'reverse OSPlist); numbers first
osm (getvar 'osmode)
); setq
(cond
((assoc osm OSPlist2); current value is among options, and ON
(initget "Accept New")
(setq OSPx
(getkword
(strcat
"\nOsnap Profile is "
(substr (caddr (assoc osm OSPlist2)) 1 1); number from front of option
": " (cadr (assoc osm OSPlist2)) ". Accept or choose New? [Accept/New] <Accept>: "
); strcat
); getkword
); setq
(if (= OSPx "New") (OSPnew))
); existing-option condition
((assoc (setq OSPoff (- osm 16384)) OSPlist2); current value is among options, but OFF
(initget "On New")
(setq OSPx
(getkword
(strcat
"\nOsnap is off; Osnap Profile is "
(substr (caddr (assoc OSPoff OSPlist2)) 1 1); number from front of option
": " (cadr (assoc OSPoff OSPlist2)) ". Turn On or choose New? [On/New]: "
); strcat
); getkword
); setq
(if (= OSPx "New") (OSPnew) (setvar 'osmode OSPoff))
); existing-option but OFF condition
((OSPnew)); none-of-the-above
); cond
(princ)
)
