Rename suffix based on list value

[yann_fradier]

Hello everyone and thank you for your help,

I try to adapt the lsp evoked on the forum for my case but that exceeds my competence in this field ^^.

I would like an lsp to rename the suffixes of the layers according to the name of each of them

Example: 

Suffixe "02-SURFACE"

Layer list: [ZRAEX;ZEX;ZDECAP]

Example after lsp: 02-SURFACE-ZRAEX

Suffixe "03-CADASTRE"

Layer list: [PARCELLE]

Example after lsp: 03-CADASTRE-PARCELLE

Suffixe "04-topo"

Layer list: [BT,HT,POINT]

Example after lsp: 04-TOPO-BT

[ВeekeeCZ]

Welcome to the forums!

First, post the lisp you're referring to. Also post a dwg with these layers to test.

Secondly, "renaming" is a 1 to 1 relation. So having a list of suffices, are you actually wanting to CREATE new layers according to that list?

[yann_fradier]

Thanks for your help

Here is a dwg type for which I want depending on the type of entity to add a suffix as mentioned before

[yann_fradier]

I don't want to create a new layer but rename the existing one

Here is the final result:

[komondormrex]

hey,

check this

(defun add_layer_prefix  (layer_list prefix)
	(vlax-map-collection (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))) 
		'(lambda (layer)
			(if (member (vla-get-name layer) layer_list)
				(vla-put-name layer (strcat prefix "-"(vla-get-name layer)))
			)
		)
	)
	(princ)
)

;to run type in command line (add_layer_prefix '("ZRAEX" "ZEX" "ZDECAP") "02-SURFACE") <Enter>

[yann_fradier]

Thanks for coming back,
this lisp does not launch although I call it with APPLOAD

[komondormrex · Accepted solution]

it is a function. should run typed in command line (add_layer_prefix '("ZRAEX" "ZEX" "ZDECAP") "02-SURFACE") <Enter>

[yann_fradier]

The command line works perfectly! thank you for your help on my subject and the speed of response!
Best wishes 🙂

[yann_fradier]

Hello everyone,
and thank you again for your help on this subject a few months ago.

I would like to reopen the subject because I would like to make a modification to this routine.

Would it be possible to modify it so that I can give it several dates and so that it renames the original layers as many times as there are dates? 

The previous lisp is very suitable but must be executed several times.

I wish that it can manage the renaming of layers in the same way but as many times as on different dates.

Expected result in attachment with the previous lisp executed several times at different dates ;)

Thank you in advance for your help !

[komondormrex]

hello,

how do you want to pass various dates to the program?

[yann_fradier]

by indicating a list of dates for example

[komondormrex]

you mean like that

Suffixe "02-SURFACE"

Layer list: [ZRAEX;ZEX;ZDECAP]

Date: [11-17-2023] - one date, not a list

Example after lsp: 02-SURFACE-11-17-2023-ZRAEX

[yann_fradier]

Exactly that could answer my request in this form

[komondormrex]

check if that suits you

(defun add_layer_prefix  (layer_list prefix date / new_layer_name)
	(vlax-map-collection (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))) 
		'(lambda (layer)
				(if (and
				 		(member (vla-get-name layer) layer_list)
						(setq new_layer_name (strcat prefix "-" date "-" (vla-get-name layer)))
						(vl-catch-all-error-p 
						 	(vl-catch-all-apply 'vla-item (list (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
								  			    new_layer_name
										      )
							)
						)
				    )
						(vla-put-name layer new_layer_name)
						(if new_layer_name (alert (strcat "Layer \"" new_layer_name "\" already exists")))
					)
				)
			)
		(princ)
	)

;to run type in command line (add_layer_prefix '("ZRAEX" "ZEX" "ZDECAP") "02-SURFACE" "17-11-2023") <Enter>

[yann_fradier]

Thanks for your help ! I can't use the script.
Would it be possible to provide me with the example with at least two dates?
I don't particularly want to use the command line but rather by offering a list of dates.
Each layer will therefore be duplicated as many times as the dates

[komondormrex]

you mean not renaming a particular layer but creating a few with different dates from the list?

[yann_fradier]

Exactly yes,
I would even go for something simpler in the sense that if I have 1 layer in my DWG I indicate 5 dates by a list the program creates a dataset of 5 layers renamed with these same dates in prefix

[komondormrex · Accepted solution]

check this. same command line thou. 

(defun add_layer_prefix  (layer_list prefix date_list / new_layer_name layer_collection layer_name renamed)
	(vlax-map-collection (setq layer_collection (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
		'(lambda (layer)
			(if (member (setq layer_name (vla-get-name layer)) layer_list)
				(progn
					(setq renamed nil)
					(foreach date date_list
						(if (and
								(setq new_layer_name (strcat prefix "-" date "-" layer_name))
								(vl-catch-all-error-p 
									(vl-catch-all-apply 'vla-item (list (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
												  						new_layer_name
													  			  )
									)
								)
							)
								(if (not renamed) 
									(setq renamed (not (vla-put-name layer new_layer_name)))
									(vla-add layer_collection new_layer_name)
								)
								(alert (strcat "Layer \"" new_layer_name "\" already exists"))
						)
			  		)
				)
		  	)
		)
	)
	(princ)
)

;to run type in command line (add_layer_prefix '("ZRAEX" "ZEX" "ZDECAP") "02-SURFACE" '("17-11-2023" "17-10-2023" "17-09-2023")) <Enter>

[yann_fradier]

It's perfect, the program works wonderfully!
Second times you change my daily life XD

Thanks !!

[yann_fradier]

Sorry but I have one more modification but by creating a new layer we do not keep the graphic properties of the source layer.
Do you have a solution to keep these settings?

See attached image (the layers created are all without style)

Thank you again for your help