Remove points from a list duplicate x (or y)

[Anonymous]

Hi all,

Can some one have code remove points duplicate x position in pointlist ? or tell me the way do it.

Thanks in advance.

[_Tharwat]

Can you show an example?

[stevor · Accepted solution]

Maybe:

 ; Unique and Duplicate Points at, resolution RE, SCG
 (defun Pars_EqX ( PL RE / P X DF UP DXPL UPL )
  (foreach P PL
   (setq X (car P)  dF NIL)
   (foreach UP UPL
    (if (equal X (car UP) RE) (setq DF T))
   )
   (if DF (setq DXPL (cons P DXPL))
          (setq UPL  (cons P UPL )) )
  )  (list  UPL  DXPL) ) ; d

[phanaem · Accepted solution]

(defun x_dupl (l)
  (if l
    (cons
      (car l)
      (x_dupl
        (vl-remove-if
          '(lambda (a)
             (equal (car a) (caar l) 1e-8)
           )
           (cdr l)
        )
      )
    )
  )
)

For y duplicates, change (car a) (caar l) to (cadr a) (cadar l)

[Anonymous]

Hi stevor,

i think same to you (2 foreach) but bad than you ^_^, (error ; entering keyboard break loop)

Thanks for share your code.

[Anonymous]

hi phanaem,

Your code exactly what i am looking for.

I learn more one way loop.

Thank you.