replace 3d polyline with block
So convert what you have to blocks of a pattern ? It makes sense to ignore the patterns as they appear to be trying to create solids etc.
So make some new blocks
1 & 3 a circle with hatch solid.
2 an ellipse with hatch solid
4 two circles
5 make block as fairly simple pattern.
For all of them can use Bounding box to get a x and y distance insert the correct block compared to type at mid pt of bounding box.
An example for say 4 draw an outside circle Dia 1 inside rad in proportion. Then use the x dist for scale. If want polygon do so.
Need to use bounding box for multi items need to find. Lee-mac multi bounding box comes to mind.
Note for 2 that ellipse is rotated 90 so check length X & Y if required swap and insert so is oriented correct.
The ellipses are a problem there is 7125 objects so multi bounding box takes a while it may be faster to just get minx maxx miny maxy. Possible fastest is pick four points also simplest. There are 4 ellipses so doing calcs I expect slower than pick 4 points. I tried pick 4 times small amounts still got 672 objects.
I may be looking at this wrong.
Hi Girgis,
Please try the following which will replace an AutoCAD Group of objects with a selected block inserted at the centre of the bounding box that contains the Group:
;; ReplaceGroups.lsp by Trevor Bird
;;
;; 2020-07-22
;;----------------------------------------------------------------------------------------
(defun c:replacegroups
(
/
assoc_330
bbmax_wcs_list
bbmax_wcs_sa
bbmin_wcs_list
bbmin_wcs_sa
dps_340
group_dxf
group_ename
list_340
list__ss_source
midpoint_wcs_list
obj_insert_replacement
obj_insert_source
obj_source
progress_int
reactors_dxf
source_dxf
source_ename
ss_filter
ss_insert
ss_source
)
(setq ss_filter
(list
(if (= (getvar 'CVPORT) 1)
(cons 410 (getvar 'CTAB))
'(410 . "Model")
);if
);list
);setq
(cond
( (not
(progn
(princ "\nSelect source Groups for replacement:")
(setq ss_source (ssget ss_filter))
);progn
);not
(princ "\nNo source Groups selected.")
)
( (not
(progn
(princ "\nSelect replacement block:")
(setq ss_insert (ssget ":S" (cons '(0 . "INSERT") ss_filter)))
);progn
);not
(princ "\nNo replacement block selected.")
)
(ss_source
;; Replacement block
(setq obj_insert_source (vlax-ename->vla-object (ssname ss_insert 0)))
;; Groups for replacement
(setq list__ss_source (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss_source))))
(while list__ss_source
(setq source_ename (car list__ss_source)
list__ss_source (cdr list__ss_source)
source_dxf (entget source_ename)
);setq
(cond
( (not (setq reactors_dxf (member '(102 . "{ACAD_REACTORS") source_dxf))))
( (not (setq reactors_dxf (reverse (member '(102 . "}") (reverse reactors_dxf))))))
( (not (setq assoc_330 (assoc 330 reactors_dxf))))
( (not (setq group_ename (cdr assoc_330))))
( (not (setq group_dxf (entget group_ename))))
(group_dxf
(setq dps_340 (vl-remove-if-not '(lambda ( _dp ) (= (car _dp) 340)) group_dxf)
list_340 (mapcar 'cdr dps_340)
bbmin_wcs_list nil
bbmax_wcs_list nil
);setq
(setq progress_int 0)
(if acet-ui-progress-init (acet-ui-progress-init "Processing group" (length list_340)))
(foreach fe__ename list_340
;; Remove all objects in group from list__ss_source
(setq list__ss_source (vl-remove fe__ename list__ss_source)
obj_source (vlax-ename->vla-object fe__ename)
);setq
(vlax-invoke-method obj_source 'GetBoundingBox 'bbmin_wcs_sa 'bbmax_wcs_sa)
;; From Lee Mac - Selection Set Bounding Box
(setq bbmin_wcs_list (mapcar 'min (vlax-safearray->list bbmin_wcs_sa) (cond (bbmin_wcs_list) ((vlax-safearray->list bbmin_wcs_sa))))
bbmax_wcs_list (mapcar 'max (vlax-safearray->list bbmax_wcs_sa) (cond (bbmax_wcs_list) ((vlax-safearray->list bbmax_wcs_sa))))
);setq
(vlax-invoke-method obj_source 'Delete)
(vlax-release-object obj_source)
(setq progress_int (1+ progress_int))
(if acet-ui-progress-safe (acet-ui-progress-safe progress_int))
);fe__ename
(if acet-ui-progress-done (acet-ui-progress-done))
;; Midpoint of group bounding box
(setq midpoint_wcs_list
(list
(/ (apply '+ (mapcar 'car (list bbmin_wcs_list bbmax_wcs_list))) 2.0)
(/ (apply '+ (mapcar 'cadr (list bbmin_wcs_list bbmax_wcs_list))) 2.0)
(/ (apply '+ (mapcar 'caddr (list bbmin_wcs_list bbmax_wcs_list))) 2.0)
);list
);setq
(setq obj_insert_replacement (vlax-invoke-method obj_insert_source 'Copy))
(vlax-put-property obj_insert_replacement 'InsertionPoint (vlax-3d-point midpoint_wcs_list))
(vlax-release-object obj_insert_replacement)
);group_dxf
);cond
);while
(vlax-release-object obj_insert_source)
);ss_source
);cond
(princ)
);c:replacegroups
;;----------------------------------------------------------------------------------------
(princ "\nReplaceGroups loaded. Start command with REPLACEGROUPS.")
(princ)
The video was edited to speed up the time it took to process the last Group selected which had 14253 objects.
I also reset the insertion point of some of the blocks which was not local to the objects in the block.
Regards,
Trevor
